S3C2416裸机开发系列二
汇编入门代码以及sd卡启动
象棋小子 1048272975
学习了arm，笔者认为就有必要学习arm的汇编语言。对于软件出错调试，往往需要跟踪c编译器生成的汇编代码和链接器生成的Mapping文件等。对于操作系统，bootloader之类的移植，必须熟悉汇编代码，因为移植涉及到体系结构相关的部分只有汇编代码才能胜任，其它高级语言均无能为力。
1. 流水灯硬件原理图
6个LED分别接到GPA，GPE，GPG，GPL对应的I/O控制引脚上，I/O口由3.3V供电，当对应I/O口输出为1时，则点亮相应的LED，输出为0时，相应的LED灭掉。对于不同的开发板，灯的GPIO口控制不一样，需修改代码的控制口。
2. 工程搭建
打开Keil MDK，版本不是问题，只要能编译armv4指令(arm7/arm9)即可。Project->NewuVersion Project，保存项目后，会出现cpu选择界面，目前最新版本的MDK在Samsung目录下可以找到S3C2416的选项，但还是没有启动代码的。由于我们编写的是汇编程序，此时也无需启动代码，为了说明代码开发只与架构、指令集相关，与各个厂商不同的外设，特殊功能寄存器的定义无关。笔者选择NXP下arm7芯片LPC2103，然后会提示是否加入LPC2103的启动代码到工程，此处即使用c开发S3C2416，LPC2103的启动代码都是不适用的，当然选择不要加入工程。
3. 代码编写
创建一个新文件，命名为LEDs.s，.s为arm汇编文件后缀，保存并加入工程。汇编的一些基本用法请google，百度。这里需要说明的是，arm架构的cpu上电复位后都是从地址0x00000000开始执行代码的，并且异常向量进入地址都是0x0偏移处。当然有些厂商的芯片内部固化了芯片bootloader，芯片上电复位后是先执行厂商固化代码(理论上此时第一条固化代码的指令还是在0地址处)，用来检测相应的引脚配置，如NXP的LPC系列检测到相应的配置后可以进入到ISP下载模式，通过串口进行代码的烧录，如新唐的NUC501在复位上电后可以配置进入USB下载模式，通过USB进行代码的烧录。这些厂商的固化代码执行完后，可能会对内存重映射，此时用户的入口代码地址可能还会是0x00000000，也可能是其它地址。如笔者此时讲解的S3C2416在nand boot后，内部RAM地址会映射到0地址处，用户代码是从0地址开始执行的。但在IROM boot后，内部RAM地址会映射到0x40000000地址处，用户代码是从0x40000000地址开始执行的。
; InternalMemory Base Addresses(IROM boot)
IRAM_BASE EQU 0x40000000
; Watchdog TimerBase Address
WT_BASE EQU 0x53000000
; IO port forcontroling LEDs
GPA_BASE EQU 0x56000000 ; GPA Base Address
GPE_BASE EQU 0x56000040 ; GPE Base Address
GPG_BASE EQU 0x56000060 ; GPG Base Address
GPL_BASE EQU 0x560000F0 ;GPL Base Address
GPCON_OFS EQU 0x00 ; Control RegisterOffset
GPDAT_OFS EQU 0x04 ; Data Register Offset
GPE13_LED2 EQU 13 ; GPE13->LED2
GPE11_LED3 EQU 11 ; GPE11->LED3
GPL13_LED4 EQU 13 ; GPL13->LED4
GPE12_LED5 EQU 12 ; GPE12->LED5
GPG2_LED6 EQU 2 ; GPG2->LED6
GPA15_LED7 EQU 15 ; GPA15->LED7
;-----------------------CODE ----------------------------------
PRESERVE8
AREA RESET, CODE, READONLY
ENTRY
ARM
Start
LDR R0, =WT_BASE
MOV R1, #0
STR R1, [R0] ; 关看门狗
BL GPIO_Init
Loop
LDR R1,=GPE_BASE
LDR R2,[R1, #GPDAT_OFS]
ORR R2,R2, #(1<<GPE13_LED2)
STR R2,[R1, #GPDAT_OFS] ; GPE13 LED2亮
LDR R0, =1000 ; 传参，延时1000*1ms
BL Delay_ms
BIC R2,R2, #(1<<GPE13_LED2)
STR R2,[R1, #GPDAT_OFS] ; GPE13 LED2灭
LDR R0,=1000 ; 延时1s
BL Delay_ms
LDR R1,=GPE_BASE
LDR R2,[R1, #GPDAT_OFS]
ORR R2,R2, #(1<<GPE11_LED3)
STR R2,[R1, #GPDAT_OFS] ; GPE11 LED3亮
LDR R0,=1000
BL Delay_ms
BIC R2,R2, #(1<<GPE11_LED3)
STR R2,[R1, #GPDAT_OFS] ; GPE11 LED3灭
LDR R0,=1000
BL Delay_ms
LDR R1,=GPL_BASE
LDR R2,[R1, #GPDAT_OFS]
ORR R2,R2, #(1<<GPL13_LED4)
STR R2,[R1, #GPDAT_OFS] ; GPL13 LED4亮
LDR R0,=1000
BL Delay_ms
BIC R2,R2, #(1<<GPL13_LED4)
STR R2,[R1, #GPDAT_OFS] ; GPL13 LED4灭
LDR R0,=1000
BL Delay_ms
LDR R1,=GPE_BASE
LDR R2,[R1, #GPDAT_OFS]
ORR R2,R2, #(1<<GPE12_LED5)
STR R2,[R1, #GPDAT_OFS] ; GPE12 LED5亮
LDR R0,=1000
BL Delay_ms
BIC R2,R2, #(1<<GPE12_LED5)
STR R2,[R1, #GPDAT_OFS] ; GPE12 LED5灭
LDR R0,=1000
BL Delay_ms
LDR R1,=GPG_BASE
LDR R2,[R1, #GPDAT_OFS]
ORR R2,R2, #(1<<GPG2_LED6)
STR R2,[R1, #GPDAT_OFS] ; GPG2 LED6亮
LDR R0,=1000
BL Delay_ms
BIC R2,R2, #(1<<GPG2_LED6)
STR R2,[R1, #GPDAT_OFS] ; GPG2 LED6灭
LDR R0,=1000
BL Delay_ms
LDR R1,=GPA_BASE
LDR R2,[R1, #GPDAT_OFS]
ORR R2,R2, #(1<<GPA15_LED7)
STR R2, [R1, #GPDAT_OFS] ; GPA15 LED7亮
LDR R0,=1000
BL Delay_ms
BIC R2,R2, #(1<<GPA15_LED7)
STR R2,[R1, #GPDAT_OFS] ; GPA15 LED7灭
LDR R0,=1000
BL Delay_ms
B Loop
GPIO_Init
LDR R0,=GPA_BASE
LDR R1,[R0]
BIC R1,R1, #(1<<GPA15_LED7) ; GPA15 output
STR R1,[R0]
LDR R1,[R0, #GPDAT_OFS]
BIC R1,R1, #(1<<GPA15_LED7) ; GPA15 LED7灭
STR R2,[R0, #GPDAT_OFS]
LDR R0,=GPE_BASE
LDR R1,[R0]
BIC R1,R1, #(0x3<<(GPE13_LED2<<1))
BIC R1,R1, #(0x3<<(GPE11_LED3<<1))
BIC R1,R1, #(0x3<<(GPE12_LED5<<1))
ORR R1,R1, #(0x1<<(GPE13_LED2<<1)) ; GPE13 output
ORR R1,R1, #(0x1<<(GPE11_LED3<<1)) ; GPE11 output
ORR R1,R1, #(0x1<<(GPE12_LED5<<1)) ; GPE12 output
STR R1,[R0]
LDR R0,=GPG_BASE
LDR R1,[R0]
BIC R1,R1, #(0x3<<(GPG2_LED6<<1))
ORR R1,R1, #(0x1<<(GPG2_LED6<<1)) ; GPG2 output
STR R1,[R0]
LDR R0,=GPL_BASE
LDR R1,[R0]
BIC R1,R1, #(0x3<<(GPL13_LED4<<1))
ORR R1,R1, #(0x1<<(GPL13_LED4<<1)) ; GPL13 output
STR R1, [R0]
BX LR
; 软件延时函数，arm汇编较精确计算，共延时R0*1ms
; 由于暂未设置时钟，用系统上电复位默认的ARM CLOCK
; 对于nand boot，ARM CLOCK = 12M(外部晶体12M)
; 对于IROM boot，ARM CLOCK = 120M(外部晶体12M)
; 这段汇编延时函数从sd卡启动，用的是IROM boot，120M
Delay_ms
; 函数用到R1寄存器，压栈，以免函数调用前R1数据被覆盖
STMFD SP!, {R1} ; 此时也是采用上电复位后的栈
Delay1
LDR R1, =30000 ; ARM CLOCK 120M计(IROMboot)
Delay2
SUBS R1, R1, #1 ; 指令执行需1个ARMCLOCK
BNE Delay2 ; 跳转会清流水线，3个ARMCLOCK
; Delay2处循环一次为R1*(1+3)=120000个ARM CLOCK，即1ms
SUBS R0, R0, #1
BNE Delay1
LDMFD SP!, {R1} ; 入栈与出栈必须一一对应
BX LR
END ; 汇编结束
4. 代码编译
写好以上代码后，由于代码是地址无关的，即代码可以被链接到任意的存储器空间地址，都是可以正常执行的，因此此入门汇编代码可以暂时不用管链接设置。例如对于S3C2416来说，nand boot时这段代码是被拷贝到0x0处的，而IROM boot时这段代码是被拷贝到0x40000000处的，不同的启动模式，代码都是可以正确运行的。直接点击编译，会给出链接警告说没有相应的段匹配InRoot$$Sections，这是因为我们没有处理链接文件，链接器采用了默认的链接文件，一般情况下，代码是要跳转到c函数的main的，而跳转之前，链接器会先链接库相应的函数，进行全局变量，静态变量等的初始化，即先初始化c运行环境。而此处我们没有调用main，所以不会链接这些c环境初始化函数，因此在代码中是没有InRoot$$Sections段的，链接器没有找到代码中InRoot$$Sections段，则忽略这段，并给予警告。MDK编译默认是不会生成代码的二进制代码bin的，此处我们在工程属性->Use->RunUser Programs After Build/Rebuild栏中加入bin生成命令fromelf --bin ".\@L.axf" --output ".\@L.bin"，即可在工程目录生成bin，这是我们用来烧录进SD卡或nand等存储器的二进制代码文件。
图4-1 MDK生成二进制执行代码设置
5. 代码从SD卡启动
5.1. SdBoot.exe工具
SdBoot工具是笔者专为Samsung arm9 S3C2450/S3C2451/S3C2416和arm11 S3C6410从sd卡启动，运行代码开发的。IROM SD/MMC启动特别适合代码的调试开发，更改的代码只需通过 IROM_Fusing_Tool.exe把可执行二进制代码烧写进sd卡，设置从sd卡启动，即可运行验证代码。但由之前文章所述IROMSD/MMC启动方式知道，代码需要在sd卡特殊的位置，内部固化代码才能正确地拷贝用户的代码到Steppingstone中。一般裸机开发生成的二进制代码以及编译生成的各个bootloader(如uboot都是需要先从sd卡启动，之后再把uboot，内核等固化到nand flash)直接通过IROM_Fusing_Tool.exe烧写进sd卡，设置从sd卡启动都是无法正确运行代码的，因为直接编译器生成的二进制代码都是不满足IROM SD/MMC启动所要求的代码存放格式的(sd卡启动流程请参考上一章节)。SdBoot工具就是为了修正这些直接编译的二进制代码格式，使之符合sd卡启动的代码位置存放要求。SdBoot工具非常适用于裸机开发，uboot之类的bootloader开发。编译后的可执行二进制代码bin先通过SdBoot.exe工具进行转换，再用IROM_Fusing_Tool.exe烧写进sd卡，设置从sd卡启动，此时即能正确地运行在sd卡中用户代码。
5.2. SdBoot工具转换成符合sd卡启动的二进制代码格式
5.2. 1.打开SdBoot.exe，点击浏览，打开由编译器生成的可执行二进制代码bin。
5.2. 2. 确保选中“制作SD卡启动文件”，点击“生成”，如果成功，将在原bin目录下生成一个文件名比原bin多_1的文件。这个转换后的bin文件即能符合sd卡启动的格式要求。
5.2.3. 如果没有点选“制作SD卡启动文件”，可以生成一个任意大小的文件（对文件扩充），该功能只为有需要的人使用（可生成特定大小的文件进行测试等）。
5.2.4. 通过IROM_Fusing_Tool.exe把转换后的代码烧写进sd卡，设置板从sd卡启动。请匆对生成的sd卡启动bin再重复转换，因为工具无法识别二制进代码是否已转换，重复转换将破坏原有的格式。对于需要nand boot的裸机、uboot二进制代码，无需用此工具进行转换，当然转换后的二进制代码下载进nand，用nand boot也是可以正常运行的，此工具只针对sd卡启动。
附注：
如果读者对本文中部分内容不理解，可先参考一下先前的章节，或者google、百度一下。任何疑问或笔者的错误，欢迎联系笔者。
以下资料笔者认为是与本文相关的，可供学习与参考，点击下面链接即可下载。
a. SdBoot.exe，笔者开发的在windows平台针对arm9 S3C2450/S3C2451/S3C2416和arm11 S3C6410从sd卡启动，代码格式转换工具。
b. ARM教程PPT，周立功讲解的NXP arm7 LPC2000系列的ppt教程，里面有arm架构以及汇编语言的教程，值得推荐。
c. 汇编流水灯代码LEDs.s
http://pan.baidu.com/s/1qW56wxA
1万+
被折叠的 条评论
为什么被折叠?
到【灌水乐园】发言
