VBA命名参数":="用法和理解

 

当调用 Sub 或 Function 过程时，可以根据位置来提供参数，也就是出现在过程定义时的顺序，或者根据名称来提供参数，如此就不用管它的位置。

例如，下面的 Sub 程序接受三个参数：

Sub PassArgs(strName As String, intAge As Integer, dteBirth As Date)
    Debug.Print strName, intAge, dteBirth
End Sub

可以在正确的位置上提供其参数来调用该过程，每个参数之间都以逗点来区隔，如下列的示例所示：

PassArgs "Mary", 29, #2-21-69#

也可以有提供命名参数的方式来调用过程，每个参数之间也是以逗点来间隔。

PassArgs intAge:=29, dteBirth:=#2/21/69#, strName:="Mary"

命名参数是由参数名称接着冒号和一个等号（:=）最后加上参数值所组成。

命名参数在调用具有可选的参数过程时显得特别有用。如果使用命名参数，则不必利用逗号去区分出失去位置的参数。使用命名参数可以很容易的追踪出传递和省略了那些参数。

在过程的定义中，可选的参数前会有一个 Optional 关键字。在过程的定义中也可以指定一个缺省值赋予可选的参数。例如：

Sub OptionalArgs(strState As String, Optional strCountry As String = "USA")
. . . 
End Sub

当在调用具有可选的参数的过程时，可以选择是否要对可选的参数给于一个值（如果没有的话则会采用缺省值）。如果没有指定缺省值，则此参数可以是属于所指定类型的任何变量。

下列过程包含一个可选的参数，varCountry 变量。而 IsMissing 函数可以决定一个可选的参数是否已经传递给过程。

Sub OptionalArgs(strState As String, Optional intRegion As Integer, _
Optional strCountry As String = "USA")
    If IsMissing(intRegion) And IsMissing(strCountry) Then
        Debug.Print strState
    ElseIf IsMissing(strCountry) Then
        Debug.Print strState, intRegion
    ElseIf IsMissing(intRegion) Then
        Debug.Print strState, strCountry
    Else
        Debug.Print strState, intRegion, strCountry
    End If
End Sub

可以使用命名参数来调用上述程序；如下示例所示：

OptionalArgs strCountry:="USA", strState:="MD"

OptionalArgs strState:= "MD", intRegion:=5