侦探推理 （NOIP2003）

题目描述

　>　明明同学最近迷上了侦探漫画《柯南》并沉醉于推理游戏之中，于是他召集了一群同学玩推理游戏。游戏的内容是这样的，明明的同学们先商量好由其中的一个人充当罪犯（在明明不知情的情况下），明明的任务就是找出这个罪犯。接着，明明逐个询问每一个同学，被询问者可能会说：
　　证词中出现的其他话，都不列入逻辑推理的内容。
　　明明所知道的是，他的同学中有N个人始终说假话，其余的人始终说真。
　　现在，明明需要你帮助他从他同学的话中推断出谁是真正的凶手，请记住，凶手只有一个！
输入输出格式
输入格式：
　　输入由若干行组成，第一行有二个整数，M（1≤M≤20）、N（1≤N≤M）和P（1≤P≤100）；M是参加游戏的明明的同学数，N是其中始终说谎的人数，P是证言的总数。接下来M行，
每行是明明的一个同学的名字（英文字母组成，没有主格，全部大写）。
　　往后有P行，每行开始是某个同学的名宇，紧跟着一个冒号和一个空格，后面是一句证词，符合前表中所列格式。证词每行不会超过250个字符。
　　输入中不会出现连续的两个空格，而且每行开头和结尾也没有空格。
输出格式：
　　如果你的程序能确定谁是罪犯，则输出他的名字；如果程序判断出不止一个人可能是罪犯，则输出 Cannot Determine；如果程序判断出没有人可能成为罪犯，则输出 Impossible。
输入输出样例
输入样例#1：
3 1 5
MIKE
CHARLES
KATE
MIKE: I am guilty.
MIKE: Today is Sunday.
CHARLES: MIKE is guilty.
KATE: I am guilty.
KATE: How are you??
输出样例#1：
MIKE

---

分析

打完这个题，永远难忘字符串。。。。而且。。。您会感觉脑洞突然大了些呢！
我写这个blog的原因就是想存下来这个题解~~~

代码

//
{1、根据题意可知可以利用枚举法完成。枚举罪犯和今天是星期几。满足N个人始终说谎话和M-N个人始终说真话的条件，就可以确定罪犯。

2、首先利用字符串操作将证言转化成计算机可表示的信息。

1）定义

Guilty:Array[1..MM,1..MM] Of Integer;{-1..1} 

FillChar(Guilty,SizeOf(Guilty),0) 

初值为0 

 Guilty[i,j]=-1：表示第i个人说第j个人不是罪犯

Guilty[i,j]= 1：表示第i个人说第j个人是罪犯

其中包含Guilty[i,i]即第i个人说自己是不是罪犯 

注意：Guilty不可以自相矛盾。

2）定义

WhatDay:Array[1..MM,1..7] Of Boolean; 

FillChar(WhatDay,SizeOf(WhatDay),False) 

WhatDay[i,j]:=True  :表示第i个人说过j是星期几 

3、枚举罪犯和星期几，判断每句证言是真是假，统计说真假证言的人数。

注意：有可能某人又说过真话，又说过假话。

4、根据题目要求输出罪犯编号或Cannot Determine或Impossible。
}

var ans,x:longint;
    m,n,p,i,j:longint;
    flag:array[1..200] of boolean;
    word,name:array[1..1000] of string;
function getweek(st:string):longint;
var i:longint;
    xingqi:array[1..7] of string=('Monday','Tuesday','Wednesday','Thursday','Friday','Saturday','Sunday');
begin
  for i:=1 to 7 do
    if xingqi[i]=st then exit(i);
    exit(0);
end;
function change(st:string):string;
begin
  while (length(st)>0)and(st[1]=' ') do
    delete(st,1,1);
  while (length(st)>0)and(st[length(st)]=' ') do
    delete(st,length(st),1);
  exit(st);
end;
function getid(st:string):longint;
var i:longint;
begin
  for i:=1 to m do
    if name[i]=st then exit(i);
  exit(0);
end;
function check(id,week:longint):boolean;
var i,j,loc,nameid,weekid,tot0,tot2:longint;
    wd,na,we:string;
    f:array[1..300] of longint;  //1表示说真话； 2表示说谎
begin
  tot0:=0;
  tot2:=0;
  for i:=1 to m do
    f[i]:=0;
  for i:=1 to p do
  begin
    loc:=pos(':',word[i]);
    nameid:=getid(change(copy(word[i],1,loc-1)));
    wd:=change(copy(word[i],loc+1,length(word[i])-loc));
    if wd='I am guilty.' then
      if nameid<>id then   //当前的枚举的罪犯不是现在说话的这个人
      begin
        if f[nameid]=1 then exit(false);   //和诚实冲突
        f[nameid]:=2
      end
      else
      begin                //当前枚举的罪犯是现在说话的这个人
        if f[nameid]=2 then exit(false);  //和说谎冲突
        f[nameid]:=1;       
      end;
    if wd='I am not guilty.' then
      if nameid=id then   //当前枚举的罪犯是现在说话的这个人
      begin            
        if f[nameid]=1 then exit(false);    //和诚实。冲突
        f[nameid]:=2                       
      end
      else                //当前枚举的罪犯不是现在说话的这个人
      begin
        if f[nameid]=2 then exit(false);  //和说谎冲突
        f[nameid]:=1;
      end;
    if copy(wd,length(wd)-9,10)='is guilty.' then
    begin
      na:=change(copy(wd,1,length(wd)-10));
      if getid(na)<>id then
      begin
        if f[nameid]=1 then exit(false);
        f[nameid]:=2
      end
      else
      begin
        if f[nameid]=2 then exit(false);
        f[nameid]:=1;
      end;
    end;
    if copy(wd,length(wd)-13,14)='is not guilty.' then
    begin
      na:=change(copy(wd,1,length(wd)-14));
      if getid(na)=id then
      begin
        if f[nameid]=1 then exit(false);
        f[nameid]:=2
      end
      else
      begin
        if f[nameid]=2 then exit(false);
        f[nameid]:=1;
      end;
    end;
    if copy(wd,1,8)='Today is' then
    begin
      we:=change(copy(wd,10,length(wd)-10));
      weekid:=getweek(we);
      if weekid=week then
      begin
        if f[nameid]=2 then exit(false);
        f[nameid]:=1;
      end
      else
      if weekid>0 then
      begin
        if f[nameid]=1 then exit(false);
        f[nameid]:=2;
      end;
    end;
  end;
  for i:=1 to m do
    if f[i]=2 then inc(tot2)  //tot2是说谎人数
      else if f[i]=0 then inc(tot0);  //tot0不确定身份人数
  if (tot2+tot0>=n)and(tot2<=n) then exit(true)   //这个判断条件特别重要【注意：有可能某人又说过真话，又说过假话。】
    else exit(false);
end;
begin
  readln(m,n,p);
  fillchar(flag,sizeof(flag),false);
  for i:=1 to m do
    readln(name[i]);
  for i:=1 to p do
    readln(word[i]);
  for i:=1 to m do
    for j:=1 to 7 do
      if check(i,j) then begin flag[i]:=true;x:=i;end;
  for i:=1 to m do
    if flag[i] then inc(ans);
  if ans>1 then writeln('Cannot Determine')
    else if ans=0 then writeln('Impossible')
      else if ans=1 then writeln(change(name[x]));
end.



提交成功了
评测结果：Accepted 
得分：　　100
提交时间：2015-10-28 15:48 耗时：75ms
内存：3133kb 点击进入记录列表。

 编译信息 Compiling
编译成功
 评测结果 Result
测试点 #1：通过该测试点。 得分10，耗时15ms，内存3117kB。
测试点 #2：通过该测试点。 得分10，耗时0ms，内存3117kB。
测试点 #3：通过该测试点。 得分10，耗时0ms，内存3121kB。
测试点 #4：通过该测试点。 得分10，耗时0ms，内存3121kB。
测试点 #5：通过该测试点。 得分10，耗时15ms，内存3117kB。
测试点 #6：通过该测试点。 得分10，耗时15ms，内存3133kB。
测试点 #7：通过该测试点。 得分10，耗时0ms，内存3125kB。
测试点 #8：通过该测试点。 得分10，耗时0ms，内存3117kB。
测试点 #9：通过该测试点。 得分10，耗时15ms，内存3125kB。
测试点 #10：通过该测试点。 得分10，耗时15ms，内存3117kB。