(delphi11最新学习资料) Object Pascal 学习笔记---第14章泛型第2节（泛型类型函数 ）

14.2.4 泛型类型函数

​ 到目前为止，我们遇到的泛型类型定义的最大问题是，您对泛型类型元素能做的事情非常少。有两种技术可以用来克服这个限制。第一种是利用运行时库的一些特殊函数，这些函数专门支持泛型类型；第二种（也是更强大的一种）是在定义泛型类时对可以使用的类型进行限制。

​ 本节将重点介绍第一种方法，下一节将重点介绍约束。正如我提到的，有一些 RTL 函数可以处理泛型定义的参数类型 (T)：

• Default（T）实际上是与泛型一起引入的新函数，它返回当前类型的空值或“零值”或null值，可以是零、空字符串、nil等；事实上，全局变量与局部变量不同，编译器会将全局变量初始化为 “零”）

• TypeInfo（T）返回指向当前版本的泛型类型的运行时信息的指针；有关类型信息的更多信息，请参见第16章

• SizeOf（T）返回类型的字节数（对于引用类型，如字符串或对象，它将是引用的大小，即32位编译器的4个字节，64位编译器的8个字节）

• IsManagedType（T）指示类型是否在内存中受管理，例如字符串和动态数组

• HasWeakRef（T）与支持ARC的编译器相关，表示目标类型是否具有弱引用；这需要特定的内存管理支持

• GetTypeKind（T）是一种从类型信息访问类型种类的快捷方式；它是比TypeInfo返回的类型定义稍高一级的类型定义

注意 所有这些方法都返回编译器评估过的常量，而不是在运行时调用实际函数。这一点的重要性并不在于这些操作非常快，而在于这使编译器和链接器可以优化生成的代码，删除未使用的分支。如果有一个 case 或 if 语句是基于这些函数之一的返回值，编译器立即就能算出，仅对于给定类型，其中一个分支将被执行，从而删除无用的代码。当针对不同类型编译相同的泛型方法时，可能会使用不同的分支，但编译器同样可以预先计算并优化方法的大小。

​ GenericTypeFunc 示例中有一个泛型类，展示了三个泛型类型的函数的作用：

type
    TSampleClass<T> = class
    private
    	FData: T;
    public
        procedure Zero;
        function GetDataSize: Integer;
        function GetDataName: string;
    end;

    function TSampleClass<T>.GetDataSize: Integer;
    begin
    	Result := SizeOf(T);
    end;

    function TSampleClass<T>.GetDataName: string;
    begin
   		Result := GetTypeName(TypeInfo(T));
    end;

    procedure TSampleClass<T>.Zero;
    begin
    	FData := Default(T);
    end;

​ 在GetDataName方法中，我使用了GetTypeName函数（System.TypInfo单元的函数），而不是直接访问数据结构，因为它可以执行保持类型名称的字符串值编码的正确转换。

​ 给定上述声明，您可以编译以下测试代码，该代码在三个不同的泛型类型实例上重复三次。我省略了重复的代码，并仅显示用于访问数据字段的语句，因为它们会根据实际类型而改变：

var
    T1: TSampleClass<Integer>;
    T2: TSampleClass<string>;
    T3: TSampleClass<Double>;
begin
    T1 := TSampleClass<Integer>.Create;
    T1.Zero;
    Show('TSampleClass<Integer>');
    Show('Data: ' + IntToStr(T1.FData));
    Show('Type: ' + T1.GetDataName);
    Show('Size: ' + IntToStr(T1.GetDataSize));
    T2 := TSampleClass<string>.Create;
    Show('Data: ' + T2.FData);
    T3 := TSampleClass<Double>.Create;
    Show('Data: ' + FloatToStr(T3.FData));

运行此代码（来自GenericTypeFunc示例）会产生以下输出：

TSampleClass<Integer>
Marco Cantù, Object Pascal Handbook 11
396 - 14: generics
Data: 0
Type: Integer
Size: 4
TSampleClass<string>
Data:
Type: string
Size: 4
TSampleClass<Double>
Data: 0
Type: Double
Size: 8

​ 请注意，您也可以在泛型类的上下文之外，对特定类型使用泛型类型函数。例如，您可以编写：

var
    I: Integer;
    s: string;
begin
    I := Default(Integer);
    Show('Default Integer: ' + IntToStr(I));
    s := Default(string);
    Show('Default String: ' + s);
    Show('TypeInfo String: ' + GetTypeName(TypeInfo(string));

这是一个简单的输出：

Default Integer: 0 
Default String: 
TypeInfo String: string 

注解：您不能像上面的代码中的TypeInfo（s）那样将TypeInfo调用应用于变量，而只能将其应用于数据类型。