[AHK]里氏代换原则AHK详解

看了一大堆的资料讲解关于里氏代换原则，在这里我想分享给大家。

下面这段话来自百度百科，是这么解释里氏代换原则的：

里氏代换原则(Liskov Substitution Principle LSP)是面向对象设计的基本原则之一。 里氏代换原则中说，任何基类可以出现的地方，子类一定可以出现。 LSP是继承复用的基石，只有当子类可以替换掉父类，软件单位的功能不受到影响时，父类才能真正被复用，而子类也能够在父类的基础上增加新的行为。里氏代换原则是对“开-闭”原则的补充。实现“开-闭”原则的关键步骤就是抽象化。而基类与子类的继承关系就是抽象化的具体实现，所以里氏代换原则是对实现抽象化的具体步骤的规范。
下面举例说明什么是里代换原则
实例1 正方形不是长方形

在几何当中，正方形肯定是长方形，只不过它是特殊的长方形，四条边都相等，利用面向对象的继承关系，我们让正方形继承长方形，代码如下：

; AHK讲解里氏代换原则
; 实例名称：正方形不是长方形



; 长方形类
class Rectangle 
{
  getLength() 
  { 
      return this.length
  }
  getWidth() 
  { 
      return this.width
  }
   setLength(length) 
  { 
      this.length := length
  }
  setWidth(width) 
  { 
      this.width := width
  }
}

; 正方形类Square
class Square extends Rectangle 
{
	;override
    setLength(length) 
      {
        base.setLength(length)
        base.setWidth(length)
      } 
      setWidth(width) 
      {
        base.setLength(width)
        base.setWidth(width)
     }
  
}

/*
 * 由于正方形的长度和宽度必须相等，所以在方法setLength和setWidth中，
 * 对长度和宽度赋值相同
 *resize方法要用到基类Rectangle，resize方法的功能是模拟长方形宽度逐步增长的效果
 */

;测试方法改变长方形的宽，将宽设为比高大
resize(objRect) ;参数是Rectangle
{
	msgbox % "设置宽度开始"
	while(objRect.getWidth() <= objRect.getLength()  ) 
	{
		objRect.setWidth(objRect.getWidth() + 1 )
	}
	msgbox % "设置宽度结束"

}
     
Main:
{
	; 实例化一个长方形
	r:=new Rectangle()
	; 设长为10
	r.setLength(10)
	; 设宽为1
	r.setWidth(1)
	
	msgbox % "长方形"
	msgbox % "改变之前长为：" r.getLength()
	msgbox % "改变之前宽为：" r.getWidth()
	
	; 调用方法改变长方形的宽
	resize(r)
	; 改变之后
	msgbox % "改变之后长为：" r.getLength()
	msgbox % "改变之后宽为：" r.getWidth()
	
	
	s:=new Square() ;也是Rectangle
	
	s.setLength(10)
	s.setWidth(1)
	msgbox % "正方形"
	msgbox % "改变之前长为：" s.getLength()
	msgbox % "改变之前宽为：" s.getWidth()
	
	; 调用方法改变正方形的宽
	resize(s)
	msgbox % "改变之后长为：" s.getLength()
	msgbox % "改变之后宽为：" s.getWidth()
}

我们运行一下这段代码就会发现，假如我们把一个普通长方形的实例作为参数传入resize方法，就会看到长方形宽度逐渐增长的效果，当宽度大于长度,代码就会停止，这种行为的结果符合我们的预期；假如我们利用里氏代换所说的，把子类的实例赋给父类，再把父类（正方形）的实例作为参数传入resize方法后，就会看到正方形的宽度和长度都在不断增长，代码会一直运行下去，直至系统产生溢出错误。所以，普通的长方形是适合这段代码的，正方形不适合。
我们得出结论：在resize方法中，Rectangle类型的参数是不能被Square类型的参数所代替，如果进行了替换就得不到预期结果。因此，Square类和Rectangle类之间的继承关系违反了里氏代换原则，它们之间的继承关系不成立，正方形不是长方形。
当运行程序的时候，长方形可以正常的改变长方形的宽度，而正方形不能改变宽度。里氏代换原则说明了我们不能乱用继承，这里长方形的长和宽和正方形的长和宽明显有不同的特点，所以正方形继承长方形是错误的。

总结前人的诸多经验来看，里氏替换原则主要是有四点：

1. 子类不要覆盖父类的非抽象的方法。可以实现其抽象方法。
2. 子类可以实现自己独有的方法。
3. 子类的方法重写父类方法的时候，参数部分，要比父类的参数范围要大或者等于（宽松）。释义：举个例子>如果说父类的方法中形参是ArrayList,那么，其子类重写这个方法的时候，形参要是List.
4. 子类重写父类方法的时候，返回值要求，父类的返回值要比子类的返回值要小于或者等于。