【DP】创意吃鱼法

 

创意吃鱼法

 提交文件：meal.pas/c/cpp

输入文件：meal.in

输出文件：meal.out

 

回到家中的猫猫把三桶鱼全部转移到了她那长方形大池子中，然后开始思考：到底要以何种方法吃鱼呢（猫猫就是这么可爱，吃鱼也要想好吃法 ^_*）。她发现，把大池子视为01矩阵（0表示对应位置无鱼，1表示对应位置有鱼）有助于决定吃鱼策略。

在代表池子的01矩阵中，有很多的正方形子矩阵，如果某个正方形子矩阵的某条对角线上都有鱼，且此正方形子矩阵的其他地方无鱼，猫猫就可以从这个正方形子矩阵“对角线的一端”下口，只一吸，就能把对角线上的那一队鲜鱼吸入口中。

　　猫猫是个贪婪的家伙，所以她想一口吃掉尽量多的鱼。请你帮猫猫计算一下，她一口下去，最多可以吃掉多少条鱼？

 

输入数据：

　　第一行有两个整数n和m（n,m≥1），描述池塘规模。接下来的n行，每行有m个数字（非“0”即“1”）。每两个数字之间用空格隔开。

　　对于30%的数据，有n,m≤100

　　对于60%的数据，有n,m≤1000

　　对于100%的数据，有n,m≤2500

 

输出数据：

　　只有一个整数——猫猫一口下去可以吃掉的鱼的数量，占一行，行末有回车。

 

输入样例：

4 6

0 1 0 1 0 0

0 0 1 0 1 0

1 1 0 0 0 1

0 1 1 0 1 0

 

输出样例：

3

===========================

===============================

var
  n,m:longint;
  map:array[1..2500,1..2500]of integer;
  f:array[0..2501,0..2501]of integer;
  left,up,down:array[0..2501,0..2501]of integer;
procedure init;
begin
  assign(input,'meal.in');
  assign(output,'meal.out');
  reset(input); rewrite(output);
end;

procedure terminate;
begin
  close(input); close(output);
  halt;
end;

function min(a,b:longint):longint;
begin
  if a>b then exit(b);
  exit(a);
end;

procedure main;
var
  i,j,k:longint;
  ans:longint;
begin
  readln(n,m);
  ans:=0;
  fillchar(left,sizeof(left),0);
  fillchar(up,sizeof(up),0);
  fillchar(down,sizeof(down),0);
  
  for i:=1 to n do
    for j:=1 to m do
      begin
        read(map[i,j]);
        if map[i,j]=1 then
          begin
            left[i,j]:=0;
            up[i,j]:=0;
          end
          else
          begin
            left[i,j]:=left[i,j-1]+1;  //维护向左可以有几个
            up[i,j]:=up[i-1,j]+1;      //维护向上可以有几个
          end;
      end;
      
  for i:=n downto 1 do
    for j:=1 to m do
      if map[i,j]=1 then
        begin
          down[i,j]:=0;
        end
        else
        begin
          down[i,j]:=down[i+1,j]+1;    //维护向下可以有几个..
        end;
        
  fillchar(f,sizeof(f),0);
  for i:=1 to n do
    for j:=1 to m do        //枚举右下角
      if map[i,j]=1 then
        begin
          f[i,j]:=left[i,j-1]+1;
          if f[i,j]>f[i-1,j-1]+1 then f[i,j]:=f[i-1,j-1]+1;
          if f[i,j]>up[i-1,j]+1 then f[i,j]:=up[i-1,j]+1;
          if f[i,j]>ans then ans:=f[i,j];
        end;
        
  fillchar(f,sizeof(f),0);
  for i:=n downto 1 do         //枚举左上角.
    for j:=1 to m do
      if map[i,j]=1 then
        begin
          f[i,j]:=left[i,j-1]+1;
          if f[i,j]>f[i+1,j-1]+1 then f[i,j]:=f[i+1,j-1]+1;
          if f[i,j]>down[i+1,j]+1 then f[i,j]:=down[i+1,j]+1;
          if f[i,j]>ans then ans:=f[i,j];
        end;
  writeln(ans);
end;

begin
  init;
  main;
  terminate;
end.