jzoj. 3928. 【NOIP2014模拟11.6】射击

Description

有问题，找副连，无聊的时候当然也可以找他啦。小W找到了他的叔叔——东厂厂长——宇宙超级无敌老WS yy。他们叔侄两个商量之后决定用弹弓打破社区里的一些窗户，但是弹弓每秒只能彻底打破一扇窗户。而且如果某户窗户的主人回来了的话，他们就不能进行破坏了（不然会死得很惨的）。因为有的人装的玻璃好，有的人装的玻璃差，有的人装的玻璃高，有的人装的玻璃矮，所以你不能要求他们叔侄两个打破不同的窗户获得的快乐值必须相同。现在他们想知道在能活着的情况下能够获得的最大快乐值。

Input

第一行一个正整数n，表示共有n个窗户。
接下来n行，每行两个整数，第一个为窗子的主人回来的时刻（秒），第二个为破坏该窗户所能获得的快乐值。

Output

最大的快乐值。

Sample Input

4
1 19
2 10
1 20
2 15

Sample Output

35
样例说明：
在第0个时刻，他们选择破坏掉3号窗户，在第1个时刻，因为1号窗户的主人已经回来了，所以不能去破坏1号窗户，只能去破坏2号窗户或4号窗户，显然选择4号窗户。总的快乐值就是20+15=35。

Data Constraint

20%的数据，n<=100。
40%的数据，n<=50000。
100%的数据，n<=200000，快乐值的绝对值不超过32767，时刻非负且小于2^31。

分析：这题好坑，首先是快乐值有负的，要直接去掉。我们设当前的世界为t，那么，我们从最大时刻反过来枚举t，显然有，t时刻最应该去破坏的窗户显然是时刻>=t的，快乐值最大的那个啦。我们可以开一个堆，把在世界t可以破坏的窗户加入堆中，有在时间t时弹出最大值即可。还有最大时间大于n的，直接变为n就好了，因为就n个窗户，破坏掉全部也就是n的时间啦。

代码：

const
 maxn=300001;
var
 a:array [0..maxn] of longint;
 x,y:array [0..maxn] of longint;
 i,j,t,n,xx,ss,tt:longint;
 ans:int64;
procedure qsort(l,r:longint);
  var
   i,j,key,temp:longint;
  begin
   if l>=r then exit;
   i:=l;j:=r;
   key:=x[l+random(r-l+1)];
  repeat
   while  (x[i]<key) do inc(i);
   while  (x[j]>key) do dec(j);
   if i<=j then
    begin
     temp:=x[i];x[i]:=x[j];x[j]:=temp;
     temp:=y[i];y[i]:=y[j];y[j]:=temp;
     inc(i);dec(j);
    end;
  until i>j;
  qsort(l,j);
  qsort(i,r);
 end;

procedure insert1(x:longint);
var i,temp:longint;
 begin
  inc(t);
  a[t]:=x;
  i:=t;
  while (i>1) and (a[i]>a[i shr 1]) do
   begin
    temp:=a[i];
    a[i]:=a[i shr 1];
    a[i shr 1]:=temp;
    i:=i shr 1;
   end;
 end;

function delete1:longint;
var i,temp,s:longint;
    flag:boolean;
begin
  delete1:=a[1];
  a[1]:=a[t];
  dec(t);
  i:=1;
  flag:=true;
  while flag and (i shl 1<=t) do
   begin
    if (i shl 1+1>t) or (a[i shl 1]>a[i shl 1+1]) then s:=i shl 1
                                                  else s:=i shl 1+1;
    if a[s]>a[i] then
     begin
      temp:=a[i];
      a[i]:=a[s];
      a[s]:=temp;
      i:=s;
     end
    else flag:=false;
   end;
 end;

begin
 assign(input,'data.in');
 reset(input);
 readln(xx);
 for i:=1 to xx do
  begin
   readln(ss,tt);
   if tt>0 then
    begin
     n:=n+1;
     x[n]:=ss;
     y[n]:=tt;
    end;
  end;
 qsort(1,n);
 for i:=1 to n do
  if x[i]>n then x[i]:=n;
 j:=n;
 for i:=x[n] downto 1 do
  begin
   while (x[j]>=i) and (j>=1) do
    begin
     insert1(y[j]);
     dec(j);
    end;
   if t>=1 then ans:=ans+delete1;
  end;
 writeln(ans);
 close(input);
end.