[动态规划，tsp问题]pku2288 Islands and Bridges_ven a map of islands and bridges that connect thes-CSDN博客

本文链接：https://blog.csdn.net/fstephen/article/details/5040562

该博客介绍了如何运用动态规划算法解决PKU2288题目的旅行商问题（TSP），探讨了输入输出格式以及示例分析。

摘要生成于 C知道，由 DeepSeek-R1 满血版支持，前往体验 >

Islands and Bridges

Time Limit: 4000MS		Memory Limit: 65536K
Total Submissions: 4173		Accepted: 1008

Description

Given a map of islands and bridges that connect these islands, a Hamilton path, as we all know, is a path along the bridges such that it visits each island exactly once. On our map, there is also a positive integer value associated with each island. We call a Hamilton path the best triangular Hamilton path if it maximizes the value described below.

Suppose there are n islands. The value of a Hamilton path C1C2...Cn is calculated as the sum of three parts. Let Vi be the value for the island Ci. As the first part, we sum over all the Vi values for each island in the path. For the second part, for each edge CiC _i+1 in the path, we add the product Vi*V _i+1. And for the third part, whenever three consecutive islands CiC _i+1C _i+2 in the path forms a triangle in the map, i.e. there is a bridge between Ci and C _i+2, we add the product Vi*V _i+1*V _i+2.

Most likely but not necessarily, the best triangular Hamilton path you are going to find contains many triangles. It is quite possible that there might be more than one best triangular Hamilton paths; your second task is to find the number of such paths.

Input

The input file starts with a number q (q<=20) on the first line, which is the number of test cases. Each test case starts with a line with two integers n and m, which are the number of islands and the number of bridges in the map, respectively. The next line contains n positive integers, the i-th number being the Vi value of island i. Each value is no more than 100. The following m lines are in the form x y, which indicates there is a (two way) bridge between island x and island y. Islands are numbered from 1 to n. You may assume there will be no more than 13 islands.

Output

For each test case, output a line with two numbers, separated by a space. The first number is the maximum value of a best triangular Hamilton path; the second number should be the number of different best triangular Hamilton paths. If the test case does not contain a Hamilton path, the output must be `0 0'.

Note: A path may be written down in the reversed order. We still think it is the same path.

Sample Input

Sample Output

22 3
69 1

Source

Shanghai 2004

分析：经典的TSP问题的变形。因为节点数比较少，最多只有13个，所以可以用状态压缩动态规划来做。令f[i,j,k]表示状态压缩后为i，（即i转化为二进制后，第x位上位1表示点x走过，否则没走过），倒数第二个经过的点为j，最后一个经过的点为k的最大得分。

初值：f[1 shl (i-1)+1 shl (j-1),i,j]:=d[i]+d[j]+d[i]*d[j](i、j之间有边)。

状态转移方程：f[i,j,k]=max(f[i',j',j]+point)（i-i'=1 shl (k-1),状态i‘没走过k这个点，j和k相连，point为这样走的得分，根据题目描述可算得）。

路径条数运用加法原理计算就行了。因为1->2和2->1是一样的，所以最后答案要除以2.

wa原因集锦：

1、没有考虑到n=1的情况，路径总条数应该为1.

2、没有看题，直接看蹩脚的翻译，结果理解错题意，point计算错误。

3、交错程序...= =

注意要用int64.

codes：

const
  max=(1 shl 13)-1;
var
  t,n,m,maxn:longint;
  v:array[0..13] of longint;
  a:array[1..13,1..13] of boolean;
  f,w:array[0..max,0..13,0..13] of int64;
procedure init;
  var
    i,x,y:longint;
  begin
    fillchar(f,sizeof(f),255);
    fillchar(w,sizeof(w),0);
    fillchar(a,sizeof(a),false);
    v[0]:=1;
    readln(n,m);
    for i:=1 to n do read(v[i]);
    for i:=1 to m do
      begin
        readln(x,y);
        a[x,y]:=true;
        a[y,x]:=true;
      end;
    maxn:=(1 shl n)-1;
  end;
procedure main;
  var
    i,j,k,x,t,next:longint;
    change,ans,tot:int64;
  begin
    for i:=1 to n do
      for j:=1 to n do
        if a[i,j] then
          begin
            f[(1 shl (i-1))+(1 shl (j-1)),i,j]:=v[i]+v[j]+v[i]*v[j];
            w[(1 shl (i-1))+(1 shl (j-1)),i,j]:=1;
          end;
    for i:=0 to maxn do
      for j:=1 to n do
        for k:=1 to n do
          if f[i,j,k]>0 then
            for x:=1 to n do
              if a[k,x] then
                 begin
                   t:=1 shl (x-1);
                   if i and t=0 then
                     begin
                       next:=i+t;
                       change:=f[i,j,k]+v[x]+v[x]*v[k];
                       if a[j,x] then inc(change,v[x]*v[k]*v[j]);
                       if f[next,k,x]<change then
                         begin
                           f[next,k,x]:=change;
                           w[next,k,x]:=w[i,j,k];
                         end
                       else
                         if f[next,k,x]=change then
                           inc(w[next,k,x],w[i,j,k]);
                     end;
                 end;
    tot:=0; ans:=0;
    for i:=1 to n do
      for j:=1 to n do
        if f[maxn,i,j]>ans then
          begin
            ans:=f[maxn,i,j];
            tot:=w[maxn,i,j];
          end
        else
          if f[maxn,i,j]=ans then inc(tot,w[maxn,i,j]);
    if n=1 then begin tot:=2; ans:=v[1]; end;
    writeln(ans,' ',tot div 2);
  end;
begin
  readln(t);
  while t>0 do
    begin
      init;
      main;
      dec(t);
    end;
end.