VS2017\VS2019\VS2022项目多余文件(中间文件\临时文件)一键清理BAT

kim-2006

已于 2022-07-12 15:34:10 修改

阅读量5.8k

点赞数 5

分类专栏：好东西文章标签：清理工具

于 2022-07-07 15:32:11 首次发布

本文链接：https://blog.csdn.net/k83133058/article/details/125660078

版权

好东西专栏收录该内容

10 篇文章 0 订阅

订阅专栏

先看看一个MFC项目清理前所占用的磁盘空间

清理后占用的磁盘空间

清理后再备份就方便多了！

使用方法一，把要清理的项目拖到BAT文件上就会执行清理工作。

使用方法二，命令行方式。

BAT文件代码

@echo off
title 清理VS项目临时文件, 以便备份.
setlocal enabledelayedexpansion

rem 本BAT支持清理VS2017、VS2019、VS2022建立的项目，其它版本的VS项目请自行测试.
rem 可清理的项目类型: QT、MFC、Win32、控制台等项目的多余文件.
rem 本BAT不适合修改过目录设置的项目.

:: 可自行设置和参数
:: VS版本 vs2017=v15, vs2019=v16, vs2022=v17
set Version=v17

:: 勿动
set ProjectDir=%~f1
set ProjectName=%~nx1
if not exist !ProjectDir! (
echo 不要双击本BAT文件!
echo 请把要清理的项目文件夹拖到本BAT文件上!
) else (
echo 清理的项目路径: %ProjectDir%
rem echo "!ProjectDir!\.vs\!ProjectName!\!Version!\*.db"

rem 清理.vs目录
del /f /q "!ProjectDir!\.vs\!ProjectName!\!Version!\*.db" 1>nul 2>nul
::del /f /s /q "!ProjectDir!\.vs\!ProjectName!\!Version!\ipch\*.ipch" 1>nul 2>nul
::rd /s /q "!ProjectDir!\.vs\!ProjectName!\!Version!\ipch\AutoPCH" 1>nul 2>nul
rd /s /q "!ProjectDir!\.vs\!ProjectName!\!Version!\ipch\" 1>nul 2>nul
:: vs2022
rd /s /q "!ProjectDir!\.vs\!ProjectName!\FileContentIndex" 1>nul 2>nul

rem 清理.aps文件, 这个文件特别大
del /f /q "!ProjectDir!\!ProjectName!\*.aps" 1>nul 2>nul

rem 清理中间文件
rd /s /q "!ProjectDir!\!ProjectName!\Release" 1>nul 2>nul
rd /s /q "!ProjectDir!\!ProjectName!\Debug" 1>nul 2>nul
rd /s /q "!ProjectDir!\!ProjectName!\x64" 1>nul 2>nul

rem 清理编译输出目录
rd /s /q "!ProjectDir!\Release" 1>nul 2>nul
rd /s /q "!ProjectDir!\Debug" 1>nul 2>nul
rd /s /q "!ProjectDir!\x64" 1>nul 2>nul
)

pause & exit