黑科技！用脚本将DeepSeek嵌入Word中，5分钟搞定（附保姆级教程）

最新推荐文章于 2025-02-22 00:34:39 发布

SQL数据库开发

最新推荐文章于 2025-02-22 00:34:39 发布

阅读量1.7k

点赞数 9

文章标签：科技 word c# 开发语言

本文链接：https://blog.csdn.net/liyue071714118/article/details/145623288

版权

大家好，我是岳哥。

岳哥最近建了几个DeepSeek交流群，大家五花八门的玩法和需求一大堆。

有小伙伴问DeepSeek能不能接入Office办公软件，岳哥研究了一番还真可以。

昨天教大家用第三方软件接入WPS和Office，还没看过的可以看下。

DeepSeek一键接入WPS和Office，效率提升300%

今天教大家如何用VB宏命令将DeepSeek集成到Word中。

获取API-Key

这一步是我们操作的关键，目前我们可以直接只用官网的API来实现。

登录官网的API平台：

https://platform.deepseek.com/

没注册的注册完登录一下，我们点击到左侧菜单的“APIKeys”按钮，然后点击右侧的“创建API Key”

在弹出的对话框中备注一下，以防忘记，这里我们备注为“Word”，表名是在Word上使用的。

点击创建，这样我们就获得了一个API Key了。记得先将密钥复制存放一下。一旦关闭就无法复制，只能删了重新创建。

这样我们就获得了一个API key。

开启宏命令

要将DeepSeek集成到Word中必须先使用到“宏”，但是Office默认是禁用宏的，所以咱们得先开启一下宏命令的功能。

打开Word文档，点击“文件”——“选项”——“自定义功能”——“信任中心”——“信任中心设置”，勾选如下两个功能，并确定。

这样我们就启用了宏命令功能。

启动开发工具

一般的Word因为禁用了“宏命令”，对应的“开发工具”菜单也没开启，我们也需要开启一下。

按如下操作启动“开发工具”菜单：“文件”——“选项”——“自定义功能”，勾选启动“开发工具”菜单

创建VB宏命令

前面的设置主要是为了方便大家能在菜单栏里找到我们即将设置的VB宏，接下来才是重点内容，跟着我操作。

点击“开发工具”下的VB编辑器

进入后选择菜单中的“插入”-“模块”，命名为“DeepSeek”。

然后将下面的一串代码复制粘贴到模块中。

Function CallDeepSeekAPI(api_key As String, inputText As String) As String
Dim API As String
Dim SendTxt As String
Dim Http As Object
Dim status_code As Integer
Dim response As String
API = "https://api.deepseek.com/chat/completions"
SendTxt = "{""model"": ""deepseek-reasoner"", ""messages"": [{""role"":""system"", ""content"":""你是一个乐于助人的AI助手，请根据用户的问题给出详细的解答。""}, {""role"":""user"", ""content"":""" & inputText & """}], ""stream"": false}"

Set Http = CreateObject("MSXML2.XMLHTTP")
With Http
    .Open "POST", API, False
    .setRequestHeader "Content-Type", "application/json"
    .setRequestHeader "Authorization", "Bearer " & api_key
    .send SendTxt
    status_code = .Status
    response = .responseText
End With

' 弹出窗口显示 API 响应（调试用）

' MsgBox "API Response: " & response, vbInformation, "Debug Info"

If status_code = 200 Then
    CallDeepSeekAPI = response
Else
    CallDeepSeekAPI = "Error: " & status_code & " - " & response
End If

Set Http = Nothing
End Function
Sub DeepSeekR1()
Dim api_key As String
Dim inputText As String
Dim response As String
Dim regex As Object
Dim reasoningRegex As Object
Dim contentRegex As Object
Dim matches As Object
Dim reasoningMatches As Object
Dim originalSelection As Object
Dim reasoningContent As String
Dim finalContent As String
api_key = "替换为你的api key"
If api_key = "" Then
    MsgBox "Please enter the API key."
    Exit Sub
ElseIf Selection.Type <> wdSelectionNormal Then
    MsgBox "Please select text."
    Exit Sub
End If

' 保存原始选中的文本
Set originalSelection = Selection.Range.Duplicate

inputText = Replace(Replace(Replace(Replace(Replace(Selection.text, "\", "\\"), vbCrLf, ""), vbCr, ""), vbLf, ""), Chr(34), "\""")
response = CallDeepSeekAPI(api_key, inputText)

If Left(response, 5) <> "Error" Then
    ' 创建正则表达式对象来分别匹配推理内容和最终回答
    Set reasoningRegex = CreateObject("VBScript.RegExp")
    With reasoningRegex
        .Global = True
        .MultiLine = True
        .IgnoreCase = False
        .Pattern = """reasoning_content"":""(.*?)"""
    End With
    
    Set contentRegex = CreateObject("VBScript.RegExp")
    With contentRegex
        .Global = True
        .MultiLine = True
        .IgnoreCase = False
        .Pattern = """content"":""(.*?)"""
    End With

    ' 提取推理内容
    Set reasoningMatches = reasoningRegex.Execute(response)
    If reasoningMatches.Count > 0 Then
        reasoningContent = reasoningMatches(0).SubMatches(0)
        reasoningContent = Replace(reasoningContent, "\n\n", vbNewLine)
        reasoningContent = Replace(reasoningContent, "\n", vbNewLine)
        reasoningContent = Replace(Replace(reasoningContent, """", Chr(34)), """", Chr(34))
    End If

    ' 提取最终回答
    Set matches = contentRegex.Execute(response)
    If matches.Count > 0 Then
        finalContent = matches(0).SubMatches(0)
        finalContent = Replace(finalContent, "\n\n", vbNewLine)
        finalContent = Replace(finalContent, "\n", vbNewLine)
        finalContent = Replace(Replace(finalContent, """", Chr(34)), """", Chr(34))

        ' 取消选中原始文本
        Selection.Collapse Direction:=wdCollapseEnd

        ' 插入推理过程（如果存在）
        If Len(reasoningContent) > 0 Then
            Selection.TypeParagraph
            Selection.TypeText "推理过程："
            Selection.TypeParagraph
            Selection.TypeText reasoningContent
            Selection.TypeParagraph
            Selection.TypeText "最终回答："
            Selection.TypeParagraph
        End If

        ' 插入最终回答
        Selection.TypeText finalContent

        ' 将光标移回原来选中文本的末尾
        originalSelection.Select
    Else
        MsgBox "Failed to parse API response.", vbExclamation
    End If
Else
    MsgBox response, vbCritical
End If
End Sub

并将其中需要填充API-Key的地方替换成我们前面准备好的API-Key。