(delphi11最新学习资料) Object Pascal 学习笔记---第11章第1节 （ 接口的实现）

11.1.2 接口的实现

​ 任何类都可以实现一个或多个接口，方法是在继承的基类后面列出这些接口，并为每个接口的每个方法提供一个实现：

type
  TAirplane = class(..., ICanFly)
    function Fly: string;
  end;

function TAirplane.Fly: string;
begin
  // 实际代码
end;

​ 当一个类实现一个接口时，这个类必须实现接口中所有的方法，并且方法签名要完全相同。如在本例中，TAirplane 类就必须将 Fly 方法实现为返回字符串的函数。由于接口也继承自一个基接口（IInterface），因此实现接口的类必须全部实现接口及基接口中的所有方法。

​ 这就是为什么一个类继承一个基类来实现接口的方式非常常见，因为这个基类已经实现了 IInterface 基接口方法。Object Pascal 运行库已经提供了这样一些基类来实现基本行为。这些类中最简单的是 TInterfacedObject 类，因此上面的代码可以变成：

type
  TAirplane = class(TInterfacedObject, ICanFly)
    function Fly: string;
  end;

注解 实现接口时，可以使用静态方法或虚方法。如果你打算覆盖继承类中的方法，使用虚拟方法是合理的。不过也有另一种方法，那就是指定基类也继承自相同的接口，然后覆盖该接口的方法。我倾向于在需要时将实现接口方法的方法声明为虚方法。

​ 现在我们已经定义了一个接口及其实现的类，我们可以创建这个类的对象。我们可以将其视为普通类，如下所示：

var
  Airplane1: TAirplane;
begin
  Airplane1 := TAirplane.Create;
  try
    Airplane1.Fly;
  finally
    Airplane1.Free;
  end;
end;

​ 在这种情况下，我们可以忽略类实现了接口这一事实。不同之处在于，现在我们还可以声明一个接口类型的变量。使用接口类型变量会自动启用引用内存模型，因此我们可以跳过 try-finally 块：

var
  Flyer1: ICanFly;
begin
  Flyer1 := TAirplane.Create;
  Flyer1.Fly;
end;

​ 对于这个看似简单的代码片段（也是 Intf101 示例的一部分）的第一行，有几个相关的注意事项。首先，只要将对象赋值给接口变量，运行时就会使用特殊版本的 as 操作符自动检查对象是否实现了该接口。您可以通过编写下面的同一行代码显式地进行这一操作：

Flyer1 := TAirplane.Create as ICanFly;

​ 其次，无论我们使用直接赋值还是 as 语句，运行时都会做一件额外的事情：调用对象的 _AddRef 方法，增加对象的引用计数。这是通过调用对象从基类 TInterfacedObject 继承的方法完成的。

​ 与此同时，一旦 Flyer1 变量离开作用域（即执行结束语句时），Delphi 运行时就会调用 _Release 方法，该方法会减少引用计数，检查引用计数是否为零，如果为零就销毁对象。这就是为什么在上面的代码中，我们不需要手动释放在代码中创建的对象，也不需要编写 try-finally 块。

注解 虽然上面的源代码没有 try-finally 代码块，但编译器会自动在方法中添加一个隐式 try-finally 代码块，并隐式调用 _Release。这种情况在 Object Pascal 中很多：基本上每当一个方法有一个或多个托管类型（如字符串、接口或动态数组）时，编译器都会自动添加一个隐式的 try-finally 代码块。

​ 正如我们在上面的代码中所看到的，被接口变量引用的 Object Pascal 对象是被引用计数的（除非接口类型变量被标记为弱变量或不安全变量，这将在后面解释）。我们还看到，当不再有接口变量引用这些对象时，它们会被自动回收。
​ 值得注意的是，虽然编译器会使用一些魔法（隐藏的 _AddRef 和 _Release 调用），但实际的引用计数机制取决于开发者或运行时库提供的具体实现。在上一个示例中，由于 TInterfacedObject 类方法中的代码（此处列出的是略微简化的版本），引用计数确实在起作用：

function TInterfacedObject._AddRef: Integer;
begin
  Result := AtomicIncrement(FRefCount);
end;

function TInterfacedObject._Release: Integer;
begin
  Result := AtomicDecrement(FRefCount);
  if Result = 0 then
  begin
    Destroy;
  end;
end;

​ 现在来看看RTL中另外一个实现 IInterface 接口的基类 TNoRefCountObject，该类基本上禁用了实际的引用计数机制：

function TNoRefCountObject._AddRef: Integer;
begin
  Result := -1;
end;

function TNoRefCountObject._Release: Integer;
begin
  Result := -1;
end;

​ Delphi 11 中引入了TNoRefCountObject 新类，该类的对象可以忽略引用计数机制。TNoRefCountObject 类用来取代名称奇怪的 TSingletonImplementation 类（定义在 Generics.Defaults 单元中）。旧的 TSingletonImplementation 类仍然作为较新的TNoRefCountObject 类的别名存在。这两个类的代码基本相同。改变的主要原因是，原来的类名不副实，因为它与单例模式毫无关系。我们将在下一章中看到单例模式的示例。

​ 虽然 TNoRefCountObject 并不常用，但还有一个类TComponent也实现了接口并禁用了引用计数机制，这只是因为它需要有自己的内存管理模式。如果你想拥有一个实现接口的自定义组件，就不必担心引用计数和内存管理问题。在本章最后的 "使用接口实现设计模式 "一节中，我们将看到一个自定义组件实现接口的例子。