[动态规划+矩阵快速幂优化]Pku3420--Quad Tiling

最新推荐文章于 2019-04-02 23:20:17 发布

fstephen

最新推荐文章于 2019-04-02 23:20:17 发布

阅读量1.2k

点赞数

分类专栏：解题报告文章标签：优化 output each input blog div

本文链接：https://blog.csdn.net/fstephen/article/details/5042295

版权

解题报告专栏收录该内容

24 篇文章 0 订阅

订阅专栏

Quad Tiling

Time Limit: 1000MS		Memory Limit: 65536K
Total Submissions: 1801		Accepted: 698

Description

Tired of the Tri Tiling game finally, Michael turns to a more challengeable game, Quad Tiling:

In how many ways can you tile a 4 × N (1 ≤ N ≤ 10⁹) rectangle with 2 × 1 dominoes? For the answer would be very big, output the answer modulo M (0 < M ≤ 10⁵).

Input

Input consists of several test cases followed by a line containing double 0. Each test case consists of two integers, N and M, respectively.

Output

For each test case, output the answer modules M.

Sample Input

Sample Output

1
11
95

Source

POJ Monthly--2007.10.06, Dagger

感慨：这道题我郁闷了很久..因为网上没有很好的解题报告...而且标程写得..我看不懂= =所以一直没有理解..现在静静地想一想，其实一切都顺理成章嘛..一次AC，庆祝下，虽然很爽，但郁闷的是，刚blog出了bug，写好的解题报告没了，郁闷= =以后一定记得发之前保存个..

题目大意：给出一个4*n的矩阵，问用1*2的骨牌将它完全覆盖有多少种方案。输出方案数mod m。

分析：传统方法因为n最大有10^9之多，所以会超时。若定义f[i,k]表示前i-1行已经完全覆盖，第i行状态为k的方案数的话，注意到f[i]只和f[i-1]有关，而且关系是线性的，且f的i域范围很大，但k域范围很小（0~15），再者每相邻两行的状态转移方程完全相同，所以可以用矩阵来表示这种转移方法。

构造16*16的矩阵G，使得f[i]*G=f[i+1]。这里，将f[i]看成是一个1*16的矩阵。

只要对矩阵乘法理解透彻，就不难用dfs来构造出矩阵G。然后，只要将第一行可能的状态org乘上Gn次，就能得到f[n+1]，f[n+1,0]即答案。

由于矩阵乘法满足结合律，所以可以用快速幂求出G^N，再乘以org。至此，问题解决。

codes:

type
  arr=array[0..16,0..16] of longint;
const
  org:array[0..15] of longint=(1,0,0,1,0,0,1,0,0,0,0,0,1,0,0,1);//第一行可能放置出来的状态
var
  g,ans,temp:array[0..16,0..16] of longint;
  n,m:longint;
procedure dfs(x,old,new:longint);
  begin
    if x=4 then
      inc(g[new,old]);
    if x>3 then exit;
    if old and (1 shl x)=0 then dfs(x+1,old,new shl 1 or 1);
    if old and (1 shl x)>0 then
      begin
        if old and (1 shl (x+1))>0 then
          dfs(x+2,old,new shl 2 or 3);
        dfs(x+1,old,new shl 1);
      end;
  end;
procedure mul(a,b:arr;var c:arr);
  var
    i,j,k:longint;
    t:arr;
  begin
    fillchar(t,sizeof(t),0);
    for i:=0 to 15 do
      for j:=0 to 15 do
        begin
          for k:=0 to 15 do
            t[i,j]:=t[i,j]+a[i,k]*b[k,j];
          t[i,j]:=t[i,j] mod m;
        end;
    c:=t;
  end;
procedure cal(x:longint);
  begin
    if x=1 then
      begin
        ans:=g;
        exit;
      end;
    cal(x div 2);
    mul(ans,ans,temp);
    ans:=temp;
    if x and 1>0 then
      begin
        mul(ans,g,temp);
        ans:=temp;
      end;
  end;
procedure print;
  var
    i:longint;
    an:int64;
  begin
    an:=0;
    for i:=0 to 15 do
      an:=(an+ans[0,i]*org[i]) mod m;
    writeln(an);
  end;
procedure main;
  var
    i:longint;
  begin
    for i:=0 to 15 do
      dfs(0,i,0);
    readln(n,m);
    while n+m<>0 do
      begin
        fillchar(ans,sizeof(ans),0);
        cal(n);
        print;
        readln(n,m);
      end;
  end;
begin
  main;
end.

fstephen

关注

0
点赞
踩
1

收藏

觉得还不错? 一键收藏
0
评论
[动态规划+矩阵快速幂优化]Pku3420--Quad Tiling

Quad TilingTime Limit: 1000MS Memory Limit: 65536KTotal Submissions: 1801 Accepted: 698DescriptionTired of the Tri Tiling game finally, Michael turns to a more
复制链接

扫一扫