【SPFA+DP】物流运输

物流运输（trans.pas/c/cpp）

    【问题描述】

    物流公司要把一批货物从码头A运到码头B。由于货物量比较大，需要n天才能运完。货物运输过程中一般要转停好几个码头。物流公司通常会设计一条固定的运输路线，以便对整个运输过程实施严格的管理和跟踪。由于各种因素的存在，有的时候某个码头会无法装卸货物。这时候就必须修改运输路线，让货物能够按时到达目的地。但是修改路线是—件十分麻烦的事情，会带来额外的成本。因此物流公司希望能够订一个n天的运输计划，使得总成本尽可能地小。

   【文件输入】

    第一行是四个整数n(l≤n≤100)、m(l≤m≤20)、K和e。n表示货物运输所需天数，m表示码头总数，K表示每次修改运输路线所需成本。接下来e行每行是一条航线描述，包括了三个整数，依次表示航线连接的两个码头编号以及航线长度(>0)。其中码头A编号为1，码头B编号为m。单位长度的运输费用为1。航线是双向的。再接下来一行是一个整数d，后面的d行每行是三个整数P(1<P<m)，a，b(1≤a≤b≤n)。表示编号为P的码头从第a天到第b天无法装卸货物（含头尾）。同一个码头有可能在多个时间段内不可用。但任何时间都存在至少一条从码头A到码头B的运输路线。

   【文件输出】

    包括了一个整数表示最小的总成本。总成本=n天运输路线长度之和+K*改变运输路线的次数。

   【样例输入】

  5 5 10 8

  1 2 1

  1 3 3

  1 4 2

  2 3 2

  2 4 4

  3 4 1

  3 5 2

  4 5 2

  4

  2 2 3

  3 1 1

  3 3 3

  4 4 5

   【样例输出】

  32

   【样例输入说明】

   上图依次表示第1至第5天的情况，阴影表示不可用的码头。

  【样例输出说明】

  前三天走1-4-5，后两天走1-3-5，这样总成本为(2+2)*3+(3+2)*2+10=32。

 ====================================

==========================================

type
  pnode=^node;
  node=record
         x,c:longint;
         next:pnode;
       end;
var
  n,m,k,e:longint;
  d:longint;
  map:array[1..20]of pnode;
  f_bo:array[1..20,1..100]of boolean;
  map_bo,v:array[1..100]of boolean;
  dist:array[1..20]of longint;
  f:array[0..100]of longint;
  queue:array[1..200000]of longint;
procedure init;
begin
  assign(input,'trans.in');
  assign(output,'trans.out');
  reset(input); rewrite(output);
end;

procedure terminate;
begin
  close(input); close(output);
  halt;
end;

procedure insert(a,b,c:longint);
var
  p:pnode;
begin
  new(p);
  p^.x:=b; p^.c:=c;
  p^.next:=map[a];
  map[a]:=p;
end;

procedure readdata;
var
  i,j:longint;
  a,b,c:longint;
begin
  readln(n,m,k,e);
  for i:=1 to m do map[i]:=nil;
  for i:=1 to e do
    begin
      readln(a,b,c);
      insert(a,b,c);
      insert(b,a,c);
    end;
  fillchar(f_bo,sizeof(f_bo),true);
  readln(d);
  for i:=1 to d do
    begin
      readln(a,b,c);
      for j:=b to c do f_bo[a][j]:=false;
    end;
end;

function min(a,b:longint):longint;
begin
  if a<b then exit(a);
  exit(b);
end;

function spfa(s,t:longint):longint;
var
  i,j:longint;
  p:pnode;
  l,r:longint;
  x:longint;
begin
  fillchar(map_bo,sizeof(map_bo),true);
  for i:=1 to m do
    for j:=s to t do
      if not f_bo[i,j] then
        map_bo[i]:=false;
  fillchar(dist,sizeof(dist),$7);
  fillchar(v,sizeof(v),true);
  dist[1]:=0;
  v[1]:=false;
  l:=0; r:=1;
  queue[1]:=1;
  repeat
    inc(l);
    x:=queue[l];
    p:=map[x];
    while p<>nil do
     begin
       if map_bo[p^.x] then
         begin
           if dist[x]+p^.c<dist[p^.x] then
             begin
               dist[p^.x]:=dist[x]+p^.c;
               if v[p^.x] then
                 begin
                   v[p^.x]:=false;
                   inc(r);
                   queue[r]:=p^.x;
                 end;
             end;
         end;
       p:=p^.next;
     end;
    v[x]:=true;
  until l>=r;
  spfa:=dist[m];
end;

procedure main;
var
  i,j:longint;
  t:longint;
begin
  fillchar(f,sizeof(f),$7);
  f[0]:=0;
  for i:=1 to n do
    for j:=i-1 downto 0 do
      begin
        t:=spfa(j+1,i);
        if t<1000000 then
          begin
            if j=0 then f[i]:=min(f[i],f[j]+(i-j)*t{spfa(j+1,i)});
            if j>=1 then f[i]:=min(f[i],f[j]+(i-j)*t{spfa(j+1,i)}+k);
          end;
      end;
  writeln(f[n]);
end;

begin
  init;
  readdata;
  main;
  terminate;
end.