Groovy探索之MOP 四 使用ExpandoMetaClass来实现Mixin

              Groovy探索之MOP 四 使用ExpandoMetaClass来实现Mixin

 

 

国内很多的文章都在说Groovy语言的Mixin机制就是Groovy语言的Categories机制。其实,在外面的Blog上,大量有人在讨论Groovy语言应该如何实现它自己的Mixin机制,这就是说明Groovy语言的Mixin机制还没有定型,处在讨论之中。Categories机制当然也能实现部分的Mixin功能,就像Java语言的接口机制,还有组合等等,都能实现部分的Mixin功能。就像C++语言的多继承一样,这些"古老"的机制都能或多或少的实现部分的Mixin功能。

其实,Mixin机制也没有想象的那么神秘和复杂。从字面上来看,它是由"mix"和"in"两个单词组成,它们各自的意义是"混合"和"进来",翻译过来就是把别的类的功能"混合进来"的意思。从这个意义上讲,上面所讲到的所有技术,如"多继承"、"接口"、"组合"和"Categories"都能实现这个机制的部分功能,也就是编译期的Mixin功能。

但是,现在的Mixin机制所强调的不仅是能够混入进别的类的功能,更强调的是要在运行期内能够混入别的类的功能。这就是那些"古老"技术所不能解决的。

在讨论中的Groovy语言的Mixin功能,不但要实现编译期的Mixin功能,同时也要实现运行期的Mixin功能。

虽然Groovy语言的Mixin机制还没有定型,但由于Groovy语言对MOP的良好支持,所以,我们还是可以比较方便的使用Groovy语言的MOP机制来实现运行期的Mixin功能的。

任何问题的讨论都是从一个简单的例子开始的。

比如,我们现在有一个Window类,它里面有一个简单的方法,就是能够实现开窗的动作。如下:

 

class Window

{

    def open()

    {

       println 'the window is opened!'

    }

}

 

同时,我们还有一个Human类,这个类可能会很复杂,但为了简单起见,我们现在不打算实现它的很多功能,只是简单的表示有这么一个类。如下:

 

 

class Human {

   

    String name

 

}

 

 

 

现在,我们要操作的当然是Human的实例。本来这两个类是互不相关的,但现在Human的对象有了一个现实的要求,就是它需要能够实现"开窗"的动作。

当然,我们可以为Human类实现一个"openWindow"方法,但这一看就不符合面向对象设计的基本原则--类的功能要单一。

接下来的考虑是我们可以在Human类里使用Window类的"open"方法,这就要使用组合模式,也就实现了编译期的Mixin机制。但这种编译期的Mixin机制显然也太刚性了,可能我们在使用Human类的大多数场合都不会用到"openWindow"方法,却把它组合到Human类里。

最后,我们的考虑就是运行期的Mixin机制,这种实现肯定既实现了Mixin的功能,又抛弃了编译期的Mixin机制的弱点。

现在,我们就来实现运行期的Mixin机制,当然是借助于ExpandoMetaClass类的强大功能。

首先,我们来获取Window对象:

 

      def window = new Window()

 

 

接着,我们要在运行期内借用该对象的"open"方法:

 

      Human.metaClass.openWindow = window.&"open"

 

现在,我们就可以测试了:

 

      def human = new Human()

     

      human.openWindow()

 

 

运行的结果为:

the window is opened!

 

这就完成了一个简单的运行期的Mixin功能。

现在,我们的需求可能会在这个基础上进一步扩展,比如,有一个机器人也希望拥有开窗的功能,或者有一个自动装置也能开窗。这就需要把我们的Window类的"open"功能Mixin到不同的类中去。

当然,我们可以使用上面的方法,对每一个需要使用开窗功能的类使用ExpandoMetaClass类一一实现。

但既然有这么多类希望实现相同的功能,我们当然希望有一个工具来帮助我们简化我们的工作。

class Mixin {

   

    private targetClass

   

    def Mixin(targetClass)

    {

       this.targetClass = targetClass

    }

   

    def mixinWith(String asMethodName, Closure closure)

    {

       targetClass.metaClass."$asMethodName" = closure

    }

   

}

 

有了这个Mixin类,我们就可以这样实现Human类的开窗功能:

 

      def window = new Window()

     

      def m = new Mixin(Human)

     

      m.mixinWith("openWindow",window.&open)

     

      def human = new Human()

     

  human.openWindow()

 

这个Mixin帮忙类的功能就比较强大了,它可以把其他类的某个方法mixin到Human类去里;也可以把Window类的"open"方法mixin到其他的某个类中去。

甚至,我们可以直接会Human类添加一个方法,如:

 

      def m = new Mixin(Human)

 

      m.mixinWith('driveCar')

      {

         println 'The car is running'

      }

     

      def human = new Human()

     

      human.driveCar()

 

运行结果为:

The car is running

 

当然,你可能对Mixin类的"mixinWith"方法不满意,希望使用更加DSL的方法,那么我们就可以这样实现:

class Mixin {

   

    private targetClass

   

    def Mixin(targetClass)

    {

       this.targetClass = targetClass

    }

   

    def invokeMethod(String name,args)

    {

       if(name.startsWith('mixinAs'))

       {

           def methodName = name[7].toLowerCase()+name[8..-1]

           targetClass.metaClass."$methodName" = args[0]

       }

    }

   

 

}

 

然后,我们就可以这样使用Mixin类:

 

      def window = new Window()

     

  def m = new Mixin(Human)

 

      m.mixinAsOpenWindow window.&open

     

      def human = new Human()

     

      human.openWindow()

   

 

上面的代码行中,形如"m.mixinAsOpenWindow window.&open"就更有可读性。运行结果同样为:

the window is opened!

 

没有更多推荐了,返回首页