Flash 模拟LED显示屏

这里是BitmipData的一个应用。BitmapData，位图数据，通过该对象，可以对位图里的某一个像素点进行操作，比如修改某位置像素的颜色，透明度等，可以对某个像素点应用滤镜，下面通过一个仿LED显示屏，在显示屏上显示一个带动画的文本的例子来展示BitmapData的应用，大概思路是：将将要显示的文本绘制到位图上，然后读取每一个像素的颜色并用该颜色在随机位置绘制一个小球，再将小球以一定的时间运动到指定位置(会用到第三方缓动类)。

1、新建一fla文件，命名LedScreen.fla

2、新建一as文件，命名LedScreen.as,编辑代码如下：

package 
{
import flash.display.*;
import flash.text.*;
import flash.filters.*;
import flash.geom.*;
import caurina.transitions.Tweener;
public class LedScreen extends Sprite
{
private var bmd:BitmapData;
public function LedScreen():void
{
var tf:TextField = new TextField();
tf.textColor = 0x000000;
tf.text = "Hello world\nWelcome you!";
tf.autoSize = "left";
//文本 draw成BitmapData
bmd = new BitmapData(tf.width,tf.height,false,0x3399ff);
bmd.draw(tf);
//添加滤镜
bmd.applyFilter(bmd, bmd.rect, new Point(), new BlurFilter());
bmd.draw(tf);
//循环排列
for (var i:int = 0; i < bmd.width; i++)
{
for (var j:int = 0; j < bmd.height; j++)
{
Tweener.addTween(
                        randomize(addChild(new Circle(bmd.getPixel(i, j)))), //getPixel（）用来按照位置获取颜色
                        {
        //排列
                            x: (stage.stageWidth-tf.width*10)/2+(i * 10)+5,
                            y: (stage.stageHeight-tf.height*10)/2+(j * 10)+5,
                            alpha: 1,
                            delay: (i + j) * .2 * Math.random(),
                            time: 1
                        }
                    );
}
}
}
//仿粒子
private function randomize(d:DisplayObject):DisplayObject
{
d.x = 1000 * Math.random();
d.y = 400 * Math.random();
d.alpha = 0;
return d;
}
}
}

import flash.display.Sprite;
//元素小球
class Circle extends Sprite
{
public function Circle(color:uint):void
{
graphics.beginFill(color);
graphics.drawCircle(0, 0, 6);
graphics.endFill();
}

}

Ctrl+Enter导出效果：