Flash图片墙

通过Flash的z轴，可以模拟3D效果，以下是一个图片墙的小例子：

1、新建一fla文件，命名PhotoWall.fla。

2、新建一as文件，命名PhotoWall.as，并关联到fla。

3、PhotoWall.as中编辑代码:

package 
{
import flash.display.DisplayObject;
import flash.display.Sprite;
import flash.events.Event;
import flash.geom.Vector3D;
import flash.display.Loader;
import flash.net.URLRequest;
import flash.display.Shape;


[SWF(width = 800,height = 400,backgroundColor = 0x0)]
public class PhotoWall extends Sprite
{
private var _holder:Sprite;
private var _items:Array;
private var _radius:Number = 300;
private var _numItems:int = 10;
public function PhotoWall()
{
this.graphics.beginFill(0x0,1);
this.graphics.drawRect(0,0,stage.stageWidth,stage.stageHeight);
this.graphics.endFill();

//设置透视深度
this.transform.perspectiveProjection.fieldOfView = 110;
_holder = new Sprite();
_holder.x = 400;
_holder.y = 200;
_holder.z = 0;
addChild(_holder);
_items = new Array();
for (var i:int = 0; i < _numItems; i++)
{
var angle:Number = Math.PI * 2 / _numItems * i;
var item:Shape = createPictureItem();
item.x = Math.cos(angle) * _radius;
item.z = Math.sin(angle) * _radius;
item.rotationY = -360 / _numItems * i + 90;
_items.push(item);
}
sortItem();


addEventListener(Event.ENTER_FRAME,onEnterFrameHandler);
}

private function createPictureItem():Shape
{
var item:Shape = new Shape();
item.graphics.beginFill(Math.random() * 0xffffff,1);
item.graphics.drawRect(-40, -40, 120, 120);
_holder.addChild(item);
return item;
}
private function sortItem():void
{
_items.sort(depthSort);
for (var i:int = 0; i < _items.length; i++)
{
_holder.setChildIndex(_items[i] as Shape, i);
}
}
private function depthSort(objA:DisplayObject, objB:DisplayObject):int
{
var posA:Vector3D = objA.transform.matrix3D.position;
posA = _holder.transform.matrix3D.deltaTransformVector(posA);
var posB:Vector3D = objB.transform.matrix3D.position;
posB = _holder.transform.matrix3D.deltaTransformVector(posB);
return posB.z - posA.z;
}
private function onEnterFrameHandler(e:Event):void
{
_holder.rotationY += (stage.stageWidth/2-mouseX)*0.01;
//_holder.y +=  (mouseY - _holder.y) * 0.1;
sortItem();
}
}
}

Ctrl+Enter效果如下: