8.4 从继承到多态
继承是避免代码重复和在不同类之间共享代码方法的一种强大技术。然而,继承的真正威力在于它能以统一的方式处理不同类的对象,这在面向对象编程语言中通常被称为多态性(polymorphism)或延迟绑定(late binding)。
要充分理解这一特性,我们需要探究几个要素:派生类之间的类型兼容性、虚拟方法等,这些内容将在接下来的几节中介绍。
8.4.1 继承和类型兼容性
Object Pascal
是一种严格类型的语言,这意味着值必须是相同的数据类型,操作才有效。不过,类类型有一个例外。如果你声明了一个类(如 TAnimal),并派生了一个新类(如 TDog),你就可以将 TDog 类型的对象赋值给 TAnimal 类型的变量。这是因为狗是一种动物这一逻辑关系。以下构造函数调用是合法的:
var
MyAnimal1, MyAnimal2: TAnimal;
begin
MyAnimal1 := TAnimal.Create;
MyAnimal2 := TDog.Create;
更准确地说,您可以在期望祖先类对象的任何地方使用后代类的对象。然而,反过来是不合法的;您不能在期望后代类对象的地方使用祖先类对象。为了简化解释,在代码中再次表示如下:
MyAnimal := MyDog; // 这是OK的
MyDog := MyAnimal; // 这是错误的!!!
事实上,虽然我们总是可以说狗是一种动物,但我们不能假定任何一种动物就是狗。有时可能是这样,但并不总是这样。这是非常合乎逻辑的,语言类型兼容性规则也遵循同样的逻辑。
在了解该语言这一重要特性的含义之前,您可以试试 Animals1 示例,该示例定义了两个简单的 TAnimal 和 TDog 类,一个继承自另一个:
type
TAnimal = class
public
constructor Create;
function GetKind: string;
private
FKind: string;
end;
TDog = class(TAnimal)
public
constructor Create;
end;
这两个Create方法只是设置 FKind 的值,而 FKind 的值是由 GetKind 函数返回的。
图 8.2:开发环境中Animals1示例的窗体
如图 8.2 所示,该示例的窗体有两个单选按钮(由面板托管),用于选择一个或另一个类的对象。该对象存储在 TAnimal 类型的私有字段 FMyAnimal 中。创建窗体时会创建并初始化该类的一个实例,每次选择其中一个单选按钮时都会重新创建该实例(这里我只显示第二个单选按钮的代码):
procedure TFormAnimals.FormCreate(Sender: TObject);
begin
FMyAnimal := TAnimal.Create;
end;
procedure TFormAnimals.RadioButton2Change(Sender: TObject);
begin
FMyAnimal.Free;
FMyAnimal := TDog.Create;
end;
最后,"Kind"按钮会调用当前动物的 GetKind 方法,并将结果显示在窗体底部的Memo控件中:
procedure TFormAnimals.BtnKindClick(Sender: TObject);
begin
Show(FMyAnimal.GetKind);
end;