字串距离

 

字串距离  

源程序名            blast.???（pas, c, cpp） 可执行文件名        blast.exe 输入文件名          blast.in 输出文件名          blast.out

【问题描述】

       设有字符串X，我们称在X的头尾及中间插入任意多个空格后构成的新字符串为X的扩展串，如字符串X为”abcbcd”，则字符串“abcb□cd”，“□a□bcbcd□”和“abcb□cd□”都是X的扩展串，这里“□”代表空格字符。

       如果A1是字符串A的扩展串，B1是字符串B的扩展串，A1与B1具有相同的长度，那么我扪定义字符串A1与B1的距离为相应位置上的字符的距离总和，而两个非空格字符的距离定义为它们的ASCII码的差的绝对值，而空格字符与其他任意字符之间的距离为已知的定值K，空格字符与空格字符的距离为0。在字符串A、B的所有扩展串中，必定存在两个等长的扩展串A1、B1，使得A1与B1之间的距离达到最小，我们将这一距离定义为字符串A、B的距离。

       请你写一个程序，求出字符串A、B的距离。

【输入】

       输入文件第一行为字符串A，第二行为字符串B。A、B均由小写字母组成且长度均不超过2000。第三行为一个整数K（1≤K≤100），表示空格与其他字符的距离。

【输出】

       输出文件仅一行包含一个整数，表示所求得字符串A、B的距离。

【样例】

       blast.in                                       blast.out

       cmc                                           10

       snmn

       2

=========================

DP

定义一个F[I,J]表示st1串前i个和st2串前j个求的的距离最小且st1串前i个的长度=st2串前j个的长度

f[i,j]:=min(f[i,j-1]+k,f[i-1,j]+k,f[i-1,j-1]+abs(ord(st1[i)]-ord(st2[j])))

-----------------------------------

边界的考虑：

f[i,0]:=i*k;

f[0,j]:=j*k;

---------------------最开始时没想到....

==========================

var
  k:longint;
  st1,st2:ansistring;
  len1,len2:longint;
  f:array[0..2000,0..2000]of longint;
procedure init;
begin
  assign(input,'blast.in');
  assign(output,'blast.out');
  reset(input); rewrite(output);
end;

procedure terminate;
begin
  close(input); close(output);
  halt;
end;

function min(a,b:longint):longint;
begin
  if a<b then exit(a);
  exit(b);
end;

procedure main;
var
  i,j:longint;
begin
  readln(st1);
  readln(st2);
  readln(k);
  len1:=length(st1);
  len2:=length(st2);
  fillchar(f,sizeof(f),0);
  for i:=1 to len1 do
    f[i,0]:=i*k;
  for i:=1 to len2 do
    f[0,i]:=i*k;
  f[0,0]:=0;
  for i:=1 to len1 do
    for j:=1 to len2 do
      begin
        f[i,j]:=f[i-1,j]+k;
        f[i,j]:=min(f[i,j],f[i,j-1]+k);
        f[i,j]:=min(f[i,j],f[i-1,j-1]+abs(ord(st1[i])-ord(st2[j])));
      end;
  writeln(f[len1,len2]);
end;

begin
  init;
  main;
  terminate;
end.