哈哈,boot文件夹里的齐了,这个head.s早看完了,一直没发

# head.s 编译生成目标文件后会被连接成system模块,并放在system的最前面
# 此时已经处于保护模式状态下了
/*
 *  linux/boot/head.s
 *
 *  (C) 1991  Linus Torvalds
 */

/*
 *  head.s contains the 32-bit startup code.
 *
 * NOTE!!! Startup happens at absolute address 0x00000000, which is also where
 * the page directory will exist. The startup code will be overwritten by
 * the page directory.
 */
.text
.globl _idt,_gdt,_pg_dir,_tmp_floppy_area
_pg_dir:        # 注意页目录表将要放在这,0地址处
startup_32:
    movl $0x10,%eax
    mov %ax,%ds
    mov %ax,%es
    mov %ax,%fs
    mov %ax,%gs
    lss _stack_start,%esp    # stack_start->ss:esp, stack_start在其他模块中定义,看名字是堆栈开始
    call setup_idt            # 初始化中断描述符表IDT
    call setup_gdt            # 初始化全局描述符表
    movl $0x10,%eax        # reload all the segment registers
    mov %ax,%ds            # after changing gdt. CS was already
    mov %ax,%es            # reloaded in 'setup_gdt'
    mov %ax,%fs
    mov %ax,%gs            # 重新装在所有段寄存器
    lss _stack_start,%esp
    xorl %eax,%eax
1:    incl %eax        # check that A20 really IS enabled
    movl %eax,0x000000    # loop forever if it isn't
    cmpl %eax,0x100000
    je 1b                # 测试A20是否真的打开
/*
 * NOTE! 486 should set bit 16, to check for write-protect in supervisor
 * mode. Then it would be unnecessary with the "verify_area()"-calls.
 * 486 users probably want to set the NE (#5) bit also, so as to use
 * int 16 for math errors.
 */                        # 下面是检测协处理器相关代码
    movl %cr0,%eax        # check math chip
    andl $0x80000011,%eax    # Save PG,PE,ET
/* "orl $0x10020,%eax" here for 486 might be good */
    orl $2,%eax        # set MP
    movl %eax,%cr0
    call check_x87
    jmp after_page_tables

/*
 * We depend on ET to be correct. This checks for 287/387.
 */
check_x87:
    fninit
    fstsw %ax
    cmpb $0,%al
    je 1f            /* no coprocessor: have to set bits */
    movl %cr0,%eax
    xorl $6,%eax        /* reset MP, set EM */
    movl %eax,%cr0
    ret
.align 2
1:    .byte 0xDB,0xE4        /* fsetpm for 287, ignored by 387 */
    ret

/*
 *  setup_idt
 *
 *  sets up a idt with 256 entries pointing to
 *  ignore_int, interrupt gates. It then loads
 *  idt. Everything that wants to install itself
 *  in the idt-table may do so themselves. Interrupts
 *  are enabled elsewhere, when we can be relatively
 *  sure everything is ok. This routine will be over-
 *  written by the page tables.
 */
setup_idt:
    lea ignore_int,%edx        # 取通用中断处理程序地址
    movl $0x00080000,%eax
    movw %dx,%ax        /* selector = 0x0008 = cs */
    movw $0x8E00,%dx    /* interrupt gate - dpl=0, present */
                        # 上面是设置指向通用中断处理程序的中断门描述符
    lea _idt,%edi
    mov $256,%ecx
rp_sidt:
    movl %eax,(%edi)    # eax中存放的是中断门描述符的低四个字节
    movl %edx,4(%edi)    # edx中存放的是中断门描述符的高四个字节
    addl $8,%edi        # 调整地址指针
    dec %ecx            # 调整计数值
    jne rp_sidt            # 循环
    lidt idt_descr        # 加载中断描述符寄存器
    ret                    # 返回主程序

/*
 *  setup_gdt
 *
 *  This routines sets up a new gdt and loads it.
 *  Only two entries are currently built, the same
 *  ones that were built in init.s. The routine
 *  is VERY complicated at two whole lines, so this
 *  rather long comment is certainly needed :-).
 *  This routine will beoverwritten by the page tables.
 */
setup_gdt:
    lgdt gdt_descr        # 加载全局描述符寄存器,已在数据区初始化,固定的
    ret                    # 返回主程序

/*
 * I put the kernel page tables right after the page directory,
 * using 4 of them to span 16 Mb of physical memory. People with
 * more than 16MB will have to expand this.
 */
.org 0x1000            # 预留4个页表空间
pg0:

.org 0x2000
pg1:

.org 0x3000
pg2:

.org 0x4000
pg3:

.org 0x5000
/*
 * tmp_floppy_area is used by the floppy-driver when DMA cannot
 * reach to a buffer-block. It needs to be aligned, so that it isn't
 * on a 64kB border.
 */
_tmp_floppy_area:
    .fill 1024,1,0        # 填充一个1024字节的块

after_page_tables:
    pushl $0        # These are the parameters to main :-)
    pushl $0
    pushl $0
    pushl $L6        # return address for main, if it decides to.    #此处压入的是main返回的地址
    pushl $_main                                                    #此处压入main的地址,待会一RET就去执行main函数了
    jmp setup_paging                                                #实际上main不返回了
L6:
    jmp L6            # main should never return here, but
                # just in case, we know what happens.

/* This is the default interrupt "handler" :-) */
int_msg:
    .asciz "Unknown interrupt/n/r"
.align 2        # 2字对齐
ignore_int:        # 非特殊的中断处理程序,输出上面的字符串
    pushl %eax
    pushl %ecx
    pushl %edx
    push %ds
    push %es
    push %fs
    movl $0x10,%eax        # 置段选择符
    mov %ax,%ds
    mov %ax,%es
    mov %ax,%fs
    pushl $int_msg
    call _printk        # 目前还没看到prink的代码
    popl %eax
    pop %fs
    pop %es
    pop %ds
    popl %edx
    popl %ecx
    popl %eax
    iret                # 中断返回,弹出CPU中断时压入的标志寄存器


/*
 * Setup_paging
 *
 * This routine sets up paging by setting the page bit
 * in cr0. The page tables are set up, identity-mapping
 * the first 16MB. The pager assumes that no illegal
 * addresses are produced (ie >4Mb on a 4Mb machine).
 *
 * NOTE! Although all physical memory should be identity
 * mapped by this routine, only the kernel page functions
 * use the >1Mb addresses directly. All "normal" functions
 * use just the lower 1Mb, or the local data space, which
 * will be mapped to some other place - mm keeps track of
 * that.
 *
 * For those with more memory than 16 Mb - tough luck. I've
 * not got it, why should you :-) The source is here. Change
 * it. (Seriously - it shouldn't be too difficult. Mostly
 * change some constants etc. I left it at 16Mb, as my machine
 * even cannot be extended past that (ok, but it was cheap :-)
 * I've tried to show which constants to change by having
 * some kind of marker at them (search for "16Mb"), but I
 * won't guarantee that's all :-( )
 */
.align 2
setup_paging:
    movl $1024*5,%ecx        /* 5 pages - pg_dir+4 page tables */
    xorl %eax,%eax
    xorl %edi,%edi            /* pg_dir is at 0x000 */
    cld;rep;stosl            # 前5页内存清零
    movl $pg0+7,_pg_dir        /* set present bit/user r/w */
    movl $pg1+7,_pg_dir+4        /*  --------- " " --------- */
    movl $pg2+7,_pg_dir+8        /*  --------- " " --------- */
    movl $pg3+7,_pg_dir+12        /*  --------- " " --------- */
    movl $pg3+4092,%edi
    movl $0xfff007,%eax        /*  16Mb - 4096 + 7 (r/w user,p) */
    std
1:    stosl            /* fill pages backwards - more efficient :-) */
    subl $0x1000,%eax
    jge 1b                #上面设置四个也表,分别映射物理内存0-16MB
    xorl %eax,%eax        /* pg_dir is at 0x0000 */
    movl %eax,%cr3        /* cr3 - page directory start */
    movl %cr0,%eax
    orl $0x80000000,%eax
    movl %eax,%cr0        /* set paging (PG) bit */
    ret            /* this also flushes prefetch-queue */
            # 在改变分页处理标志位后需要使用转移指令刷新预取指令队列,在这用RET
            # 这个RET弹出堆栈最后压入的main函数地址,执行main了,本程序到此结束
.align 2
.word 0                # 保证4字节对齐,并前两字节为0
idt_descr:            # 加载中断描述符表寄存器时需要的6字节数据
    .word 256*8-1        # idt contains 256 entries    #界限
    .long _idt                                        #基址
.align 2
.word 0                # 保证4字节对齐,并前两字节为0
gdt_descr:            # 加载全局描述符寄存器时需要的6字节数据
    .word 256*8-1        # so does gdt (not that that's any    #界限
    .long _gdt        # magic number, but it works for me :^)    #基址

    .align 3        # 按8字节(2^3)对齐
_idt:    .fill 256,8,0        # idt is uninitialized    #在代码中IDT将初始化

_gdt:    .quad 0x0000000000000000    /* NULL descriptor */
    .quad 0x00c09a0000000fff    /* 16Mb */    # 可读可写数据段
    .quad 0x00c0920000000fff    /* 16Mb */    # 代码段
    .quad 0x0000000000000000    /* TEMPORARY - don't use */
    .fill 252,8,0            /* space for LDT's and TSS's etc */