自定義ALV控件的工具條按鈕

*&---------------------------------------------------------------------*
*& Report YTEST00A
*&---------------------------------------------------------------------*
*&Violin 2021/3/10
*&---------------------------------------------------------------------*
REPORT ytest00a.

*第8章 表控件ALV控件的使用---------------------------------------------------------------------*
*8.4自定義ALV控件的工具條按鈕
INCLUDE <ICON>.

*用DEFINITION DEFERRED让程序提前知道类 LCL_EVENT_RECEIVER 避免编译错误。
CLASS LCL_EVENT_RECEIVER DEFINITION DEFERRED.

DATA: OK_CODE  TYPE SY-UCOMM,
      SAVE_OK TYPE SY-UCOMM.

*定義類對象
DATA EVENT_RECEIVER TYPE REF TO LCL_EVENT_RECEIVER.

DATA: WA_SPFLI TYPE TABLE OF SPFLI,
      A_SPFLI LIKE SPFLI.

SELECT * INTO TABLE WA_SPFLI FROM SPFLI.

DATA: WA_CONTAINER TYPE SCRFNAME VALUE 'ALVDATA',
      ALV_GRID TYPE REF TO CL_GUI_ALV_GRID,
      WA_CUSTOM_CONTAINER TYPE REF TO CL_GUI_CUSTOM_CONTAINER.

CALL SCREEN 580.

*定義類
CLASS LCL_EVENT_RECEIVER DEFINITION.

  PUBLIC SECTION.
  METHODS:
    HANDLE_TOOLBAR
      FOR EVENT TOOLBAR OF CL_GUI_ALV_GRID
        IMPORTING E_OBJECT E_INTERACTIVE,

    HANDLE_USER_COMMAND
      FOR EVENT USER_COMMAND OF CL_GUI_ALV_GRID
        IMPORTING E_UCOMM.

ENDCLASS.

*實現類
CLASS LCL_EVENT_RECEIVER IMPLEMENTATION.

  METHOD HANDLE_TOOLBAR.
    DATA: LS_TOOLBAR TYPE STB_BUTTON.
    CLEAR LS_TOOLBAR-BUTN_TYPE.
    APPEND LS_TOOLBAR TO E_OBJECT->MT_TOOLBAR.
    CLEAR LS_TOOLBAR.

    MOVE 'SHOW_DETA' TO LS_TOOLBAR-FUNCTION.

    MOVE ICON_PPE_VNODE TO LS_TOOLBAR-ICON.
    MOVE '航班明細顯示' TO LS_TOOLBAR-QUICKINFO.
    MOVE '航班明細顯示'(112) TO LS_TOOLBAR-TEXT.
    MOVE '' TO LS_TOOLBAR-DISABLED.
    APPEND LS_TOOLBAR TO E_OBJECT->MT_TOOLBAR.
  ENDMETHOD.

  METHOD HANDLE_USER_COMMAND.
    DATA: LT_ROWS TYPE LVC_T_ROW.
    CASE E_UCOMM.
      WHEN 'SHOW_DETA'.
        CALL METHOD ALV_GRID->GET_SELECTED_ROWS
          IMPORTING
            ET_INDEX_ROWS = LT_ROWS.
        CALL METHOD CL_GUI_CFW=>FLUSH.
        IF SY-SUBRC = 0.
          MESSAGE S005(YMESS) WITH '已選擇行！'.
          PERFORM MESSDETA TABLES LT_ROWS.
        ENDIF.
     ENDCASE.
  ENDMETHOD.
ENDCLASS.

MODULE STATUS_0100 OUTPUT.
  SET PF-STATUS 'TESTSTA1'.
  IF WA_CUSTOM_CONTAINER IS INITIAL.
    CREATE OBJECT WA_CUSTOM_CONTAINER
      EXPORTING CONTAINER_NAME = WA_CONTAINER.
    CREATE OBJECT ALV_GRID
      EXPORTING I_PARENT = WA_CUSTOM_CONTAINER.

    CALL METHOD ALV_GRID->SET_TABLE_FOR_FIRST_DISPLAY
      EXPORTING
        I_STRUCTURE_NAME = 'SPFLI'
      CHANGING
        IT_OUTTAB = WA_SPFLI.

    CREATE OBJECT EVENT_RECEIVER.
    SET HANDLER EVENT_RECEIVER->HANDLE_USER_COMMAND FOR ALV_GRID.

    SET HANDLER EVENT_RECEIVER->HANDLE_TOOLBAR FOR ALV_GRID.

    CALL METHOD ALV_GRID->SET_TOOLBAR_INTERACTIVE.
  ENDIF.

ENDMODULE.

MODULE USER_COMMAND_0100 INPUT.

  SAVE_OK = OK_CODE.
  CLEAR OK_CODE.
  CASE SAVE_OK.
    WHEN 'EXIT'.
      LEAVE PROGRAM.
  ENDCASE.

ENDMODULE.


FORM MESSDETA TABLES P_ET_INDEX_ROWS STRUCTURE LVC_S_ROW.
"INSERT CORRECT NAME FOR <....>
  DATA: LS_SELECTED_LINE LIKE LVC_S_ROW,
        LF_ROW_INDEX TYPE LVC_INDEX.

  DATA: S1(200) TYPE C,
        S2(3) TYPE C.

  S2 = '-'.
  LOOP AT P_ET_INDEX_ROWS INTO LS_SELECTED_LINE.
    LF_ROW_INDEX = LS_SELECTED_LINE-INDEX.

    READ TABLE WA_SPFLI INDEX LF_ROW_INDEX INTO A_SPFLI.

    S1 = '選擇行內容'.

    CONCATENATE S1 A_SPFLI-CONNID A_SPFLI-CARRID A_SPFLI-CITYFROM INTO S1 SEPARATED BY S2.

    MESSAGE i005(YMESS) WITH S1.

  ENDLOOP.

ENDFORM.