uvm-1.2 examples —— 2.6 config_db - manual

最新推荐文章于 2024-03-20 10:25:39 发布
最新推荐文章于 2024-03-20 10:25:39 发布
阅读量336 收藏 4
点赞数
分类专栏： uvm-1.2 examples
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/hh199203/article/details/113105677
版权

2.6 config_db - manual

文章目录

前言

本文以uvm-1.2/examples/simple/configuration/manual为例，主要介绍在config_db机制中，如何通过set和get函数，在UVM的各个组件之间传递参数。另外，这个例子还展示了两种不同的方法，打印UVM的树状拓扑结构。

一、基本介绍

这个测试用例的UVM树状拓扑结构和2.5节一样，在top下面例化了两个组件A和B，其中A下面例化了两个C，B下面例化了一个C，具体的组件层次结构和参数如下所示。2.5节没有get函数，是通过满足一定的条件，在build_phase中，通过调用super.build_phase，自动调用了get函数；和2.5节不一样的是，在这个测试用例中，A，B和C组件中通过手动调用get函数，获取set函数传递的参数。

----------------------------------------------------
Name                  Type              Size  Value 
----------------------------------------------------
topenv                my_env            -     @362  
  inst1               A                 -     @381  
    u1                C                 -     @402  
      v               integral          32    'h1e  
      s               integral          32    'h10  
      myaa            aa_string_string  3     -     
        myaa[bar]     string            3     bye   
        myaa[foo]     string            3     boo   
        myaa[foobar]  string            6     boobah
    u2                C                 -     @411  
      v               integral          32    'h5   
      s               integral          32    'h10  
      myaa            aa_string_string  3     -     
        myaa[bar]     string            3     bye   
        myaa[foo]     string            2     hi    
        myaa[foobar]  string            5     howdy 
    debug             integral          1     'h1   
  inst2               B                 -     @390  
    u1                C                 -     @433  
      v               integral          32    'ha   
      s               integral          32    'h0   
      myaa            aa_string_string  3     -     
        myaa[bar]     string            3     bye   
        myaa[foo]     string            2     hi    
        myaa[foobar]  string            5     howdy 
    debug             integral          1     'h1   
  debug               integral          1     'h0   
----------------------------------------------------

这里简单介绍一下config_db机制中的set函数和get函数。
1、写信set函数
set函数实例
1）第一个和第二个参数联合起来组成目标路径，与此路径符合的目标才能收信。
2）第一个参数必须为uvm_component 的实例的指针。
3）第二个参数是相对于此实例的路径。
4）既然是第一个和第二个参数联合起来的，set 也可以是下面：
在这里插入图片描述

2、收信get函数
get函数示例
1）第一个参数必须为uvm_component 的实例的指针。
2）第二个参数是相对于此实例的路径。如果第一个设置为 this，第二个可以是空的字符串。
3）第三个参数必须和set中的严格一样。
4）get也可以这样，比如driver的build_phase：
在这里插入图片描述

二、代码分析

代码共5个文件，包括：top.sv，my_env_pkg.sv，classA.svh，classB.svh，classC.svh。下面分别介绍这5个文件的代码。

1.top.sv

module top;
  import uvm_pkg::*;
  import my_env_pkg::*;

  my_env topenv;

  initial begin
    //uvm_default_printer = uvm_default_table_printer;
    uvm_top.enable_print_topology = 1;

    //set configuration prior to creating the environment
    uvm_config_int::set(null, "topenv.*.u1", "v", 30);
    uvm_config_int::set(null, "topenv.inst2.u1", "v", 10);
    uvm_config_int::set(null, "topenv.*", "debug", 1);
    uvm_config_string::set(null, "*", "myaa[foo]", "hi");
    uvm_config_string::set(null, "*", "myaa[bar]", "bye");
    uvm_config_string::set(null, "*", "myaa[foobar]", "howdy");
    uvm_config_string::set(null, "topenv.inst1.u1", "myaa[foo]", "boo");
    uvm_config_string::set(null, "topenv.inst1.u1", "myaa[foobar]", "boobah");

    topenv = new("topenv", null);
    run_test();

  end

endmodule

这个文件的代码大部分和2.5节一致，其中值得注意的是，第9行通过设置uvm_top.enable_print_topology这个参数为1，在end_of_elaboration phase结束的时候打印UVM的树状拓扑结构。

2. my_env_pkg.sv

package my_env_pkg;
  import uvm_pkg::*;

  `include "classA.svh"
  `include "classB.svh"
  
  class my_env extends uvm_env;
    bit debug = 0;
    A inst1;
    B inst2;
  
    function new(string name, uvm_component parent);
      super.new(name, parent);
    endfunction
  
    function void build_phase(uvm_phase phase);
      super.build_phase(phase);
      void'(uvm_config_int::get(this, "", "debug", debug));
      uvm_config_int::set(this, "inst1.u2", "v", 5);
      uvm_config_int::set(this, "inst2.u1", "v", 3);
      uvm_config_int::set(this, "inst1.*", "s", 'h10);
  
      $display("%s: In Build: debug = %0d", get_full_name(), debug);
  
      inst1 = new("inst1", this);
      inst2 = new("inst2", this);
    endfunction
  
    function string get_type_name();
      return "my_env";
    endfunction
    function void do_print(uvm_printer printer);
      printer.print_field("debug", debug, 1);
    endfunction

    task run_phase(uvm_phase phase);
       phase.raise_objection(this);
       uvm_top.print_topology();
       #10;
       phase.drop_objection(this);
    endtask

  endclass
  
endpackage : my_env_pkg

这个文件值得注意的是，第18行手动的调用的get函数。另外，第38行这里提供了第二种打印UVM树状top结构的方法。

3. classA.svh，classB.svh，classC.svh

三个文件的代码分别如下所示，与2.5节的区别是，在build_phase中手动的加入了get函数。
classA.svh

`ifndef CLASSA_SVH
`define CLASSA_SVH

`include "classC.svh"

class A extends uvm_component;
  bit debug = 0;
  C u1;
  C u2;

  function new(string name, uvm_component parent);
    super.new(name, parent);
  endfunction
  function void build_phase(uvm_phase phase);
    super.build_phase(phase);

    void'(uvm_config_int::get(this, "", "debug", debug));
    uvm_config_int::set(this, "*", "v", 0);

    $display("%s: In Build: debug = %0d", get_full_name(), debug);

    u1 = new("u1", this);
    u2 = new("u2", this);
  endfunction

  function string get_type_name();
    return "A";
  endfunction
  function void do_print(uvm_printer printer);
    printer.print_field("debug", debug, 1);
  endfunction
endclass

`endif

classB.svh

`ifndef CLASSB_SVH
`define CLASSB_SVH

`include "classC.svh"

class B extends uvm_component;
  bit debug = 0;
  C u1;

  function new(string name, uvm_component parent);
    super.new(name, parent);
  endfunction
  function void build_phase(uvm_phase phase);
    super.build_phase(phase);

    void'(uvm_config_int::get(this, "", "debug", debug));
    uvm_config_int::set(this, "u1", "v", 0);

    $display("%s: In Build: debug = %0d", get_full_name(), debug);

    u1 = new("u1", this);
  endfunction

  function string get_type_name();
    return "B";
  endfunction
  function void do_print(uvm_printer printer);
    printer.print_field("debug", debug, 1);
  endfunction
endclass

classC.svh

`ifndef CLASSC_SVH
`define CLASSC_SVH

class C extends uvm_component;
  int v=0;
  int s=0;
  string myaa [string];
  function new(string name, uvm_component parent);
    super.new(name, parent);
  endfunction

  function void build_phase(uvm_phase phase);
    string str;
    super.build_phase(phase);
    void'(uvm_config_int::get(this, "", "v", v));
    void'(uvm_config_int::get(this, "", "s", s));
    if(uvm_config_string::get(this, "", "myaa[foo]", str)) myaa["foo"] = str;
    if(uvm_config_string::get(this, "", "myaa[bar]", str)) myaa["bar"] = str;
    if(uvm_config_string::get(this, "", "myaa[foobar]", str)) myaa["foobar"] = str;
  endfunction

  function string get_type_name();
    return "C";
  endfunction

  function void do_print(uvm_printer printer);
    printer.print_field("v", v, 32);
    printer.print_field("s", s, 32);
    printer.print_array_header("myaa", myaa.num(), "aa_string_string");
    foreach(myaa[i])
      printer.print_string($sformatf("myaa[%0s]", i), myaa[i]);
    printer.print_array_footer();
  endfunction

  function void set_string_local (string  field_name,
                                                 string  value,
                                                 bit     recurse=1);
    string index;
    bit wildcarded;
    //call the super function to get child recursion and any registered fields
    super.set_string_local(field_name, value, recurse);

    index = uvm_get_array_index_string(field_name, wildcarded);
    if(!wildcarded && uvm_is_match(field_name, {"myaa[", index, "]"}))
    myaa[index] = value;
  endfunction

endclass

`endif

总结

通过这个测试用例可以学习到：1、如何利用config_db机制中的set和get函数，在UVM的组件之间传递参数；2、两种不同的方法打印UVM的树状top结构。

hh199203
关注
专栏目录
UVM 1.2源码包
06-25
UVM Class Library Code for Release 1.2 UVM 1.2最新版本2014年6月release
uvm-1.2.rar
11-12
1小时玩转数字电路.rar AHB-SRAMC和FIFO的设计与验证.rar clock skew.rar IC攻城狮求职宝典.rar linux basic.rar Linux EDA虚拟机 - 个人学习IC设计.rar Perl语言在芯片设计中的应用.rar SoC芯片设计技能专题.rar SystemVerilog Assertion断言理论与实践.rar SystemVerilog_Assertions_应用指南-源代码.rar uvm-1.2.rar VCS_labs.rar Verdi 基础教程.rar Verilog RTL 编码实践.rar [Cadence.IC设计.全资料教
UVM Class Reference Manual 1.2
04-11
对UVM-1.2标准的参考手册，在阅读uvm-1.2源码源码时结合起来看更便于理解
UVM的configuration机制
qq_40268672的博客
05-26 781
UVM的configuration机制uvm configuration机制特点UVM资源池添加配置资源获取配置资源config机制的使用单个变量使用configure机制interface使用configure机制总结 uvm configuration机制 uvm configuration是一个强大的属性配置工具，它： 1.可以传递值； 2.可以传递对象； 3.可以传递interface（virtual）； 特点 作为半个全局变量，避免全局变量带来的风险； 高层组件可以通过该机制实现在不改变代码的机
UVM_Class_Reference_Manual_1.2.pdf
09-12
UVM_Class_Reference_Manual_1.2.pdf用来查UVM中的phase啥的很是方便。目录很清晰。与之共享。
uvm-1.2_hidden871_universal_源码_uvm1.2_UVM_
10-03
通过分析`uvm-1.2`压缩包中的文件，我们可以逐个查看每个类的实现细节，理解它们如何协同工作以满足验证需求。同时，源码中包含的示例和测试平台也能帮助我们快速掌握UVM的使用技巧，提高我们的验证技能。 总之，...
UVM_Class_Reference_Manual_1.2_UVM_Class_reference_uvm1.2_
10-04
《UVM Class Reference Manual 1.2》是验证方法学（Unified Verification Methodology，简称UVM）中的核心文档，它详细介绍了UVM 1.2版本的类库及其使用方法。UVM是一种基于SystemVerilog的工业标准，用于硬件验证，...
uvm_users_guide_1.2.zip_UVM手册_site:www.pudn.com_uvm user guide 1
07-15
《UVM用户手册1.2版》是集成电路（IC）验证领域的一份重要参考资料，它详细介绍了统一验证方法学（Unified Verification Methodology, UVM）。UVM是一种基于SystemVerilog的验证方法，它为系统级验证提供了标准的...
ces_uvm-1.2_2016.06.tar源码.zip
09-29
标题中的“ces_uvm-1.2_2016.06.tar源码.zip”表明这是一款名为“ces_uvm”的软件的源代码，版本为1.2，发布于2016年6月，并且是通过.tar归档格式进行打包的。源代码通常是程序员用来构建软件的原始代码，它提供了...
uvm1.2源码
01-21
最新的uvm1.2源代码，深入学习uvm验证最佳的资料。
UVM Class Reference Manual v1.2
09-08
通用验证方法学(Universal Verification Methodology, UVM)在当今大规模数字集成电路前端验证领域是被广泛认可的方法，本文档为其手册，详细介绍了类与对象的属性，公用私用方法，便于学习与查询
UVM Users Guide 1.2
05-28
UVM Users Guide 1.2
UVM 1.2 Class Reference Manual.pdf
05-09
UVM 1.2 Class Reference Manual包含了UVM1.2的类，当做工具书查阅。
UVM_Class_Reference_Manual_1.2
05-04
UVM_Class_Reference_Manual_1.2 UVM用户必备查询手册，完整版。
UVM——configuration机制
weixin_45704530的博客
02-14 511
这里使用三个示例具体介绍uvm_config_db的用法 配置sequence产生transaction的数量 1、添加控制变量item_num 2、使用get()获取控制变量item_num的配置 获取： class my_sequence extends uvm_sequence #(my_transaction_da3); `uvm_object_utils(my_sequence) int item_num = 10; function new(string name
UVM 1.2
gjbt123的博客
08-04 329
来源红宝书
uvm-1.2 examples —— 1.2 makefile
hh199203的博客
12-02 3414
1. makefile 文章目录1. makefile前言一、pandas是什么？二、使用步骤1.引入库2.读入数据总结 前言 提示：这里可以添加本文要记录的大概内容： 例如：随着人工智能的不断发展，机器学习这门技术也越来越重要，很多人都开启了学习机器学习，本文就介绍了机器学习的基础内容。 一、pandas是什么？ 示例：pandas 是基于NumPy 的一种工具，该工具是为了解决数据分析任务而创建的。 二、使用步骤 1.引入库 代码如下（示例）： import numpy as np import
[UVM源代码研究] uvm中的factory机制（uvm-1.2版）
最新发布
sunstat的博客
03-20 1157
uvm中的factory机制（uvm-1.2版）
UVM-1.1d UVM_PHSAE源代码深度解析与实践指南
本文档主要对UVM-1.1d的UVM_PHSAE（UVM Phase System Architecture and Execution）源代码进行了深入分析。作者在2013年的国庆假期期间，结合《UVM1.1应用指南和源代码分析》以及《UVMphase的用法研究》等参考资料，...
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值