P1993 七色花（二) - 解题报告

在某个时间点，天空中会飘落各种颜色的花朵。你可以不消耗时间就接住所有的花。
下面告诉你每个时间点落下的花的颜色，请问你最少需要多少时间就能接到k种颜色的花朵。
例如：下面有 5个时间点,每个时间点跟着落花的数量和每朵花的颜色
1 3 1 1 1
3 1 2
5 2 3 1
9 3 1 2 4
10 2 1 3
如果你要接住至少3种颜色不一样的花，你只需要从时间9开始接花，不需要花费时间就能得到3种颜色的花。
如果你要接住至少4种颜色不一样的花，你只需要从时间9开始接花，一直到时间10。需要花费时间10-9=1.
下面你请编程解决这个问题。
输入:
第一行两个整数n和k，分别表示有n个时间点，共要收集至少k朵不同颜色的花
后面n行。
每行第1个整数表示时间点time,第2个整数表示落花的数量num,后面若干个整数表示落花的颜色color
数据保证时间点是从小到大有序的，且一定能收集到至少k种颜色的花
输出:
一个整数，表示最少收集到至少k朵不同颜色花的最短时间。

样例输入（一）：

3 2
1 1 1
3 2 2 2
8 3 1 6 7

样例输入（二）:

5 3
1 1 1
5 2 3 3
6 2 2 2
7 2 4 4
8 3 2 2 2

样例输出（一）

0

样例说明:
落花有3个时间点，至少要收集2种颜色的花
只要等在时间点8收集花朵，就能收集到不同颜色的花3种
所需时间为8-8=0

样例输出（二）

2

样例说明:
落花有5个时间点，至少要收集3种颜色的花
只要从时间点5开始，一直收集到时间点7，就能收集到3种颜色的花。
所需时间为7-5=2

two pointers 线扫
这里采用的是枚举尾(j)，后推头(i)的方法，需要注意的一点是i向前移动后可能会产生更优的答案

const INF=100000008;
var
        n,i,j,k,ans,now:longint;
        time,num:array[0..100005] of longint;
        col:array[0..100005,0..50] of longint;
        flag:array[0..1005] of longint;
procedure add(j:longint);
var k:longint;
begin
        for k:=1 to num[j] do
        begin
                inc(flag[ col[j,k] ]);
                if flag[ col[j,k] ]=1 then inc(now);
        end;
end;
function check:boolean;
begin
        exit(now>=k);
end;
procedure note;
begin
        if time[j]-time[i]<ans then ans:=time[j]-time[i];
end;
procedure delete(i:longint);
var k:longint;
begin
        for k:=1 to num[i] do
        begin
                dec(flag[ col[i,k] ]);
                if flag[ col[i,k] ]=0 then dec(now);
        end;
end;
begin
        readln(n,k);
        for i:=1 to n do
        begin
                read(time[i],num[i]);
                for j:=1 to num[i] do
                        read(col[i,j]);
        end;
        i:=1; ans:=INF;
        //time[n+1]:=time[n]; num[n+1]:=0;
        for j:=1 to n do
        begin
                add(j);
                if check then note;
                while check and (i<=n) do
                begin
                        note; //这是整个程序中需要注意的点！！！ 可能i向前移动后会产生更优的解
                        delete(i);
                        inc(i);
                end;
        end;
        writeln(ans);
end.