tomcat setclasspath.bat解读（含setenv.bat）

[b]setclasspath.bat注释版：[/b]

rem setclasspath.bat用于确定JAVA_HOME和JRE_HOME环境变量的设置
@echo off
echo Enter the setclasspath.bat file ......
rem ---------------------------------------------------------------------------
rem Set JAVA_HOME or JRE_HOME if not already set, ensure any provided settings
rem are valid and consistent with the selected start-up options and set up the
rem endorsed directory.
rem
rem $Id: setclasspath.bat 1202062 2011-11-15 06:50:02Z mturk $
rem ---------------------------------------------------------------------------

rem Make sure prerequisite environment variables are set     rem 确保设置必备的环境变量

rem In debug mode we need a real JDK (JAVA_HOME)             rem debug模式下需要设置JAVA_HOME环境变量 
if ""%1"" == ""debug"" goto needJavaHome                     rem 如果参数是debug即debug模式，就直接跳到needJavaHome

rem Otherwise either JRE or JDK are fine                     rem 否则直接查看是否JDK或JRE设置
rem set JAVA_HOME=%CATALINA_HOME%\..\jdk                     rem 可以在这里设置JAVA_HOME，也可以在setenv.bat中设置

if not "%JRE_HOME%" == "" goto gotJreHome                    rem 如果设置了JRE_HOME环境变量，就直接跳到gotJreHome
if not "%JAVA_HOME%" == "" goto gotJavaHome                  rem 如果设置了JAVA_HOME环境变量，就直接跳到gotJavaHome，否则提示错误信息
echo Neither the JAVA_HOME nor the JRE_HOME environment variable is defined
echo At least one of these environment variable is needed to run this program
goto exit

:needJavaHome
rem debug
rem Check if we have a usable JDK                            rem 检查是否我们有可用的JDK
if "%JAVA_HOME%" == "" goto noJavaHome                       rem 如果JAVA_HOME没有设置，就直接跳到noJavaHome
if not exist "%JAVA_HOME%\bin\java.exe" goto noJavaHome      rem 如果设置了JAVA_HOME且在JAVA_HOME\bin\java.exe不存在，就直接跳到noJavaHome
if not exist "%JAVA_HOME%\bin\javaw.exe" goto noJavaHome     rem 如果javaw.exe不存在，就直接跳到noJavaHome
if not exist "%JAVA_HOME%\bin\jdb.exe" goto noJavaHome       rem 如果jdb.exe不存在，就直接跳到noJavaHome
if not exist "%JAVA_HOME%\bin\javac.exe" goto noJavaHome     rem 如果javac.exe不存在，就直接跳到noJavaHome
set "JRE_HOME=%JAVA_HOME%"                                   rem 如果都存在，则设置JRE_HOME为JAVA_HOME
goto okJava                                                  rem 直接跳到okJava

:noJavaHome
rem debug
echo The JAVA_HOME environment variable is not defined correctly.
echo It is needed to run this program in debug mode.
echo NB: JAVA_HOME should point to a JDK not a JRE.
goto exit

:gotJavaHome
rem 跳到gotJavaHome表示设置了JAVA_HOME但没有设置JRE_HOME
rem No JRE given, use JAVA_HOME as JRE_HOME
set "JRE_HOME=%JAVA_HOME%"                                    rem 如果设置了JAVA_HOME但是没有设置JRE_HOME，则设置JAVA_HOME为JRE_HOME

:gotJreHome
rem Check if we have a usable JRE
if not exist "%JRE_HOME%\bin\java.exe" goto noJreHome         rem 如果不存在java.exe，则直接跳到noJreHome
if not exist "%JRE_HOME%\bin\javaw.exe" goto noJreHome
goto okJava                                                   rem 如果均都不存在，就直接跳到okJava

:noJreHome
rem Needed at least a JRE
echo The JRE_HOME environment variable is not defined correctly
echo This environment variable is needed to run this program
goto exit

:okJava
rem Don't override the endorsed dir if the user has set it previously
if not "%JAVA_ENDORSED_DIRS%" == "" goto gotEndorseddir
rem Set the default -Djava.endorsed.dirs argument
set "JAVA_ENDORSED_DIRS=%CATALINA_HOME%\endorsed"

:gotEndorseddir
rem Set standard command for invoking Java.
rem Note that NT requires a window name argument when using start.
rem Also note the quoting as JAVA_HOME may contain spaces.
set _RUNJAVA="%JRE_HOME%\bin\java"
set _RUNJDB="%JAVA_HOME%\bin\jdb"

goto end

:exit
exit /b 1

:end
exit /b 0

[b]setclasspath.bat使用版：[/b]

@echo off
echo Enter the setclasspath.bat file ......
rem ---------------------------------------------------------------------------
rem Set JAVA_HOME or JRE_HOME if not already set, ensure any provided settings
rem are valid and consistent with the selected start-up options and set up the
rem endorsed directory.
rem
rem $Id: setclasspath.bat 1202062 2011-11-15 06:50:02Z mturk $
rem ---------------------------------------------------------------------------

rem Make sure prerequisite environment variables are set

rem In debug mode we need a real JDK (JAVA_HOME)
if ""%1"" == ""debug"" goto needJavaHome

rem Otherwise either JRE or JDK are fine
rem set JAVA_HOME=%CATALINA_HOME%\..\jdk

if not "%JRE_HOME%" == "" goto gotJreHome
if not "%JAVA_HOME%" == "" goto gotJavaHome
echo Neither the JAVA_HOME nor the JRE_HOME environment variable is defined
echo At least one of these environment variable is needed to run this program
goto exit

:needJavaHome
rem Check if we have a usable JDK
if "%JAVA_HOME%" == "" goto noJavaHome
if not exist "%JAVA_HOME%\bin\java.exe" goto noJavaHome
if not exist "%JAVA_HOME%\bin\javaw.exe" goto noJavaHome
if not exist "%JAVA_HOME%\bin\jdb.exe" goto noJavaHome
if not exist "%JAVA_HOME%\bin\javac.exe" goto noJavaHome
set "JRE_HOME=%JAVA_HOME%"
goto okJava

:noJavaHome
echo The JAVA_HOME environment variable is not defined correctly.
echo It is needed to run this program in debug mode.
echo NB: JAVA_HOME should point to a JDK not a JRE.
goto exit

:gotJavaHome
rem No JRE given, use JAVA_HOME as JRE_HOME
set "JRE_HOME=%JAVA_HOME%"

:gotJreHome
rem Check if we have a usable JRE
if not exist "%JRE_HOME%\bin\java.exe" goto noJreHome
if not exist "%JRE_HOME%\bin\javaw.exe" goto noJreHome
goto okJava

:noJreHome
rem Needed at least a JRE
echo The JRE_HOME environment variable is not defined correctly
echo This environment variable is needed to run this program
goto exit

:okJava
rem Don't override the endorsed dir if the user has set it previously
if not "%JAVA_ENDORSED_DIRS%" == "" goto gotEndorseddir
rem Set the default -Djava.endorsed.dirs argument
set "JAVA_ENDORSED_DIRS=%CATALINA_HOME%\endorsed"
:gotEndorseddir

rem Set standard command for invoking Java.
rem Note that NT requires a window name argument when using start.
rem Also note the quoting as JAVA_HOME may contain spaces.
set _RUNJAVA="%JRE_HOME%\bin\java"
set _RUNJDB="%JAVA_HOME%\bin\jdb"

goto end

:exit
exit /b 1

:end
exit /b 0

[b]setenv.bat文件(自定义环境变量文件):[/b]

rem Do not set the variables in this script(catalina_note.bat). Instead put them into a script setenv.bat in CATALINA_BASE/bin to keep your customizations separate.
echo Enter the setenv.bat file ......
set JAVA_HOME=%CATALINA_HOME%\..\jdk