(delphi11最新学习资料) Object Pascal 学习笔记---第14章泛型第2节（泛型类型实例化）

本文链接：https://blog.csdn.net/langfengyl/article/details/139534825

14.2.3 泛型类型实例化

请注意，这是一个相当高级的一节内容，重点关注泛型的一些内部细节及其潜在的优化。如果这是您第一次学习泛型，那么建议您多读一遍。

除了一些优化之外，每次实例化泛型类型时，无论是在方法中还是在类中，编译器都会生成一个新的类型。这种新类型不会与同一泛型的不同实例（或同一方法的不同版本）共用代码。。

以下是一个示例（它是GenericCodeGen示例的一部分）。该程序定义了一个泛型类：

type
    TSampleClass<T> = class
    private
    	FData: T;
    public
        procedure One;
        function ReadT: T;
        procedure SetT(Value: T);
    end;

这三个方法的实现如下（请注意，One方法与泛型类型完全无关）：

procedure TSampleClass<T>.One;
begin
	Form30.Show('OneT');
end;

function TSampleClass<T>.ReadT: T;
begin
	Result := FData;
end;

procedure TSampleClass<T>.SetT(Value: T);
begin
	FData := Value;
end;

现在主程序主要使用泛型类型来计算编译器生成实例的方法的内存地址。这是代码：

procedure TForm30.Button1Click(Sender: TObject);
var
    T1: TSampleClass<Integer>;
    T2: TSampleClass<string>;
begin
    T1 := TSampleClass<Integer>.Create;
    T1.SetT(10);
    T1.One;
    T2 := TSampleClass<string>.Create;
    T2.SetT('Hello');
    T2.One;
    Show('T1.SetT: ' +
    IntToHex(PInteger(@TSampleClass<Integer>.SetT)^, 8));
    Show('T2.SetT: ' +
    IntToHex(PInteger(@TSampleClass<string>.SetT)^, 8));
    Show('T1.One: ' +
    IntToHex(PInteger(@TSampleClass<Integer>.One)^, 8));
    Show('T2.One: ' +
    IntToHex(PInteger(@TSampleClass<string>.One)^, 8));
end;

结果大致如下（实际值会有所不同）：

T1.SetT: C3045089
T2.SetT: 51EC8B55
T1.One: 4657F0BA
T2.One: 46581CBA

正如我预料的那样，编译器不仅会为每个使用的不同数据类型SetT方法在内存中生成的不同版本，而且即使是完全相同的方法，如One方法也会这样做。

此外，如果重新声明相同的泛型类型，则会获得一组新的实现函数。同样，在不同单元中使用相同的泛型类型实例会强制编译器一遍又一遍地生成相同的代码，可能会导致显著的代码膨胀。因此，如果您有一个泛型类有许多不依赖于泛型类型的方法，则建议定义一个具有这些公共方法的非泛型基类，并具有泛型方法的继承泛型类：这样基类方法只编译一次并包含在可执行文件中。