VB实现excel自动拆分表格

最新推荐文章于 2025-02-19 17:30:00 发布

lcsjdn

最新推荐文章于 2025-02-19 17:30:00 发布

阅读量3k

点赞数 2

文章标签： excel

本文链接：https://blog.csdn.net/lcsjdn/article/details/115998931

版权

这篇博客介绍了一种使用VBA宏在Excel中实现数据按部门自动拆分的方法，避免了传统的人工筛选复制操作。通过创建对象字典，用户选择拆分依据列后，程序会自动生成新工作表并将数据按部门分类。此外，还提供了代码实现过程，以帮助用户在不支持自动拆分功能的老版本Excel中提升工作效率。

摘要生成于 C知道，由 DeepSeek-R1 满血版支持，前往体验 >

工作场景：从系统导出后人工处理完的excel数据，需要按照部门拆分并推送给各部门人员。

传统的工作方式就只能人工一个个部门筛选，复制粘贴出来各自发送。

其实现在有些版本的excel或wps已经集成了根据某列数据自动拆分表格数据，不过有些老版本的仍不支持，搜集了网上前辈的资料，结合自身实际，使用VB实现了该功能。

Sub splitTable()
    Dim d As Object, sht As Worksheet, arr, brr, r, kr, i&, j&, k&, x&
    Dim Rng As Range, Rg As Range, tRow&, tCol&, aCol&, pd&
    Application.ScreenUpdating = False '关闭屏幕更新
    Application.DisplayAlerts = False '关闭警告信息提示
    Set d = CreateObject("scripting.dictionary") 'set字典
    Set Rg = Application.InputBox("请框选拆分依据列！只能选择单列单元格区域！", Title:="提示", Type:=8)
    '用户选择的拆分依据列
    tCol = Rg.Column '取拆分依据列列标
    tRow = Val(Application.InputBox("请输入总表标题行的行数？"))
    '用户设置总表的标题行数
    If tRow = 0 Then MsgBox "你未输入标题行行数，程序退出。": Exit Sub
    Set Rng = ActiveSheet.UsedRange '总表的数据区域
    arr = Rng '数据范围装入数组arr
    tCol = tCol - Rng.Column + 1 '计算依据列在数组中的位置
    aCol = UBound(arr, 2) '数据源的列数
    For i = tRow + 1 To UBound(arr) '遍历数组arr
        If Not d.exists(arr(i, tCol)) Then
            d(arr(i, tCol)) = i '字典中不存在关键词则将行号装入字典
        Else
            d(arr(i, tCol)) = d(arr(i, tCol)) & "," & i '如果存在则合并行号，以逗号间隔
        End If
    Next
    For Each sht In Worksheets '遍历一遍工作表，如果字典中存在则删除
        If d.exists(sht.Name) Then sht.Delete
    Next
    kr = d.keys '字典的key集
    For i = 0 To UBound(kr) '遍历字典key值
        If kr(i) <> "" Then '如果key不为空
            r = Split(d(kr(i)), ",") '取出item里储存的行号
            ReDim brr(1 To UBound(r) + 1, 1 To aCol) '声明放置结果的数组brr
            k = 0
            For x = 0 To UBound(r)
                k = k + 1 '累加记录行数
                For j = 1 To aCol '循环读取列
                    brr(k, j) = arr(r(x), j)
                Next
            Next
            With Worksheets.Add(, Sheets(Sheets.Count))
            '新建一个工作表，位置在所有已存在sheet的后面
                .Name = kr(i) '表格命名
                .[a1].Resize(tRow, aCol) = arr '放标题行
                .[a1].Offset(tRow, 0).Resize(k, aCol) = brr '放置数据区域
                Rng.Copy '复制粘贴总表的格式
                .[a1].PasteSpecial Paste:=xlPasteFormats, Operation:=xlNone, SkipBlanks:=False, Transpose:=False
                .[a1].Select
            End With
        End If
    Next
    Sheets(1).Activate '激活第一个表格
    Set d = Nothing '释放字典
    Erase arr: Erase brr '释放数组
    MsgBox "数据拆分完成！"
    Application.ScreenUpdating = True '恢复屏幕更新
    Application.DisplayAlerts = True '恢复警示
    
'开始生成新excel文件
    Application.ScreenUpdating = False
    For Each sht In Worksheets
        sht.Copy
        ActiveWorkbook.SaveAs Filename:=ThisWorkbook.Path & "\" & sht.Name, FileFormat:=xlOpenXMLWorkbook, CreateBackup:=False
        ActiveWorkbook.Close
    Next
    
    Application.ScreenUpdating = True '恢复屏幕更新
End Sub

运行过程如下：