Hidden Password usaco5.5 最小表示法

Description

---

有时候程序员有很奇怪的方法来隐藏他们的口令。Billy”Hacker”Geits会选择一个字符串S（由L个小写字母组成，5<=L<=100,000），然后他把S顺时针绕成一个圈，每次取一个做开头字母并顺时针依次取字母而组成一个字符串。这样将得到一些字符串，他把它们排序后取出第一个字符串。把这个字符串的第一个字母在原字符串中的位置做为口令。
第一个字母所在的位置是0
如字符串alabala，按操作得到7个字符串，排序后得：
aalabal abalaal alaalab alabala balaala laalaba labalaa
第一个字符串为aalabal，这个a在原字符串位置为6，则6为口令。

Solution

---

对于一个长度为n的字符串s连成环后有n种表示方法，那么我们的任务是找到其中字典序最小的辣个

把字符串st复制一遍，用指针i、j，记录长度k，若st[i+k]< st[j+k]表示i开头的表示法是二者中最优的，那么把j提到j+k+1，否则把i提到i+k+1。这样找到的一定是最小的

Code

---

{
ID:wjp13241
PROG:hidden
LANG:PASCAL
}
function min(x,y:longint):longint;
begin
  min:=x;
  if y<x then
  min:=y;
end;
var
  n,i,j,k,len:longint;
  tmp,st:ansistring;
begin
  assign(input,'hidden.in');
  assign(output,'hidden.out');
  reset(input);
  rewrite(output);
  readln(len);
  while not eof do
  begin
    readln(tmp);
    st:=st+tmp;
  end;
  st:=st+st;
  i:=1;
  j:=2;
  while (i<=len)and(j<=len) do
  begin
    k:=0;
    while (st[i+k]=st[j+k])and(k<len) do
      inc(k);
    if k=len then break;
    if st[i+k]<st[j+k] then
      j:=j+k+1
    else
      i:=i+k+1;
    if i=j then
      inc(j);
  end;
  writeln(min(i,j)-1);
  close(input);
  close(output);
end.