arm64_linux head.S的执行流程(3.18)- 9.stext之__cpu_setup

1.前言

本文基于高通8996平台，kernel版本为3.18.31。
本文主要介绍head.S的__cpu_setup执行流程

2. __cpu_setup

主要对cpu相关进行设置。在调用__cpu_setup之前设定了lr的内容是__enable_mmu，而调用__cpu_setup使用的是b而不是bl指令，因此lr寄存器没有修改，因此，这里的ret返回到__enable_mmu函数

#arch/arm64/mm/proc.S

/*
 *      __cpu_setup
 *
 *      Initialise the processor for turning the MMU on.  Return in x0 the
 *      value of the SCTLR_EL1 register.
 */
ENTRY(__cpu_setup)
//ic iallu指令设置instruction cache中的所有的cache line是无效的，直到PoU
// I+BTB cache invalidate
        ic      iallu  
                                 
//tlbi这条指令通过猜测也知道是对TLB进行invalidation的操作，
//vmalle1is是vm-all-e1-is，vmall表示要invalidate all TLB entry，
//e1表示该操作适用于EL1，is表示inner sharebility
// invalidate I + D TLBs
        tlbi    vmalle1is           
                    
//step 1和step 2的操作和打开MMU操作有严格的时序要求，
//dsb这个memory barrier操作可以保证在执行打开MMU的时候，step 1和step 2都已经执行完毕。
//同样的，ish表示inner shareable。
        dsb     ish 
        
//CPACR_EL1（Architectural Feature Access Control Register）是用来控制Trace，
     浮点运算单元以及SIMD单元的。
//FPEN，bits [21:20]是用来控制EL0和EL1状态的时候访问浮点单元和
     SIMD单元是否会产生exception从进入上一个exception level。
//这里的设定运行用户空间（EL0）和内核空间（EL1）访问浮点单元和SIMD单元。
//MDSCR_EL1（Monitor Debug System Control Register）主要用来控制debug系统的
        mov     x0, #3 << 20
        msr     cpacr_el1, x0                   // Enable FP/ASIMD
        msr     mdscr_el1, xzr                  // Reset mdscr_el1
        /*  
         * Memory region attributes for LPAE:
         *
         *   n = AttrIndx[2:0]
         *                      n       MAIR
         *   DEVICE_nGnRnE      000     00000000
         *   DEVICE_nGnRE       001     00000100
         *   DEVICE_GRE         010     00001100
         *   NORMAL_NC          011     01000100
         *   NORMAL             100     11111111
         */
        ldr     x5, =MAIR(0x00, MT_DEVICE_nGnRnE) | \ 
                     MAIR(0x04, MT_DEVICE_nGnRE) | \ 
                     MAIR(0x0c, MT_DEVICE_GRE) | \ 
                     MAIR(0x44, MT_NORMAL_NC) | \ 
                     MAIR(0xff, MT_NORMAL)
        msr     mair_el1, x5
        /*
         * Prepare SCTLR
         */
 //在调用__enable_mmu之前要准备好SCTLR_EL1的值，
     该值在这段代码中设定并保存在x0寄存器中，
 //随后做为参数传递给__enable_mmu函数。具体怎么设定SCTLR_EL1的值呢？
     这是通过crval变量设定的
        adr     x5, crval
        ldp     w5, w6, [x5]
        mrs     x0, sctlr_el1
        bic     x0, x0, x5                      // clear bits
        orr     x0, x0, x6                      // set bits
//这里的代码是准备TCR寄存器的值。
    TCR_TxSZ(VA_BITS)是根据CONFIG_ARM64_VA_BITS配置来设定内核和用户空间的size，
//其他的是进行page size的设定或者是page table对应的memory的attribute的设定
        /*
         * Set/prepare TCR and TTBR. We use 512GB (39-bit) address range for
         * both user and kernel.
         */
        ldr     x10, =TCR_TxSZ(VA_BITS) | TCR_CACHE_FLAGS | TCR_SMP_FLAGS | \
                        TCR_TG_FLAGS | TCR_ASID16 | TCR_TBI0
        /*
         * Read the PARange bits from ID_AA64MMFR0_EL1 and set the IPS bits in
         * TCR_EL1.
         */
        mrs     x9, ID_AA64MMFR0_EL1
        bfi     x10, x9, #32, #3
        msr     tcr_el1, x10
        ret                                     // return to head.S
ENDPROC(__cpu_setup)

3. 总结

__cpu_setup主要作用就是为开启mmu做准备，比如清空tlb的cacheline, 清空icache的cacheline等。

参考文档

1.https://blog.csdn.net/xichangbao/article/details/51568782
2.https://www.cnblogs.com/smartjourneys/diary/2017/04/27/6774121.html
3.http://www.wowotech.net/armv8a_arch/arm64_initialize_1.html ARM64的启动过程之（一）：内核第一个脚印
3.http://www.wowotech.net/armv8a_arch/create_page_tables.html ARM64的启动过程之（二）：创建启动阶段的页表
4.http://www.wowotech.net/armv8a_arch/__cpu_setup.html ARM64的启动过程之（三）：为打开MMU而进行的CPU初始化
5.http://www.wowotech.net/armv8a_arch/turn-on-mmu.html ARM64的启动过程之（四）：打开MMU
6.https://blog.csdn.net/xichangbao/article/details/51568782 Kernel启动流程源码解析 1 head.S
7.https://blog.csdn.net/xichangbao/article/details/51605462 Kernel启动流程源码解析 2 head.S