kafka-connector-util 批处理命令

kafka-connector-util 批处理命令

功能描述

由于Kafka Connect旨在作为服务运行，因此它还支持用于管理连接器的REST API。默认情况下，此服务在port上运行8083。在分布式模式下执行时，REST API将成为群集的主要接口。您可以向任何集群成员发出请求；REST API会根据需要自动转发请求。

尽管仅通过在命令行上提交连接器就可以使用独立模式，但是它也运行REST界面。这对于获取状态信息，添加和删除连接器而不停止该过程等很有用。

由于每次手工录入rest命令查看结果较为繁琐，所以将rest命令行整理为批处理脚本，方便常用命令的调阅。

脚本

运行批处理命令时，本地需要按照python，用于格式返还json字符串

@echo off
title kafka-connector-util[%date% %time%]

set server=localhost:8083
set headers=-H "Accept:application/json" -H "Content-Type:application/json"

:select_opts
echo ------------------------------------------
echo 请选择需要执行的操作:
echo [0] 查看connectors列表
echo [1] 查看connector信息
echo [2] 查看connector状态
echo [3] 查看connector配置
echo [9] 查看connectors插件列表

echo [n] 注册connector:connect-dbz-mysql
echo [d] 删除connector
echo [q] 退出
echo ------------------------------------------
set /p env_opt=请输入[0]:

if "%env_opt%"=="0" goto opt0
if "%env_opt%"=="1" goto opt1
if "%env_opt%"=="2" goto opt2
if "%env_opt%"=="3" goto opt3
if "%env_opt%"=="9" goto opt9

if "%env_opt%"=="n" goto optn
if "%env_opt%"=="d" goto optd
if "%env_opt%"=="q" goto optq

echo "输入错误，请重新选择"
goto select_opts

:opt0
echo.
echo. 查看connector列表
curl -X GET %headers% http://%server%/connectors/ -s | python -m json.tool
echo.
goto select_opts

:optn
echo.
echo. 注册connector:connect-dbz-mysql
curl -i -X POST %headers% http://%server%/connectors/ -d @config/connect-dbz-mysql.json
goto opt0

:opt1
echo.
echo. 查看connector信息
call :input_connector
curl -X GET %headers% http://%server%/connectors/%in_connector% -s | python -m json.tool
echo.
goto select_opts

:opt2
echo.
echo. 查看connector状态
call :input_connector
curl -X GET %headers% http://%server%/connectors/%in_connector%/status/ -s | python -m json.tool
echo.
goto select_opts

:opt3
echo.
echo. 查看connector配置
call :input_connector
curl -X GET %headers% http://%server%/connectors/%in_connector%/config/ -s | python -m json.tool
echo.
goto select_opts

:opt9
echo.
echo. 查看connectors插件列表
curl -X GET %headers% http://%server%/connector-plugins/ -s | python -m json.tool
echo.
goto select_opts

:optd
echo.
echo. 删除connector
call :input_connector
curl -X DELETE http://%server%/connectors/%in_connector%
goto opt0

:optq
echo 正在退出
exit 

:input_connector
set /p in_connector=请输入connector名称:

运行截图

参考

https://docs.confluent.io/current/connect/references/restapi.html