Groovy探索 “as”关键字的深入使用

                 Groovy探索 "as"关键字的深入使用

 

 

在前面的系列《Groovy Tip 20  "as"关键字的用法》中,我们已经谈到了"as"关键字的一些激动人心的用法。本篇则要接着前篇的内容说下去,继续来展现"as"关键字的一些更为激动人心的用法。

在前一篇中,我们谈到了"as"关键字的一个用法是进行类型转换。最常用的是形如下面的用法:

 

      def list = ['a','b','c']

     

      println list.class

     

      def strs = list as String[]

     

      println strs.class

   

 

这就是一个常用的类型转换的代码,从下面的打印结果可以看出,"as"关键字的使用的确使得变量进行了类型转换。

class java.util.ArrayList

class [Ljava.lang.String;

 

看到了这个用法,我们可能会想,"as"关键字的这个用法是如何实现的?我们如何想把自己设计的两个类之间进行相互转换,该如何实现。

比如说我们有如下的两个类:

class A

{

    def x

   

}

 

 

class B

{

    def x

}

 

如果我们已经得到了一个A类的对象,如下:

 

      def a = new A(x:3)

 

 

那么我们如何通过下面的语句获取到一个B类的对象呢?

 

      def b = a as B

 

其实,很简单,我们只需要在A类里实现"asType"方法即可,如下所示:

 

class A

{

    def x

   

    Object asType(Class type)

    {

       if(type == B) return new B(x:this.x+1)

    }

}

 

这是我们重写过的A类,那么我们现在就可以测试看看我们是否实现了上面所希望的功能:

 

      def a = new A(x:3)

     

      def b = a as B

     

      println b.class.simpleName

     

      println b.x

   

 

运行结果为:

B

4

 

可以看到,的确是实现了我们预想的功能。

 

除此之外,"as"关键字还有让我们惊奇的发现。比如,我们有如下的一个简单类:

 

class C

{

    def x

    def y

   

    public C(x,y)

    {

       this.x = x

       this.y = y

    }

}

 

那么,我们可以这样实例化它的一个实例:

 

      def list = [1,2]

     

      def c = list as C

     

      println c.class.simpleName

     

      println "${c.x},${c.y}"

 

运行的结果为:

C

1,2

 

 

这真是如魔幻一样。

 

且慢惊叹,再跟着我们看看下面的例子,比如,我们定义了如下的一个接口:

 

interface D

{

    def test_d()

}

 

我们就可以这样使用"as"关键字:

 

      def map = [test_d:{println 'ok'}]

     

      def d = map as D

     

      println d.class.simpleName

     

      d.test_d()

   

 

运行结果为:

$Proxy0

ok

 

 

真的是很酷吧!我们可以看到,"as"关键字是Groovy语言中是一个很重要的关键字,它的用法体现了Groovy语言作为一个动态语言的特点,一切都可以在运行期内在做决定,充分的展现了Groovy语言灵活、快捷的特点。

展开阅读全文

没有更多推荐了,返回首页