221.标识值不连续的原因

--1. 下面的代码演示了回滚事务导致标识值不连续的情况：
--a.手工回滚事务
CREATE TABLE #(id int IDENTITY(0,1),b int)
INSERT # SELECT 1

--手工事务回滚
BEGIN TRAN
	INSERT # SELECT 2
ROLLBACK TRAN
INSERT # SELECT 2
SELECT * FROM #
DROP TABLE #
/*--结果
id           b 
----------------- ----------- 
0           1
2           2
--*/
GO

--b. 因操作失败自动回滚事务
CREATE TABLE #(id int IDENTITY(0,1),b int UNIQUE)
INSERT # SELECT 1

--违反惟一键约束,插入失败而导致自动回滚事务
INSERT # SELECT 1
INSERT # SELECT 2
SELECT * FROM #
DROP TABLE #
/*--结果
id           b 
----------------- ----------- 
0           1
2           2
--*/
GO



/*===================================================*/



--2. 删除记录导致标识值不连续
CREATE TABLE #(id int IDENTITY(0,1),b int)
INSERT # SELECT 1
INSERT # SELECT 2

--删除一条记录
DELETE # WHERE b=2
INSERT # SELECT 2
SELECT * FROM #
DROP TABLE #
/*--结果
id           b 
----------------- ----------- 
0           1
2           2
--*/
GO



/*===================================================*/



--3. 使用DBCC CHECKIDENT重置标识值导致标识值不连续的情况。
CREATE TABLE #(id int IDENTITY(0,1),b int)
INSERT # SELECT 1

--重置当前标识值
DBCC CHECKIDENT(#,RESEED,1)
INSERT # SELECT 2
select * from #
drop table #
GO
/*--结果
id           b
----------------- ----------- 
0           1
2           2
--*/