ZBCC0002-Maintenance view update create/change user id/date/time-SE38(I類型)

最新推荐文章于 2021-07-25 13:48:15 发布

Violin Huang

最新推荐文章于 2021-07-25 13:48:15 发布

阅读量86

点赞数

本文链接：https://blog.csdn.net/huanglin529/article/details/116450794

版权

SAP-ZBC 专栏收录该内容

12 篇文章 0 订阅

订阅专栏

这是一个ABAP代码段，用于在表格维护事件中更新创建者和更改者的名字、日期和时间。根据不同的操作（新条目或修改条目），程序会更新相应的字段值，如CRNAM（创建者姓名）、CRDAT（创建日期）、CRTIM（创建时间）、UPNAM（更新者姓名）、UPDAT（更新日期）和UPTIM（更新时间）。

摘要由CSDN通过智能技术生成

*&---------------------------------------------------------------------*
*& Include ZBCC0002 Maintenance view update create/change user id/date/time
*&---------------------------------------------------------------------*

*&---------------------------------------------------------------------*
*&      Form  update_nam_dat_tim
*&---------------------------------------------------------------------*
*     when  table maintain event 01, update crnam/crdat/crtim
*                                           updat/updat/upnam
*----------------------------------------------------------------------*
FORM update_nam_dat_tim.

  DATA  l_index LIKE sy-tabix. " Index to note the lines found
  FIELD-SYMBOLS  <fs> TYPE any.
****
  LOOP AT total.
    READ TABLE extract WITH KEY <vim_xtotal_key>.
    IF sy-subrc EQ 0.
      l_index = sy-tabix.
    ELSE.
      CLEAR l_index.
    ENDIF.

    CASE <action>.
      WHEN neuer_eintrag. " New entry
        ASSIGN COMPONENT 'CRNAM' OF STRUCTURE <vim_total_struc> TO <fs>.
        IF sy-subrc = 0. <fs> = sy-uname. ENDIF.
        ASSIGN COMPONENT 'CRDAT' OF STRUCTURE <vim_total_struc> TO <fs>.
        IF sy-subrc = 0. <fs> = sy-datum. ENDIF.
        ASSIGN COMPONENT 'CRTIM' OF STRUCTURE <vim_total_struc> TO <fs>.
        IF sy-subrc = 0. <fs> = sy-uzeit. ENDIF.
      WHEN aendern. " changed entry
        ASSIGN COMPONENT 'UPNAM' OF STRUCTURE <vim_total_struc> TO <fs>.
        IF sy-subrc = 0. <fs> = sy-uname. ENDIF.
        ASSIGN COMPONENT 'UPDAT' OF STRUCTURE <vim_total_struc> TO <fs>.
        IF sy-subrc = 0. <fs> = sy-datum. ENDIF.
        ASSIGN COMPONENT 'UPTIM' OF STRUCTURE <vim_total_struc> TO <fs>.
        IF sy-subrc = 0. <fs> = sy-uzeit. ENDIF.
    ENDCASE.
    MODIFY total.

    CHECK l_index GT 0.
    extract = total.
    MODIFY extract INDEX l_index.
  ENDLOOP.
  sy-subrc = 0.

ENDFORM.                    "update_nam_dat_tim