如何去掉、修改Flex生成的SWF加载进度条？

方法一：

           <s:Application xmlns:fx="http://ns.adobe.com/mxml/2009"
               xmlns:s="library://ns.adobe.com/flex/spark" 
               xmlns:mx="library://ns.adobe.com/flex/mx" minWidth="800" minHeight="600" width="800" height="600" 
               usePreloader="false">

 

方法二：

          重写Preload的进度条类

如：

package com.component 
{ 
    import flash.display.Sprite; 
    import flash.events.Event; 
    import flash.events.ProgressEvent; 
     
    import mx.events.FlexEvent; 
    import mx.preloaders.DownloadProgressBar; 
     
    public class pbarunsee extends DownloadProgressBar 
    { 
        public function pbarunsee() 
        { 
            super(); 
        } 
        override public function set preloader( preloader:Sprite ):void    { 
            preloader.addEventListener( ProgressEvent.PROGRESS , SWFDownloadProgress );          
            preloader.addEventListener( Event.COMPLETE , SWFDownloadComplete );  
            preloader.addEventListener( FlexEvent.INIT_PROGRESS , FlexInitProgress );  
            preloader.addEventListener( FlexEvent.INIT_COMPLETE , FlexInitComplete );  
        } 
        private function SWFDownloadProgress( event:ProgressEvent ):void {  
            this.visible=false; 
        }  
         
        private function SWFDownloadComplete( event:Event ):void {this.visible=false;}  
         
        private function FlexInitProgress( event:Event ):void {  
            this.visible=false; 
        }  
         
        private function FlexInitComplete( event:Event ):void     
        {              
            dispatchEvent(new Event(Event.COMPLETE));  
        }  
    } 
}

在App中引用

<s:Application xmlns:fx="http://ns.adobe.com/mxml/2009"
               xmlns:s="library://ns.adobe.com/flex/spark"
               xmlns:mx="library://ns.adobe.com/flex/mx" minWidth="800" minHeight="600" width="800" height="600"
 preloader="com.component.pbarunsee">

 

方法三：

重写Preload的进度条类、在此过程中可以自己修改进度条样式

package Components.Common.Core
{
 import flash.filters.BlurFilter;
 import flash.geom.Matrix;
 import flash.text.TextField;
 import flash.utils.ByteArray;
 import flash.utils.Timer;
 import flash.display.*;
 import flash.events.*;
 import flash.filters.BitmapFilterQuality;
 import flash.filters.BlurFilter;
 import flash.geom.Matrix;

 import mx.controls.Alert;
 import mx.events.FlexEvent;
 import mx.preloaders.DownloadProgressBar;
 
 public class MyDownloadProgressBar extends DownloadProgressBar
 {
  [Embed(source="/Assets/PIC/logo.png", mimeType="application/octet-stream")]
  public var _loadingLogo:Class;
  
  private var dpbImageControl:Loader;
  private var _barSprite:Sprite;
  private var progressText:TextField;
  private var ProgressBarSpritIsAdded:Boolean = false;
  
  public function MyDownloadProgressBar()
  {
   super();
  }
  
  override public function set preloader(preloader:Sprite):void
  {
   //Listen for 正在下载
   preloader.addEventListener(ProgressEvent.PROGRESS, SWFDownloadProgressHandler, false, 0, true);
   //Listen for 下载完成
   preloader.addEventListener(Event.COMPLETE, SWFDownloadCompleteHandler, false, 0, true);
   //Listen for 正在初始化
   preloader.addEventListener(FlexEvent.INIT_PROGRESS, FlexInitProgressHandler, false, 0, true);
   //Listen for 初始化完成
   preloader.addEventListener(FlexEvent.INIT_COMPLETE, FlexInitCompleteHandler, false, 0, true);
  }
  
  public function initalize():void
  {
   // 添加logo图
   dpbImageControl = new Loader();
   dpbImageControl.contentLoaderInfo.addEventListener(Event.COMPLETE, loader_CompleteHandler, false, 0, true);
   dpbImageControl.loadBytes(new _loadingLogo() as ByteArray);
  }
  
  private function loader_CompleteHandler(event:Event):void
  {
   this.addChild(dpbImageControl);
   dpbImageControl.width = 230;
   dpbImageControl.height = 80;
   dpbImageControl.x = this.stage.stageWidth / 2 - dpbImageControl.width / 2;
   dpbImageControl.y = this.stage.stageHeight / 2 - dpbImageControl.height / 2 - 80;
  }
  
  private function addProgressBarSprit():void
  {
   // 绘制背景渐变
   var matrix:Matrix = new Matrix();
   matrix.createGradientBox(this.stage.stageWidth, this.stage.stageHeight, Math.PI/2);
   var colors:Array = [0x058BBD, 0xFFFFFF];
   var alphas:Array = [1, 1];
   var ratios:Array = [0, 255];
   this.graphics.lineStyle();
   this.graphics.beginGradientFill(GradientType.LINEAR, colors, alphas, ratios, matrix);
   this.graphics.drawRect(0, 0, this.stage.stageWidth, this.stage.stageHeight);
   this.graphics.endFill();
   
   // 绘制中心白色发光
   var _Sprite1:Sprite = new Sprite();
   this.addChild(_Sprite1);
   _Sprite1.graphics.beginFill(0xFFFFFF, 0.45);
   _Sprite1.graphics.drawEllipse(this.stage.stageWidth/2 - 130, this.stage.stageHeight/2 - 90, 280, 100);
   _Sprite1.graphics.endFill();
   
   //  滤镜实现发光边缘柔和
   var blur:BlurFilter = new BlurFilter();
   blur.blurX = 100;
   blur.blurY = 50;
   blur.quality = BitmapFilterQuality.HIGH;
   _Sprite1.filters = [blur];
   
   // 绘制进度条背景
   var _Sprite2:Sprite = new Sprite();
   this.addChild(_Sprite2);
   _Sprite2.graphics.lineStyle(1, 0xCCCCCC);
   _Sprite2.graphics.beginFill(0xFFFFFF);
   _Sprite2.graphics.drawRect((this.stage.stageWidth/2 - 152), (this.stage.stageHeight/2 - 10), 304, 20);
   _Sprite2.graphics.endFill();
   
   // 加载进度条Sprite
   _barSprite = new Sprite();
   this.addChild(_barSprite);
   _barSprite.x = this.stage.stageWidth/2 - 150;
   _barSprite.y = this.stage.stageHeight/2 - 8;
   
   // 加载进度条文字
   progressText = new TextField();
   this.addChild(progressText);
   progressText.textColor = 0x333333;
   progressText.width = 300;
   progressText.height = 18;
   progressText.x = this.stage.stageWidth/2 - 152;
   progressText.y = this.stage.stageHeight/2 + 20;
  }
  
  // 刷新进度条
  private function drawProgressBar(bytesLoaded:Number, bytesTotal:Number):void
  {
   if(_barSprite != null && progressText != null)
   {
    var g:Graphics = _barSprite.graphics;
    g.clear();
    
    var matrix:Matrix = new Matrix();
    matrix.createGradientBox(300*(bytesLoaded/bytesTotal), 16, Math.PI/2);
    var colors:Array = [0x0099cc, 0x99cc77];
    var alphas:Array = [1, 1];
    var ratios:Array = [0, 255];
    g.lineStyle();
    g.beginGradientFill(GradientType.LINEAR, colors, alphas, ratios, matrix);
    g.drawRect(0, 0, 300*(bytesLoaded/bytesTotal), 16);
    g.endFill();
   }
  }
  
  private function SWFDownloadProgressHandler(event:ProgressEvent):void
  {
   // 第一次处理时绘制进度条Sprite
   if(!ProgressBarSpritIsAdded)
   {
    ProgressBarSpritIsAdded = true;
    addProgressBarSprit();
   }
   
   if(progressText != null)
   {
    progressText.text = "下载进度：已下载" + event.bytesLoaded + "byte, 总大小" + event.bytesTotal + "byte";
   }
   drawProgressBar(event.bytesLoaded, event.bytesTotal);
  }
  
  private function SWFDownloadCompleteHandler(event:Event):void
  {
   if(progressText != null)
   {
    progressText.text = "下载完成";
   }
   drawProgressBar(1, 1);
  }
  
  private function FlexInitProgressHandler(event:Event):void
  {
   if (progressText != null)
   {
    progressText.text = "正在初始化...";
   }
   drawProgressBar(1,1);
  }
  
  private function FlexInitCompleteHandler(event:Event):void
  {
   if(progressText != null)
   {
    progressText.text = "正在初始化...";
   }
   drawProgressBar(1,1);
   
   // 0.03秒后抛出完成事件
   var timer:Timer = new Timer(300, 1);
   timer.addEventListener(TimerEvent.TIMER, dispatchCompleteHandler, false, 0, true);
   timer.start();
  }
  
  private function dispatchCompleteHandler(event:Event):void
  {
   trace("发送消息");
   dispatchEvent(new Event(Event.COMPLETE));
  }
 }
}

在App中引用

<s:Application xmlns:fx="http://ns.adobe.com/mxml/2009"
      xmlns:s="library://ns.adobe.com/flex/spark"
      xmlns:mx="library://ns.adobe.com/flex/mx" minWidth="800" minHeight="600" width="800" height="600"
       xmlns:MainModule="MainModule.*" preloader="Components.Common.Core.MyDownloadProgressBar">