AHK 中 = 和 == 等比较运算符的用法

上一篇文章我们了解到了 = 和 := 的区别，也了解了怎样对变量赋值。除了赋值，我们还经常需要比较两个变量的值是否相等，这就需要比较运算符了。

一翻手册，头疼的事情又来了。其他语言要么用 = 比较，要么用 == 比较，只是习惯的问题。而 AHK 用 = 和 == 都可以比较，而且二者居然还有区别。不过还好区别不是那么大，也并不难理解。

大小写问题

这里先提下大小写问题，这与 = 和 == 的区别密切相关。AHK 的代码是不区分大小写的，也就是说，在通常情况，将一份不涉及外部交互（如创建目录、写文件、和其他程序交互等）的 AHK 代码中的小写字母全部转换成大写字母，是不影响功能的。所有的关键字、变量名，都是不区分大小写的。但有一些特例，用 == 比较字符串是区分大小写的，以及后边会提到的 StringCaseSense 命令。

= 和 == 的区别

用 = 比较字符串是不区分大小写的，而用 == 比较字符串是区分大小写的。

a := "abc"
b := "ABC"

if (a = b)
{
    ; 条件成立
}

if (a == b)
{
    ; 条件不成立
}

!= 和 <> 的用法

如果只考虑 = 和 == 的用法，并没有什么需要注意的，一个不区分大小写，一个区分大小写，根据实际情况选择即可。但有等号，自然就有不等号，考虑到不等号，问题就复杂化了。

AHK 中的不等号也有两种，!= 和 <>，好在二者是完全相同的，可以根据自己的习惯来使用。但在处理大小写问题上，不等号和等号有着很大的区别。

我们需要先了解一个命令，StringCaseSense：

StringCaseSense, On|Off|Locale

StringCaseSense 用于设置在字符串处理时是否区分大小写。如果设置了 On，就是区分；如果设置了 Off，就是不区分。先不用关注 Locale 参数。默认是 Off。

注意这个命令不影响 = 和 == 的功能。也就是说即使设置了 StringCaseSense, On，用 = 比较字符串还是不区分大小写的。但影响 != 和 <> 的结果：

a := "abc"
b := "ABC"

StringCaseSense, On
if (a != b)
{
    ; 条件成立
}

StringCaseSense, Off
if (a != b)
{
    ; 条件不成立
}

这个也并不难理解，因为通常情况我们无需设置 StringCaseSense，比较的结果都是不区分大小写的。

=、==、!=、<> 一起使用

既然我们已经分别了解了 =、==、!= 和 <> 的区别，就可以一起使用了。但这里就又一些新的事情需要注意了。

默认情况，也就是 StringCaseSense, Off 的情况。= 和 != 是对应的，也就是说：

if (a = b)
{
}

和

; ! 是逻辑非操作，和很多其他语言一样。
if (!(a != b))
{
}

是一样的。但 StringCaseSense, On 的情况，== 和 != 是对应的。

也就是说，如果我们在 StringCaseSense, Off 的情况，将 == 和 != 在一起使用，可能会出问题。同理，在 StringCaseSense, On 的情况，将 = 和 != 在一起使用，也可能会出问题。会出什么样的问题呢，举一个例子：

StringCaseSense, Off

a := "abc"
b := "ABC"

; 片段一
if (a == b)
{
    ; 做 a
    ; 条件不成立
}
else
{
    ; 做 b
    ; 走此分支
}

; 片段二
if (a != b)
{
    ; 做 b
    ; 条件不成立
}
else
{
    ; 做 a
    ; 走此分支
}

我们看下里边的片段一和片段二。逻辑看起来好像一样，有人喜欢用等号比较，有人喜欢用不等号比较，这和习惯有关，无可厚非。但我们发现问题来了，这两段看起来一样的代码执行结果完全相反，片段一做了 b，片段二做了 a。如果这个判断很重要，会留下非常大的隐患。

更要命的是，以上的代码如果设置了 StringCaseSense, On，片段一和片段二是一样的，不存在问题，但后续代码维护者可能因为某些原因，将其改成了 StringCaseSense, Off。改的人可能认为只是把原来的区分大小写改成了不区分大小写，其他地方都不用动，而不会专门把所有的 == 改成 =。而这一改可能就留下了非常严重的 bug，而且通常情况不会触发，只有在比较仅大小写不同的两个字符串时才会触发。

注意事项

所以，在比较字符串时还是需要留神的。因为通常情况我们无需设置 StringCaseSense，不等号在比较字符串的时候是不区分大小写的。对应地，我们也应该用 = 来比较字符串，以免发生之前描述的问题。如果因为某些情况，我们需要修改之前代码的 StringCaseSense，一定要仔细审视每一处用 = 或者 == 比较字符串的代码，看是否存在问题。必要的话，需要将 = 与 == 互换。

付费解决 Windows、Linux、Shell、C、C++、AHK、Python、JavaScript、Lua 等领域相关问题，灵活定价，欢迎咨询，微信 ly50247。