PowerBI可视化实战:商品销售动态ABC分析案例

本文详细介绍了商品销售ABC分析法,这是一种管理方法,用于区分商品的重点和一般性,通过销售占比划分A、B、C三类。文中展示了如何在KSOA时空医药软件数据库背景下建立销售分析模型,涉及商品档案、日期、销售数据等维度表和事实表的处理。关键步骤包括定义分析指标、设置ABC参数、处理元素价值和占比,并提供了动态设置和可视化报告的制作方法。案例虽未提供医药数据,但读者可通过回复获取销售数据源进行学习。
摘要由CSDN通过智能技术生成

在开始动手制作案例之前,大家首先跟随小黎子来一起了解商品销售中的ABC分析的定义。

1.商品销售ABC分析法是以商品销售为主线将商品划分为A、B、C类,商品销售从高到低,累计占比0至50%为A类商品,50%-90%为B类商品,90%-100%为C类商品

2.商品销售ABC分析法又称巴雷托分析法,它是根据事物在技术或经济方面的主要特征,进行分类排队,分清重点和一般,从而有区别地确定管理方式的一种分析方法。由于它把被分析的对象分成A、B、C三类,所以又称为ABC分析法。

3. 商品销售ABC分析法可以完成整体宏观分析要求,也可以满足单品的销售、毛利、成本、笔数等的分析和操作需求。

图片

该模型是基于KSOA时空医药软件的数据库建立的销售ABC分析模型,本案例中无法提供给大家医药数据源。大家可以通过小黎子数据分析公众号回复【销售】获取销售数据源进行学习了解。我们首先来看一下商品动态ABC分析中的构成元素:

1、分析指标、分析维度、元素名称都是我们可以自由选择的要被分析的对象,可以动态选择在右下角显示分析曲线

2、动态设置ABC参数的相对大小,可以通过调节ABC的参数大小来结合企业实际的分类占比进行分析商品

3、ABC分类总价值占比和全动态ABC分析都是展现最终结果的图表

接下来我们来看看是如何制作的。

一、处理需要的维度表和事实表

1、维度表:商品档案、日期

2、事实表:销售数据

图片

二、处理需要分析的维度和指标公式信息

  • 商品档案维度:商品类型、商品一级分类、商品二级分类、剂型、生产厂商、主治功能

  • 销售指标:销售笔数、销售成本、销售金额、销售毛利

  • 动态设置ABC参数

  • ABC元素价值指标处理

1、商品档案维度信息处理

实现动态ABC分析,就需要从商品档案中动态提取ABC元素。具体公式如下:

维度_ABC元素 =

VAR Products1 = SELECTCOLUMNS( ADDCOLUMNS( DISTINCT( '维度_商品档案'[主治功能] ) , "元素类型" , "主治功能" ) , "元素名称" , [主治功能] , "元素类型" , [元素类型] )

VAR Products2 = SELECTCOLUMNS( ADDCOLUMNS( DISTINCT( '维度_商品档案'[商品一级分类] ) , "元素类型" , "商品一级分类" ) , "元素名称" , [商品一级分类] , "元素类型" , [元素类型] )

VAR Products3 = SELECTCOLUMNS( ADDCOLUMNS( DISTINCT( '维度_商品档案'[商品二级分类] ) , "元素类型" , "商品二级分类" ) , "元素名称" , [商品二级分类] , "元素类型" , [元素类型] )

VAR Products4 = SELECTCOLUMNS( ADDCOLUMNS( DISTINCT( '维度_商品档案'[商品类型] ) , "元素类型" , "商品类型" ) , "元素名称" , [商品类型] , "元素类型" , [元素类型] )

VAR Products5 = SELECTCOLUMNS( ADDCOLUMNS( DISTINCT( '维度_商品档案'[剂型] ) , "元素类型" , "剂型" ) , "元素名称" , [剂型] , "元素类型" , [元素类型] )

VAR Products6 = SELECTCOLUMNS( ADDCOLUMNS( DISTINCT( '维度_商品档案'[生产厂商] ) , "元素类型" , "生产厂商" ) , "元素名称" , [生产厂商] , "元素类型" , [元素类型] )

RETURN UNION(  Products1,Products2,Products3,Products4,Products5,Products6 )

2、销售指标信息处理

销售指标是直接填写的ABC指标分类,在表中直接输入指标信息和排序即可

图片

  • 销售金额公式:销售金额 = SUM('事实_销售数据'[实收金额])

  • 销售毛利公式:销售毛利 = SUM('事实_销售数据'[毛利])

  • 销售笔数公式:销售笔数 = DISTINCTCOUNT('事实_销售数据'[单据编号])

  • 销售成本公式:销售成本 = SUM('事实_销售数据'[成本金额])

销售指标自动选择切换

销售 指标 自动 =

SWITCH( TRUE() ,

   SELECTEDVALUE( '维度_ABC指标分类'[指标名称] ) = "销售金额" , [销售金额] ,

   SELECTEDVALUE( '维度_ABC指标分类'[指标名称] ) = "销售毛利" , [销售毛利] ,

   SELECTEDVALUE( '维度_ABC指标分类'[指标名称] ) = "销售笔数" , [销售笔数] ,

   SELECTEDVALUE( '维度_ABC指标分类'[指标名称] ) = "销售成本" , [销售成本] ,

   [销售金额] // as default

)

3、动态ABC参数设置

首先我们需要输入ABC分类表

图片

在通过公式生成参数A\B\C

参数 ABC A = GENERATESERIES(0, 100, 1)

参数 ABC B = GENERATESERIES(0, 100, 1)

参数 ABC C = GENERATESERIES(0, 100, 1)

4、ABC元素指标价值处理

ABC 元素 价值 =  

VAR ItemRelationOfCustomer1 = TREATAS( VALUES( '维度_ABC元素'[元素名称] ) , '维度_会员'[性别] )

VAR ItemRelationOfCustomer2 = TREATAS( VALUES( '维度_ABC元素'[元素名称] ) , '维度_会员'[年龄 (组)] )

VAR ItemRelationOfProduct = TREATAS( VALUES( '维度_ABC元素'[元素名称] ) , '维度_商品档案'[商品类型] )

VAR ItemRelationOfProduct2 = TREATAS( VALUES( '维度_ABC元素'[元素名称] ) , '维度_商品档案'[主治功能] )

VAR ItemRelationOfProduct3 = TREATAS( VALUES( '维度_ABC元素'[元素名称] ) , '维度_商品档案'[商品一级分类] )

VAR ItemRelationOfProduct4 = TREATAS( VALUES( '维度_ABC元素'[元素名称] ) , '维度_商品档案'[商品二级分类] )

VAR ItemRelationOfProduct5 = TREATAS( VALUES( '维度_ABC元素'[元素名称] ) , '维度_商品档案'[剂型] )

VAR ItemRelationOfProduct6 = TREATAS( VALUES( '维度_ABC元素'[元素名称] ) , '维度_商品档案'[生产厂商] )

RETURN  

   SWITCH( TRUE() ,

     

       SELECTEDVALUE( '维度_ABC元素'[元素类型] ) = "性别" ,

       CALCULATE( [销售 指标 自动] , ItemRelationOfCustomer1 ) ,

       SELECTEDVALUE( '维度_ABC元素'[元素类型] ) = "年龄 (组)" ,

       CALCULATE( [销售 指标 自动] , ItemRelationOfCustomer2 ) ,

       SELECTEDVALUE( '维度_ABC元素'[元素类型] ) = "商品类型" ,

       CALCULATE( [销售 指标 自动] , ItemRelationOfProduct ) ,

        SELECTEDVALUE( '维度_ABC元素'[元素类型] ) = "主治功能" ,

       CALCULATE( [销售 指标 自动] , ItemRelationOfProduct2 ) ,

        SELECTEDVALUE( '维度_ABC元素'[元素类型] ) = "商品一级分类" ,

       CALCULATE( [销售 指标 自动] , ItemRelationOfProduct3 ) ,

        SELECTEDVALUE( '维度_ABC元素'[元素类型] ) = "商品二级分类" ,

       CALCULATE( [销售 指标 自动] , ItemRelationOfProduct4 ) ,

        SELECTEDVALUE( '维度_ABC元素'[元素类型] ) = "剂型" ,

       CALCULATE( [销售 指标 自动] , ItemRelationOfProduct5 ) ,

        SELECTEDVALUE( '维度_ABC元素'[元素类型] ) = "生产厂商" ,

       CALCULATE( [销售 指标 自动] , ItemRelationOfProduct6 ) ,

     

       BLANK()

   )

ABC 元素 价值 占比 =

VAR Items = CALCULATETABLE( DISTINCT( '维度_ABC元素'[元素名称] ) , ALLSELECTED( '维度_ABC元素'[元素名称] ) )

VAR Total = CALCULATE( [ABC 元素 价值] , Items )

VAR CurrentItemValue = [ABC 元素 价值]

RETURN DIVIDE( CurrentItemValue , Total )

ABC 元素 价值 占比 按分类 =

IF( SELECTEDVALUE( '维度_ABC分类'[ABC分类名称] ) = [ABC 元素 所属分类] , [ABC 元素 价值 占比] , BLANK() )

ABC 元素 价值 累计占比位 =

VAR Items = CALCULATETABLE( DISTINCT( '维度_ABC元素'[元素名称] ) , ALLSELECTED( '维度_ABC元素'[元素名称] ) )

VAR Total = CALCULATE( [ABC 元素 价值] , Items )

VAR CurrentItemValue = [ABC 元素 价值]

VAR CumulativeValue = CALCULATE(

   [ABC 元素 价值] , FILTER( Items , [ABC 元素 价值] >= CurrentItemValue )

)

RETURN DIVIDE( CumulativeValue , Total )

ABC 元素 价值 累计占比位 按分类 =

IF( SELECTEDVALUE( '维度_ABC分类'[ABC分类名称] ) = [ABC 元素 所属分类] , [ABC 元素 价值 累计占比位] , BLANK() )

ABC 参数 A = [参数 ABC A 值] / ( [参数 ABC A 值] + [参数 ABC B 值] + [参数 ABC C 值] )

ABC 参数 B = ( [参数 ABC A 值] + [参数 ABC B 值] ) / ( [参数 ABC A 值] + [参数 ABC B 值] + [参数 ABC C 值] )

ABC 参数 占比 =

SWITCH( TRUE() ,

   SELECTEDVALUE( '维度_ABC分类'[ABC分类名称] ) = "A" , [参数 ABC A 值] / ( [参数 ABC A 值] + [参数 ABC B 值] + [参数 ABC C 值] ) ,

   SELECTEDVALUE( '维度_ABC分类'[ABC分类名称] ) = "B" , [参数 ABC B 值] / ( [参数 ABC A 值] + [参数 ABC B 值] + [参数 ABC C 值] )  ,

   SELECTEDVALUE( '维度_ABC分类'[ABC分类名称] ) = "C" , [参数 ABC C 值] / ( [参数 ABC A 值] + [参数 ABC B 值] + [参数 ABC C 值] )  ,

   BLANK()

)

   

ABC 元素 所属分类 =

VAR CurrentItemCumulativePrecent = [ABC 元素 价值 累计占比位]

RETURN SWITCH( TRUE() ,

   CurrentItemCumulativePrecent >= [ABC 参数 B] , "C" ,

   CurrentItemCumulativePrecent >= [ABC 参数 A] , "B" ,

   "A"

)

ABC 类别 价值 =

VAR CurrentABCCategory = SELECTEDVALUE( '维度_ABC分类'[ABC分类名称] )

VAR Items = CALCULATETABLE( DISTINCT( '维度_ABC元素'[元素名称] ) , ALLSELECTED( '维度_ABC元素'[元素名称] ) )

RETURN CALCULATE( [ABC 元素 价值] , FILTER( Items , [ABC 元素 所属分类] = CurrentABCCategory ) )

ABC 类别 价值 占比 = DIVIDE( [ABC 类别 价值] , CALCULATE( [ABC 元素 价值] , ALLSELECTED( '维度_ABC元素'[元素名称] ) ) )

三、制作前端可视化报告

1、分析指标切片器:直接勾选维度_ABC指标分类中的指标名称即可,切片器样式选择下拉

图片

2、动态设置ABC参数的相对大小切片器:直接分别勾选参数ABC A、参数ABC B或者参数ABC C。切片器样式上开启滑块

图片

3、分析维度切片器:直接勾选维度_ABC元素中的元素类型,切片器样式选择下拉

图片

4、元素名称切片器:直接勾选维度_ABC元素中的元素名称,切片器样式选择列表

图片

5、ABC分类总价值占比:选择条形图,勾选维度_ABC分类中的ABC分类名称

图片

6、全动态ABC分析是本文核心的展现区域,它主要通过折线和柱状图来实现的效果。

图片

四、总结

本文中制作商品动态销售ABC分析法的关键就是在于滚动计算要分析的指标,也可以灵活的使用要分析的维度信息。当然本文中还缺少了时间维度的切片设置,大家可以根据实际的情况进行加上时间切片器即可。文中的小黎子并没有非常仔细的去描述细节,对于学习的新手来说可能比较复杂一点。当然大家在制作过程中遇到任何问题欢迎联系小黎子,我们一起成长。该项目使用的用友时空的数据源,涉及用户信息不方便分享。大家如果手上没有数据源可以通过回复客户分析报告获取示例数据源练手。最终我们实现的效果如下:

图片

评论 4
添加红包

请填写红包祝福语或标题

红包个数最小为10个

红包金额最低5元

当前余额3.43前往充值 >
需支付:10.00
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包

打赏作者

黄昏前黎明后

你的鼓励将是我创作的最大动力

¥1 ¥2 ¥4 ¥6 ¥10 ¥20
扫码支付:¥1
获取中
扫码支付

您的余额不足,请更换扫码支付或充值

打赏作者

实付
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明:

1.余额是钱包充值的虚拟货币,按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载,可以购买VIP、付费专栏及课程。

余额充值