能量项链

能量项链

(energy.pas/c/cpp)

 

【问题描述】

在Mars星球上，每个Mars人都随身佩带着一串能量项链。在项链上有N颗能量珠。能量珠是一颗有头标记与尾标记的珠子，这些标记对应着某个正整数。并且，对于相邻的两颗珠子，前一颗珠子的尾标记一定等于后一颗珠子的头标记。因为只有这样，通过吸盘（吸盘是Mars人吸收能量的一种器官）的作用，这两颗珠子才能聚合成一颗珠子，同时释放出可以被吸盘吸收的能量。如果前一颗能量珠的头标记为m，尾标记为r，后一颗能量珠的头标记为r，尾标记为n，则聚合后释放的能量为 （Mars单位），新产生的珠子的头标记为m，尾标记为n。

需要时，Mars人就用吸盘夹住相邻的两颗珠子，通过聚合得到能量，直到项链上只剩下一颗珠子为止。显然，不同的聚合顺序得到的总能量是不同的，请你设计一个聚合顺序，使一串项链释放出的总能量最大。

例如：设N=4，4颗珠子的头标记与尾标记依次为(2，3) (3，5) (5，10) (10，2)。我们用记号⊕表示两颗珠子的聚合操作，(j⊕k)表示第j，k两颗珠子聚合后所释放的能量。则第4、1两颗珠子聚合后释放的能量为：

(4⊕1)=10*2*3=60。

这一串项链可以得到最优值的一个聚合顺序所释放的总能量为

((4⊕1)⊕2)⊕3）=10*2*3+10*3*5+10*5*10=710。

 

【输入文件】

输入文件energy.in的第一行是一个正整数N（4≤N≤100），表示项链上珠子的个数。第二行是N个用空格隔开的正整数，所有的数均不超过1000。第i个数为第i颗珠子的头标记（1≤i≤N），当i<N时，第i颗珠子的尾标记应该等于第i+1颗珠子的头标记。第N颗珠子的尾标记应该等于第1颗珠子的头标记。

至于珠子的顺序，你可以这样确定：将项链放到桌面上，不要出现交叉，随意指定第一颗珠子，然后按顺时针方向确定其他珠子的顺序。

【输出文件】

输出文件energy.out只有一行，是一个正整数E（E≤2.1*10⁹），为一个最优聚合顺序所释放的总能量。

【输入样例】

  4

  2  3  5  10

【输出样例】

710

===========

区间动归

=============

记忆化....

----------------

var
  n:longint;
  a:array[0..100]of longint;
  f:array[0..100,0..100]of longint;
  xx:longint;
procedure init;
begin
  assign(input,'energy.in');
  assign(output,'energy.out');
  reset(input);
  rewrite(output);
end;

procedure terminate;
begin
  close(input);
  close(output);
  halt;
end;

function max(a,b:longint):longint;
begin
  if a>b then exit(a);
  exit(b);
end;

function search(s,t:longint):longint;
var
  i:longint;
begin
  if f[s mod n,t mod n]<>0 then exit(f[s mod n,t mod n]);
  search:=0;
  for i:=s+1 to t-1 do
    begin
      search:=max(search,search(s,i)+search(i,t)+a[s mod n]*a[t mod n]*a[i mod n]);
    end;
  f[s mod n,t mod n]:=search;
end;

procedure main;
var
  i,j,k:longint;
  max:longint;
  //xx:lo
begin
  readln(n);
  for i:=1 to n do
    read(a[i]);
  a[0]:=a[n];
  max:=0;
  fillchar(f,sizeof(f),0);
  //for i:=0 to n do
   //f[i,i]:=0;
  //fillchar(xx,sizeof(xx),$7);
  
  for i:=0 to n-1 do
    begin
      if max<search(i,i+n)
        then max:=search(i,i+n);
    end;
    
  writeln(max);
end;

begin
  init;
  main;
  terminate;
end.

 

----------------

递推

----------

var
  n:longint;
  a:array[1..200]of longint;
  f:array[0..200,0..200]of longint;
procedure init;
begin
  assign(input,'p1062.in');
  assign(output,'p1062.out');
  reset(input); rewrite(output);
end;

procedure terminate;
begin
  close(input); close(output);
  halt;
end;

function max(a,b:longint):longint;
begin
  if a>b then exit(a);
  exit(b);
end;

procedure main;
var
  i,j:longint;
  len:longint;
  ans:longint;
begin
  readln(n);
  for i:=1 to n do
    begin
      read(a[i]);
      a[i+n]:=a[i];
    end;
  fillchar(f,sizeof(f),0);
  ans:=0;
  for len:=1 to n-1 do    //枚举间隔...
    for i:=1 to 2*n-len do //枚举头结点
      for j:=i to i+len-1 do   //枚举断点
        begin
          f[i,i+len]:=max(f[i,i+len],f[i,j]+f[j+1,i+len]+a[i]*a[j+1]*a[i+len+1]);
          ans:=max(f[i,i+len],ans);
        end;
  writeln(ans);
end;

begin
  init;
  main;
  terminate;
end.