操作TreeView

最新推荐文章于 2024-04-01 19:17:30 发布
最新推荐文章于 2024-04-01 19:17:30 发布
阅读量382 收藏
点赞数
文章标签： query string integer button 数据库 windows
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/hnxxcxg/article/details/2864536
版权

{*******************************************************}
{                                                       }
{       操作TreeView                                    }
{                                                       }
{       版权所有 (C) 2008 咏南工作室                    }
{                                                       }
{*******************************************************}

//==============================================================================
// 本单元实现了TreeView与数据的关联，各方法形参如下：
//
//            AId：为自增字段，用于标识节点的编号。
//            AParentId：用来表示当前节点的父节点。
//            ACaption:用来表示在树中所要显示的内容。
//==============================================================================


unit dbtree;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, ComCtrls, DB, ADODB;

{-------------------------------------------------------------------------------
  过程名:    MakeTree
  说明:      创建树
  作者:      cxg
  日期:      2008.08.21
  参数:      Query: TADOQuery; TableName: string; TreeView: TTreeView;AParentId,AId:string
  返回值:    无
-------------------------------------------------------------------------------}
procedure MakeTree(Query: TADOQuery; TableName: string; TreeView: TTreeView;AParentId,AId:string);

{-------------------------------------------------------------------------------
  过程名:    AddNode
  说明：     增加树的节点
  作者:      cxg
  日期:      2004.12.07
  参数:      Query: TADOQuery; TreeView: TTreeView
  参数说明： Query:相关联的数据库;TreeView: 所使用的树
  返回值:    无
-------------------------------------------------------------------------------}
procedure AddNode(Query: TADOQuery; TreeView: TTreeView;AParentId,ACaption:string);

{-------------------------------------------------------------------------------
  过程名:    AddChildNode
  说明：     增加树的子节点
  作者:      cxg
  日期:      2004.12.07
  参数:      Query: TADOQuery; TreeView: TTreeView
  参数说明： Query:相关联的数据库;TreeView: 所使用的树
  返回值:    无
-------------------------------------------------------------------------------}
procedure AddChildNode(Query: TADOQuery; TreeView: TTreeView;AParentId,AId,ACaption:string);
{-------------------------------------------------------------------------------
  过程名:    AddTreeNode
  说明：     增加节点（内部使用的过程）
  作者:      cxg
  日期:      2004.12.07
  参数:      Query: TADOQuery; TreeView: TTreeView; bj: boolean = false
  参数说明： Query:相关联的数据库;TreeView: 所使用的树;bj:是否将焦点移到当前选择的节点
  返回值:    无
-------------------------------------------------------------------------------}
procedure AddTreeNode(Query: TADOQuery; TreeView: TTreeView; bj: boolean = false);

{-------------------------------------------------------------------------------
  过程名:    DelTree
  说明：     删除节点（包括删除本节点下的所有子节点）
  作者:      cxg
  日期:      2004.12.07
  参数:      query: TAdoQuery; TreeView: TTreeView
  参数说明： Query:相关联的数据库;TreeView: 所使用的树
  返回值:    无
-------------------------------------------------------------------------------}
procedure deltree(query: TAdoQuery; TreeView: TTreeView;AID:string);

{-------------------------------------------------------------------------------
  过程名:    Treechange
  说明：     在树中选择了一个节点，将数据库的游标移动到所选择的节点所对应记录
  作者:      cxg
  日期:      2004.12.07
  参数:      query: TADOQuery; node: TTreenode
  参数说明： Query:相关联的数据库;TreeView: 所使用的树
  返回值:    无
-------------------------------------------------------------------------------}
procedure Treechange(query: TADOQuery; node: TTreenode);

{-------------------------------------------------------------------------------
  过程名:    Treeedit
  说明：     树中的节点内容已经作了修改，将所修改的内容更新回数据库
  作者:      cxg
  日期:      2004.12.07
  参数:      query: TADOQuery; text: string
  参数说明： Query:相关联的数据库;TreeView: 所使用的树
  返回值:    无
-------------------------------------------------------------------------------}
procedure TreeEdit(query: TADOQuery; text: string;ACaption:string);

{-------------------------------------------------------------------------------
  过程名:    treeselect
  说明：     数据库中的游标已经移动，将焦点移到树中对应的节点
  作者:      cxg
  日期:      2004.12.07
  参数:      query: Tadoquery; TreeView: TTreeView
  参数说明： Query:相关联的数据库;TreeView: 所使用的树
  返回值:    无
-------------------------------------------------------------------------------}
procedure treeselect(query: Tadoquery; TreeView: TTreeView;AId:string);

{-------------------------------------------------------------------------------
  函数名:    TreeFind
  说明：     找出给定的内容，并移动数据库中的游标，同时将焦点移到树中对应的节点
  作者:      cxg
  日期:      2004.12.07
  参数:      TreeView: TTreeView; text: string
  参数说明： TreeView: 所使用的树 text: 要查找的内容
  返回值:    True：找到　　False:找不到
-------------------------------------------------------------------------------}
function TreeFind(TreeView: TTreeView; text: string): boolean;

implementation

var
  List: TStringList; //用于记录各个id及其在树中所对应的节点,从而实现快速查找

procedure MakeTree(Query: TADOQuery; TableName: string; TreeView: TTreeView;AParentId,AId:string);
begin
  TreeView.Items.BeginUpdate;
  list.Clear;
  TreeView.items.clear;
  if query.Active then query.Close;
  Query.SQL.Text := 'SELECT * FROM ' + TableName + ' ORDER BY '+AParentId+','+AId;
  Query.Open;
  query.DisableControls;
  TreeView.Items.Clear;
  list.Clear;
  List.Sorted := True;
  query.First;
  while not Query.Eof do
  begin
    addtreenode(Query, TreeView); //依次增加所有的节点
    Query.Next;
  end;
  TreeView.Items.EndUpdate;
  query.EnableControls;
  if treeview.Items.Count < 1 then exit;
  treeview.Select(treeview.Items.Item[0]);
  treeview.SetFocus;
end;

procedure addtreenode(Query: TADOQuery; TreeView: TTreeView; bj: boolean = false);
var
  index: integer;
  Node: TTreeNode;
begin
  if Query.FieldByName('PID').AsInteger = 0 then { ParentID=0，顶层节点 }
    Node := TreeView.Items.AddChildObject(nil, Query.FieldByName('CAPTION').AsString, query.GetBookmark)
//增加节点，并将本节点所对应的记录标签数据放到节点所提供的附加数据中
  else
  begin
    Index := List.IndexOf(Query.FieldByName('PID').AsString);
    Node := TreeView.Items.AddChildObjectFirst(TTreeNode(List.Objects[Index]),
      Query.FieldByName('CAPTION').AsString, query.GetBookmark);
//增加子节点，并将本节点所对应的记录标签数据放到节点所提供的附加数据中
  end;
//增加当前节点的信息到列表中，以实现在列表中快速查找节点的功能。
  List.AddObject(Query.FieldByName('ID').AsString, Node);
  if bj then
  begin
    treeview.Select(node);
    treeview.SetFocus;
  end;
end;

procedure deltree(query: TAdoQuery; TreeView: TTreeView;AID:string);
var
  node: TTreenode;
  //删除当前选择的节点下的所有节点（不删除当前选择的节点）
  procedure delnode(node: TTreenode);
  var
    i: integer;
    childnode: TTreenode;
  begin
    for i := 0 to node.Count - 1 do
    begin
      childnode := node.Item[i];                                   //取当前节点下的所有节点
      query.GotoBookmark(childnode.Data);                          //移到节点所对应的记录
      list.Delete(list.IndexOf(query.FieldByName(AID).AsString)); //删除列表中的数据
      query.Delete;                                                //删除对应的记录
      if node.HasChildren then delnode(childnode);                 //有子节点则递归直到所有的数据删除完毕
    end;
  end;

begin
  node := treeview.Selected;
  if node = nil then exit;
//删除当前选择的节点下的所有节点（不删除当前选择的节点）
  delnode(node);
//删除当前选择的节点
  query.GotoBookmark(node.Data);
  list.Delete(list.IndexOf(query.FieldByName(AID).AsString));
  query.Delete;
  node.Delete;
  TreeView.SetFocus;
end;

procedure AddChildNode(Query: TADOQuery; TreeView: TTreeView;AParentId,AId,ACaption:string);
var
  id: integer;
begin
  id := query.FieldByName(AId).AsInteger; //记下当前的节点编号
  query.Append;
  query.FieldByName(AParentId).AsInteger := id; //新增加的子节点的父节点编号即为id
  query.FieldByName(ACaption).AsString := '新子节点';
  query.post;
  addtreenode(query, treeview, true);
end;

procedure AddNode(Query: TADOQuery; TreeView: TTreeView;AParentId,ACaption:string);
var
  pid: integer;
begin
  pid := query.FieldByName(AParentId).AsInteger; //记下当前节点的父节点编号
  query.Append;
  query.FieldByName(AParentId).AsInteger := pid; //新增加的子节点的父节点编号即为pid
  query.FieldByName(ACaption).AsString := '新节点';
  query.post;
  addtreenode(query, treeview, true);
end;

procedure Treechange(query: TADOQuery; node: TTreenode);
begin
  query.GotoBookmark(node.Data);
end;

procedure TreeEdit(query: TADOQuery; text: string;ACaption:string);
begin
  query.Edit;
  query.FieldByName(ACaption).AsString := text;
  query.post;
end;

procedure treeselect(query: Tadoquery; TreeView: TTreeView;AId:string);
var
  index: integer;
  Node: TTreeNode;
begin
  Index := List.IndexOf(Query.FieldByName(AId).AsString);
  Node := TTreeNode(List.Objects[Index]);
  treeview.Selected := Node;
  treeview.SetFocus;
end;

function TreeFind(TreeView: TTreeView; text: string): boolean;
var
  i: integer;
begin
  Result := false;
  for i := 0 to treeview.Items.Count - 1 do
  begin
    if treeview.Items.Item[i].Text = text then
    begin
      treeview.Select(treeview.Items.Item[i]);
      treeview.SetFocus;
      Result := true;
      exit;
    end;
  end;
end;

initialization
  List := TStringList.Create;

finalization
  list.Free;

end.

 

//调用演示(鼠标拖放移动节点)---------------------------------------------

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  DB, ADODB, StdCtrls, ExtCtrls, Grids, DBGrids, ComCtrls, dialogs;

type
  TForm1 = class(TForm)
    TreeView1: TTreeView;
    DBGrid1: TDBGrid;
    Panel1: TPanel;
    Button1: TButton;
    Button2: TButton;
    Button3: TButton;
    Splitter1: TSplitter;
    Splitter2: TSplitter;
    btn2: TButton;
    Button4: TButton;
    Edit1: TEdit;
    ADOQuery: TADOQuery;
    ds1: TDataSource;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure TreeView1Change(Sender: TObject; Node: TTreeNode);
    procedure Button3Click(Sender: TObject);
    procedure TreeView1Edited(Sender: TObject; Node: TTreeNode; var S: string);
    procedure btn2Click(Sender: TObject);
    procedure DBGrid1MouseUp(Sender: TObject; Button: TMouseButton;
      Shift: TShiftState; X, Y: Integer);
    procedure Button4Click(Sender: TObject);
    procedure TreeView1DragOver(Sender, Source: TObject; X, Y: Integer;
      State: TDragState; var Accept: Boolean);
    procedure TreeView1DragDrop(Sender, Source: TObject; X, Y: Integer);
  private
     { Private declarations }
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

uses dbtree;

{$R *.dfm}


procedure TForm1.Button1Click(Sender: TObject);
begin
  MakeTree(ADOQuery, 'dir', TreeView1,'pid','id');  //创建树
end;

procedure TForm1.Button3Click(Sender: TObject);
begin
  addnode(adoquery, treeview1,'pid','caption');           //增加节点
end;

procedure TForm1.Button2Click(Sender: TObject);
begin
  addchildnode(adoquery, treeview1,'pid','id','caption');       //增加子节点
end;

procedure TForm1.TreeView1Change(Sender: TObject; Node: TTreeNode);
begin
  treechange(adoquery, node);
end;

procedure TForm1.TreeView1Edited(Sender: TObject; Node: TTreeNode;
  var S: string);
begin
  Treeedit(adoquery, s, 'caption');
end;

procedure TForm1.btn2Click(Sender: TObject);
begin
  deltree(adoquery, treeview1,'id');          //删除树
end;

procedure TForm1.DBGrid1MouseUp(Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
begin
  treeselect(adoquery, treeview1,'id');
end;

procedure TForm1.Button4Click(Sender: TObject);
begin
  if not TreeFind(treeview1,edit1.text) then
    showmessage('找不到。');
end;

procedure TForm1.TreeView1DragOver(Sender, Source: TObject; X, Y: Integer;
  State: TDragState; var Accept: Boolean);
begin
  Accept := False ;
  if (source is TTreeView) or (source is TListview) then
    Accept := true ;
end;

procedure TForm1.TreeView1DragDrop(Sender, Source: TObject; X, Y: Integer);
var
  tSrcNode ,tDesNode: TTreeNode ;
  tSrcID ,tDesID : Integer ;
  sSql : String ;
  lSrcItem : TListItem ;
  DestNodeId:string;
begin
  tSrcID := 0 ;tDesID := 0 ;

  tDesNode := TTreeview(Sender).GetNodeAt(X,Y);
  Treechange(ADOQuery,tDesNode);
  DestNodeId:=ADOQuery.FieldValues['id'];

  if Source is TTreeview then
  begin
    TTreeview(Sender).Items.BeginUpdate;

    tSrcNode := TTreeview(Source).Selected ;
    tSrcNode.Moveto(tDesNode,naAddChild);
    Treechange(ADOQuery,tSrcNode);
    ADOQuery.Edit;
    ADOQuery.FieldValues['pid']:=DestNodeId;
    ADOQuery.Post;

    TTreeview(Sender).Items.EndUpdate;
  end
end;

end.

hnxxcxg
关注
Tree View
akakz的博客
12-14 99
Tree View控件的基本操作 效果 可以用imagelist给节点加上小图标 TreeView 默认节点样式 selectdimageindex就是图标选中了之后出现的图标 效果 单个节点个性设置样式 节点的深度 TreeView对象.SelectedNode.Level 返回值是int类型 根节点的level是0 节点的文本 TreeView对象.SelectedNode.Text ...
Treeview
05-29
Treeview的实例，具备添加、删除、修改、拖动节点的功能。
TreeView
zoujinjishu的专栏
10-11 6703
TreeView ASP.NET TreeView 控件是一个用于呈现 TreeView UI 的功能强大的服务器控件，如下图中所示。该控件支持各种编程模型，从静态定义的树、到动态构造的树以及数据绑定的树几乎无所不包。TreeView 的呈现是可以完全自定义的，从而允许该控件具有多种外观。TreeView 支持回发样式的事件以及简单的超链接导航，还支持唯一的事件处理模型，该模型允许从客户端直
TTreeView学习
weixin_30372371的博客
05-24 146
详细参考：http://www.cnblogs.com/del/archive/2008/03/10/1098798.html 1，什么是TTreeView，TTreeNodes，TTreeNode ？ 打个比方: 譬如 TreeView 是一个军营的"营部"! 这里会有营长、连长、排长、班长、战士等等.我们把它们分成三种对象: 营部、营长(总当家)、营长的下属.在这里的对应关系是:TTre...
treeview
wang_yuanyuan1的专栏
11-29 890
今天学习了使用TreeView控件：使用站点地图完成对treeview的显示。用代码动态添加，使之在服务器中显示所要的效果，还可以用treeview 控件在代码区中调用数据库中的表格中的信息按某个字段进行排序然后调用它。using System; using System.Collections.Generic; using System.Linq; using System.Web; u
VBA操作treeview
05-13
### VBA操作TreeView：实现节点上移与子节点交换 #### 概述 在VBA中，`TreeView` 控件是一种非常实用的功能组件，用于显示具有层级关系的数据。本文将详细介绍如何通过VBA来实现`TreeView`控件中的节点上移功能...
专门操作Treeview目录树和数据库的Delphi类及示例
05-16
内容索引:Delphi源码,控件组件,TreeView,树形菜单,目录树　自己写的一个专门用来操作Treeview树形菜单和数据库的Delphi操作类，读取数据库中的数据自动添加到Treeview控件中，这里的数据控件用的是ADO，公用单元：...
易语言操作treeview20wndclass
01-08
易语言是一种使用简单、易学易用的编程语言，它可以用于操作TreeView控件的WNDCLASS。在易语言中，可以通过TreeView控件的WNDCLASS实现对TreeView控件的操作和管理。 首先，我们需要使用CreateWindow函数创建...
客户端操作TreeView的一些方法
04-14
### 客户端操作TreeView的一些方法 在Web开发过程中，TreeView控件因其强大的层次结构展示功能而被广泛应用于各类项目中。然而，对于前端开发者来说，如何有效地在客户端操作TreeView一直是一个较为复杂的问题，但...
Delphi中快速实现数据库树形结构并实现Treeview导航表数据
08-01
在本教程中，我们将探讨如何快速地在Delphi中实现这样的功能，利用TreeView组件来导航数据库表的数据。我们将重点关注以下几个方面： 1. **数据库连接与查询**：首先，我们需要连接到数据库。在Delphi中，可以使用...
TreeView.txt
05-11
当我选择一个父节点，希望该父节点下所有的子节点都被选中，取消一个节点，希望他所有的父节点都取消
好看的Winform.TreeView
03-25
自定义的美化TreeView源码和对应demo，样式好看，对初学者是很好的学习资料，然后也可用于项目中
TreeView简单介绍
proglover66的专栏
07-26 3199
TreeView : TreeView是一个IMGUI控件，可以让您为编辑器创建树视图、列表视图和多列表。它可以自定义行内容呈现、拖拽逻辑、选择逻辑、搜索、排序和项目重命名. TreeView类中两个重要的函数： BuildRoot():是一个需要被实现的抽象方法。该方法应该创建treeviewitem的完整树并返回根目录。这个方法和BuildRows一起实现TreeView的初始化工作。
TreeView详解（转载）
weixin_34177064的博客
06-22 669
TreeView详解（转载） TreeView 控件响应一些我们觉的VFP 控件的方法和事件: Click, DblClick, Drag, DragDrop, DragOver, GotFocus, KeyDown, KeyPress, KeyUp, LostFocus, MouseDown, MouseMove, MouseUp, Move, Refresh, SetF...
使用TreeView树状图
qq_42820903的博客
11-11 522
使用TreeView树状图 转址进入页面后可看见如图 Demo 使用的就是TreeView菜单，在页面进行展示实验 website 进入示例之后看见导入项目 可直接下载Demo 不使用样式的话可在SRC中 找到 EasyTree.js 直接使用也可出以上效果 ...
WPF —— TreeView树形控件
最新发布
一个新人博客，愿多多支持。
04-01 2374
TreeView 表示一个控件，该控件在树结构（其中的项可以展开和折叠）中显示分层数据。TreeView 是一个 ItemsControl，这意味着它可以包含任何类型的对象的集合 (，例如字符串、图像或面板)。
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值