新斯诺克

最新推荐文章于 2021-06-01 12:53:10 发布

歘_

最新推荐文章于 2021-06-01 12:53:10 发布

阅读量790

点赞数

分类专栏：分治文章标签：分治

本文链接：https://blog.csdn.net/lcyzlcl/article/details/49152577

版权

分治专栏收录该内容

1 篇文章 0 订阅

订阅专栏

题目描述

Description
斯诺克又称英式台球，是一种流行的台球运动。在球桌上，台面四角以及两长边中心位置各有一个球洞，使用的球分别为1 个白球，15 个红球和6 个彩球（黄、绿、棕、蓝、粉红、黑）共22个球。
击球顺序为一个红球、一个彩球直到红球全部落袋，然后以黄、绿、棕、蓝、粉红、黑的顺序逐个击球，最后以得分高者为胜。斯诺克的魅力还在于可以打防守球，可以制造一些障碍球使对方无法击打目标球而被扣分。正是因为这样，斯诺克是一项充满神奇的运动。
现在考虑这样一种新斯诺克，设母球（母球即是白球，用于击打其他球）的标号为M，台面上有N 个红球排成一排，每一个红球都有一个标号，他们的标号代表了他们的分数。
现在用母球击打这些红球，一杆击打，如果母球接触到红球，就称为“K 到红球”。我们假设，一次可以击打任意多相邻连续的红球，也可以只击打一个球。并且红球既不会落袋，也不会相互发生碰撞，而只是停留在原处。每次击打时候，要想“K 到红球”，至少要击打一个红球，如果想一次击打多个红球，那么击打的红球必须是依次连续排列的。如果一次“K 到红球”所有红球的标号之和的平均数大于母球的标号M，就获得了一个“连击”。
现在请你计算总共能有多少种“连击”方案。
注意：如果当前有标号为1、2、3 的三种红球，母球标号为0，有如下6 种获得“连击”方案：（ 1）、（ 2）、（ 3）、（ 1，2）、（ 2，3）、（ 1，2，3）
输入描述 Input Description
共有两行。
第一行是N，M (N<=100000，M<=10000) ，N 表示台面上一共有N 个红球，M 表示母球的标号。
第二行是N 个正整数，依次表示台面上N 个红球的标号，所有标号均不超过10000。
输出描述 Output Description
只有一个数，为“连击”的方案总数。
样例输入 Sample Input
4 3
3 7 2 4
样例输出 Sample Output
7

解题思路

这个题啊！。。。。看着貌似非常高大上。。。但是并不是这样。
题目即求在长度为n的序列中有多少长度大于等于1的连续的，平均数大于m的序列的个数。
现在假设从i到j是一列符合要求的连击。sum【i】是前i个数的总和。那么

（sum【j】-sum【i】）/（j-i）>m
即（sum【j】-sum【i】）>m * j-m * i
即 m * i-sum【i】>m * j-sum【j】

令a【i】：=sum【i】-m * i

即须a【i】>a【j】且 i< j

啊啊啊啊啊啊啊啊啊啊啊啊啊啊啊。。。逆序对啊！！！！！！
所以构造新数列然后求逆序对就OK啦！！！

但是不要现在就开始ZB，因为求逆序对时要从0到n。。为什么呢？
因为是（sum【j】-sum【i】）>m * j-m * i，可知
如果选择前一个球那么应该是（sum【1】-0）>m * 1-m * 0；
如果选择前两个球那么应该是（sum【2】-0）>m * 2-m * 0；
如果选择前三个球那么应该是（sum【3】-0）>m * 3-m * 0；
如果选择前 i 个球那么应该是（sum【 i 】-0）>m * i-m * 0；
。。。。。。
可知应在所有球的最前面加一个假想的球a【0】，其编号为0。
这样使sum【0】：=0；然后使在选择前i个球符合要求时的方案能在计算时加入计算。

代码

var i,x,n,m:longint;
    ans,sum:int64;
    a,c:array[0..100000]of longint;

procedure msort(s,t:longint);
var m,i,j,k:longint;
begin
  m:=(s+t)>>1;
  if s=t then exit;
  msort(s,m);
  msort(m+1,t);
  i:=s; j:=m+1; k:=s;
  while (i<=m)and(j<=t) do
    begin
      if a[i]>a[j]
       then
         begin
           inc(ans,m-i+1);
           c[k]:=a[j];
           inc(k);
           inc(j);
         end
       else
         begin
           c[k]:=a[i];
           inc(k);
           inc(i);
         end;
    end;
  while (i<=m) do
    begin
      c[k]:=a[i];
      inc(k);
      inc(i);
    end;
  while (j<=t) do
    begin
      c[k]:=a[j];
      inc(k);
      inc(j);
    end;
  for i:=s to t do a[i]:=c[i];
end;

begin

  readln(n,m);
  sum:=0;
  for i:=1 to n do
    begin
      read(x);
      inc(sum,x);
      a[i]:=i*m-sum;
    end;
  ans:=0;
  msort(0,n);   //神奇的0
  write(ans);
end.


测试通过 Accepted

总耗时: 133 ms
0 / 0 数据通过测试.
运行结果
测试点#sheeta1.in  结果:AC    内存使用量:  256kB     时间使用量:  0ms     
测试点#sheeta10.in  结果:AC    内存使用量:  880kB     时间使用量:  35ms     
测试点#sheeta2.in  结果:AC    内存使用量:  256kB     时间使用量:  1ms     
测试点#sheeta3.in  结果:AC    内存使用量:  256kB     时间使用量:  0ms     
测试点#sheeta4.in  结果:AC    内存使用量:  256kB     时间使用量:  0ms     
测试点#sheeta5.in  结果:AC    内存使用量:  368kB     时间使用量:  4ms     
测试点#sheeta6.in  结果:AC    内存使用量:  620kB     时间使用量:  15ms     
测试点#sheeta7.in  结果:AC    内存使用量:  752kB     时间使用量:  22ms     
测试点#sheeta8.in  结果:AC    内存使用量:  880kB     时间使用量:  28ms     
测试点#sheeta9.in  结果:AC    内存使用量:  1008kB     时间使用量:  28ms