Bat脚本学习

(后面字符串部分，非原创，记不清哪位大神的杰作，如有问题请立即联系我删除后面的部分)

一，基础语法

@echo 窗口设置：mode con cols=80 lines=30
color 0a

@echo 精简输出
@echo off

@echo 资源管理器中打开D盘：
start explorer d:\

@echo 变量赋值与显示（注意空格）
set name=alex
set word=My name is %name% .
echo 最终字符串：%word%

@echo 新建文件
echo 我会写入文件1中>test1.txt
echo 我会写入文件2中>test2.txt
echo 我会追加到文件2中>>test2.txt
echo 1111111111>fixTest.txt
echo 2222222222>>fixTest.txt
echo 3333333333>>fixTest.txt
echo 4444444444>>fixTest.txt
echo 5555555555>>fixTest.txt

@echo 新建文件夹
md 新建文件夹
md 文件夹\文件夹

@echo 文件自己:%0

@echo 当前路径:%cd%

@echo 复制/移动 文件/文件夹(/y 直接覆盖)(/f 显示详情)(/e 空文件夹也复制)
copy /y test1.txt 文件夹
copy /y test2.txt 文件夹
copy /y test1.txt 文件夹\文件夹
move /y test2.txt %cd%\文件夹\文件夹
copy /y %0 %cd%\文件夹\文件夹

@echo 删除文件/文件夹(/s 删除目录树)(/q 安静模式，即不提示)
del test1.txt
rd 新建文件夹
rd /s /q 文件夹

@echo dir (path路径) (/ad 文件夹)(/a-d 文件)(/b 空格式)(/s 包含子文件夹)
dir d:\资料 /ad/b/s


@echo (无参)(/s 所有子目录的文件和文件夹)()：查看当前所在目录的文件和文件夹。 /s：查看当前目录已经其所有子目录的文件和文件夹。 

@echo 调用其他bat
call bat2.cmd
set path=d:
call bat3.cmd "%path%"

echo pause... & pause > nul

二，goto，if 语法

@echo off

echo 清除屏幕
cls

echo 空一行
echo.

echo 自定义pause文字... & pause > nul
@echo goto语句：退出代码为:1就跳至标签FAILED_1处执行,0就跳至标签UCCESS_1处执行
IF ERRORLEVEL 1 goto FAILED_1
IF ERRORLEVEL 0 goto SUCCESS_1

@echo 上面的两行不可交换位置，否则失败了也显示成功。
:SUCCESS_1
echo 命令执行成功！
goto END_1
:FAILED_1
echo 命令执行失败！
goto END_1
:END_1
echo 程序执行完毕

set string1=11111
set string2=11112
IF %string1%==%string2% (echo 相等) else echo 不相等
IF NOT EXIST test.txt echo test.txt文件不存在!

pause

三，循环语法

@echo off

@echo 无开关的for循环
for %%i in (a,"b c",d,e,"fg") do echo %%i
echo.

@echo 开关/l的for循环(start,step,end)(边界可相等)
for /l %%i in (0,1,10) do echo %%i
echo.

@echo 开关/f的for循环(拆分字符串)
for /f "tokens=1-3 delims=," %%a in ("1,2,10") do echo a=%%a b=%%b c=%%c
echo.

@echo 开关/f的for循环(获取文件夹)
　　for /f "skip=5 tokens=3* delims= " %%a in ('dir d:') do (
　　　　if "%%a"=="<DIR>" if not "%%b"=="." if not "%%b"==".." echo %%b
　　)
echo.

@echo 开关/f的for循环(获取文件)
　　for /f "skip=5 tokens=3* delims= " %%a in ('dir') do (
　　　　if not "%%a"=="<DIR>" if not "%%b"=="字节" if not "%%b"=="可用字节" echo %%b
　　)
echo.

pause

四，传参，call

@echo off

echo 传入数据有这些: %1 %2 %3 %4

set path=%1
set fileList=fileList.txt
set foldList=foldList.txt
set buildSource=buildSource.txt

if exist %fileList% del %fileList%
if exist %foldList% del %foldList%
if exist %buildSource% del %buildSource%

@echo 延迟变量，批处理读取命令时是按行读取的
setlocal enableDelayedExpansion

for /f "delims=" %%i in ('dir/a-d/s/b %path%')do (
    set filePath=%%i
    echo !filePath!>>%fileList%
)

for /f "delims=" %%i in ('dir/ad/s/b %path%')do (
    set filePath=%%i
    echo !filePath!>>%foldList%
)

for /f "delims=" %%i in ('dir/ad/s/b %path%')do (
    set filePath=%%i
    set line=-sourcepath src !filePath!\*.java
    set /p=!line! >>%buildSource%<nul
)

@echo off
set path=D:\资料\
call bat语法4_传入参数.cmd %path% 参数2 参数3 参数4
pause

五，修改文本

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%a in (fixTest.txt) do (
    set aa=%%a
    set aa=!aa:3=1!
    echo !aa!>>fixTestNew.txt
)

六，字符串操作

1、截取字符串

截取字符串可以说是字符串处理功能中最常用的一个子功能了，能够实现截取字符串中的特定位置的一个或多个字符。举例说明其基本功能：

@echo off
set ifo=abcdefghijklmnopqrstuvwxyz0123456789
echo 原字符串（第二行为各字符的序号）：
echo %ifo%
echo 123456789012345678901234567890123456
echo 截取前5个字符：
echo %ifo:~0,5%
echo 截取最后5个字符：
echo %ifo:~-5%
echo 截取第一个到倒数第6个字符：
echo %ifo:~0,-5%
echo 从第4个字符开始，截取5个字符：
echo %ifo:~3,5%
echo 从倒数第14个字符开始，截取5个字符：
echo %ifo:~-14,5%
pause

当然，上面的例子只是将字符串处理的基本功能展示出来了，还看不出字符串处理具体有什么用处。下面这个例子是对时间进行处理。

@echo off
echo 当前时间是：%time% 即 %time:~0,2%点%time:~3,2%分%time:~6,2%秒%time:~9,2%厘秒
pause

2、替换字符串

替换字符串，即将某一字符串中的特定字符或字符串替换为给定的字符串。举例说明其功能：

@echo off
set aa=伟大的中国！我为你自豪！
echo 替换前：%aa%
echo 替换后：%aa:中国=中华人民共和国%
echo aa = %aa%
set "aa=%aa:中国=中华人民共和国%"
echo aa = %aa%
pause

对于上面的例子有一点说明，对比两个echo aa = %aa%可以发现，如果要修改变量aa的内容的话，就需要将修改结果“%aa:中国=中华人民共和国%”赋值给变量aa。上面的字符串截取也有着同样的特点。

3、字符串合并

其实，合并字符串就是将两个字符串放在一起就可以了。举例说明：

@echo off
set aa=伟大的中国！
set bb=我为你自豪！
echo %aa%%bb%
echo aa=%aa%
echo bb=%bb%
set "aa=%aa%%bb%"
echo aa=%aa%
pause

同样，如果要改变变量aa的内容的话，就需要将合并结果“%aa%%bb%”赋值给变量aa。

4、扩充字符串

“扩充”这个词汇来自于微软自己的翻译，意思就是对表示文件路径的字符串进行特殊的处理，具体功能罗列如下：

~I - 删除任何引号(")，扩充 %I
%~fI - 将 %I 扩充到一个完全合格的路径名
%~dI - 仅将 %I 扩充到一个驱动器号
%~pI - 仅将 %I 扩充到一个路径
%~nI - 仅将 %I 扩充到一个文件名
%~xI - 仅将 %I 扩充到一个文件扩展名
%~sI - 扩充的路径只含有短名
%~aI - 将 %I 扩充到文件的文件属性
%~tI - 将 %I 扩充到文件的日期/时间
%~zI - 将 %I 扩充到文件的大小
%~$PATH:I - 查找列在路径环境变量的目录，并将 %I 扩充
到找到的第一个完全合格的名称。如果环境变量名
未被定义，或者没有找到文件，此组合键会扩充到
空字符串
可以组合修饰符来得到多重结果:
%~dpI - 仅将 %I 扩充到一个驱动器号和路径
%~nxI - 仅将 %I 扩充到一个文件名和扩展名
%~fsI - 仅将 %I 扩充到一个带有短名的完整路径名
%~dp$PATH:i - 查找列在路径环境变量的目录，并将 %I 扩充
到找到的第一个驱动器号和路径。
%~ftzaI - 将 %I 扩充到类似输出线路的 DIR

以上内容引用于for /?帮助信息。其中的I代表变量I，不过需要说明的是，不是所有的变量都能够进行扩充的，有两个条件：1、该字符串代表一个文件路径；2、变量要用%x来表示，x可取a-z A-Z 0-9共62个字符中的任意一个。举例说明：

@echo off
echo 正在运行的这个批处理：
echo 完全路径：%0
echo 去掉引号：%~0
echo 所在分区：%~d0
echo 所处路径：%~p0
echo 文件名：%~n0
echo 扩展名：%~x0
echo 文件属性：%~a0
echo 修改时间：%~t0
echo 文件大小：%~z0
pause

其中的%0是批处理里面的参数，代表当前运行的批处理的完全路径。类似的还有%1-%9，分别代表传递来的第1-9个参数。例子如下：

@echo off
set aa=C:\Windows\PPP\a.btx
call :deal aaa %aa% "c c" ddd eee
pause>nul
exit
:deal
echo %%0 = %0
echo %%1 = %1
echo %%2 = %2
echo %%3 = %3
echo %%4 = %4
echo %%5 = %5

其中，变量aa在之前是不可以扩充的，通过call命令并将aa作为参数传递给子函数:deal，将aa变量转换成了变量%1，即符合%x格式，从而可以进行字符串扩充。
至于%x中x取a-z A-Z的形式，可以复习一下for语句，for语句里面的变量就是用%x来表示的，因而可以直接进行扩充。

补充

下面是其它网友的补充：注意是与c语言做了一些对比

首先说一下，批处理和高级语言不同，没有字符串处理函数，比如strcat之类的，但是却可以利用环境变量来实现这些函数的功能。
本文对照C语言中的字符串处理函数，讲解在批处理中的实现方法。

首先说一下字符串的存储，在C语言中，采用字符数组或者字符指针来存储字符串，而BAT中没有这些东东，所以要依靠环境变量来存储。
设置环境变量的语句为set语句，本文不详细介绍了，参考set /?语句。

1、C语中的strcpy函数，将一个字符串复制到另一个字符型指针或字符数组，覆盖原来的字符串。

C语言中的调用方法：strcpy(目标字符串,源字符串)
在批处理中的实现方法：
set 目标字符串=%源字符串%

@echo off
::关闭屏幕回显（可选）
set str1=This is old string
::设置str1中存储的字符串，注意没有双引号，这点与C语言等不同！
set str2=This is new string
::设置str2中存储的字符串
echo 执行字符串拷贝以前：
echo str1=%str1%
echo str2=%str2%
::先输出一次原有的字符串
set str1=%str2%
::字符串拷贝
echo 执行字符串拷贝以后：
echo str1=%str1%
echo str2=%str2%
::输出执行完字符串拷贝后的字符串
echo 输出完毕，按任意键退出&&pause>nul&&exit
::输出信息，当用户按任意键时，结束该批处理。

2、C语中的strcat函数，将一个字符串连接到另一个字符型指针或字符数组的末尾。

C语言中的调用方法：strcat(目标字符串,源字符串)
在批处理中的实现方法：
set 目标字符串=%目标字符串%%源字符串%

@echo off
set str1=This is string1
set str2=This is string2
::设置str1和str2中存储的字符串
echo 连接字符串以前：
echo str1=%str1%
echo str2=%str2%
::先输出一次原有的字符串
set str1=%str1%%str2%
::字符串连接
echo 连接字符串以后：
echo str1=%str1%
echo str2=%str2%
::输出执行完字符串连接后的两个字符串
echo 输出完毕，按任意键退出&&pause>nul&&exit

3、字符串截取，C中没有这种函数，不过可以通过语句实现，不再介绍，直接说批处理的。

set 目标字符串=%源字符串:~起始值,截取长度%
注意，起始值从0开始！
截取长度是可选的，如果省略逗号和截取长度，将会从起始值一直截取到字符串的结尾。

@echo off
set str1=This is string1
::设置str1中存储的字符串
set str2=%str1:~8,6%
set str3=%str1:~0,4%
set str4=%str1:~5%
::字符串截取
echo 原字符串：
echo str1=%str1%
echo 截取得到的字符串：
echo str2=%str2%
echo str3=%str3%
echo str4=%str4%
::输出执行结果
echo 输出完毕，按任意键退出&&pause>nul&&exit

4、C语中的strlen函数，取得字符串的长度。

C语言中的调用方法：strlen(字符串)
在批处理中的实现方法是利用goto和标签，形成循环结构，不断将字符串截短1字符，并用变量记录截短的次数，直到字符串变成空串。

@echo off
set str1=This is a test string
set str2=Hello World
::设置两个字符串
set str=%str1%
::将str1复制到str
:next1
::标签，用于goto跳转
::注意与注释语句的区别，注释用两个冒号开头，标签则为一个冒号
if not "%str%"=="" (
::判断str是不是空串，如果不是则执行下边的语句
set /a num+=1
::算术运算，使num的值自增1，相当于num++或者++num语句
set "str=%str:~1%"
::截取字符串，赋给自身
goto next1
::跳转到next1标签
::这里利用goto和标签，构成循环结构
)
::当以上循环结构执行完毕时，会执行下边的语句
echo str1=%str1%
echo str1的长度为：%num%
::输出结果
set num=0
::将记和用的环境变量num置0，以便开始下一次运算。
set str=%str2%
::将str2复制到str
:next2
::定义一个新的标签
::注意不能与已有的标签同名，否则会出错！
if not "%str%"=="" (
set /a num+=1
set "str=%str:~1%"
goto next2
)
::和上一个循环相似，不再介绍
echo str2=%str2%
echo str2的长度为：%num%
::输出结果
echo 输出完毕，按任意键退出&&pause>nul&&exit

5、C语中的strchr函数，在一个字符串中查找一个字符的首次出现位置，找到时返回所在位置，找不到时返回0值。

批处理中的思路：不断截短字符串，并取截短后字符串中的首字符，和要求的字符比较，如果相同就利用goto语句跳出循环，输出结果，如果没有相同的字符，执行到最后就输出0值。

@echo off
Setlocal ENABLEDELAYEDEXPANSION
::启用命令扩展，参加setlocal /?命令
set str1=This is a test string
set ch1=t
::注意，这里是区分大小写的！
set str=%str1%
::复制字符串，用来截短，而不影响源字符串
:next
if not "%str%"=="" (
set /a num+=1
if "!str:~0,1!"=="%ch1%" goto last
::比较首字符是否为要求的字符，如果是则跳出循环
set "str=%str:~1%"
goto next
)
set /a num=0
::没有找到字符时，将num置零
:last
echo 字符'%ch1%'在字符串"%str1%"中的首次出现位置为%num%
echo 输出完毕，按任意键退出&&pause>nul&&exit

引用:
最后出几道题，看看大家学习的怎么样！

(1)如何实现C语言中strstr函数的功能？

提示：strstr函数的功能是在字符串1中查找字符串2，找到时返回串2首次出现的位置，否则返回0值。与strchr区别就是，第二个参数是字符串，而不是字符了。

(2)如何用批处理构建while循环？

提示：while循环一般格式为：

while(表达式)
{
循环体
[break|continue;]
循环体
}

其中，循环体为0条或多条语句，break用于跳出循环，continue用于直接判断表达式并决定是否进入下一次循环。
一般执行顺序：首先判断表达式，如果成立则进入循环，循环体执行完毕后再次判断表达式的值，决定是否再次循环。

(3)如何用批处理构建do-while循环？

提示：do-while循环一般格式为：

do
{
循环体
[break|continue;]
循环体
}while(表达式)；

各个语句的解释参照while循环。
一般执行顺序：首先进入循环，循环体执行完毕后判断表达式的值，表达式成立则再次进入循环。