【BZOJ1103】【POI2007】大都市meg

【Description】

　　在经济全球化浪潮的影响下,习惯于漫步在清晨的乡间小路的邮递员Blue Mary也开始骑着摩托车传递邮件了。不过，她经常回忆起以前在乡间漫步的情景。昔日，乡下有依次编号为1..n的n个小村庄，某些村庄之间有一些双向的土路。从每个村庄都恰好有一条路径到达村庄1（即比特堡）。并且，对于每个村庄，它到比特堡的路径恰好只经过编号比它的编号小的村庄。另外，对于所有道路而言，它们都不在除村庄以外的其他地点相遇。在这个未开化的地方，从来没有过高架桥和地下铁道。随着时间的推移，越来越多的土路被改造成了公路。至今，Blue Mary还清晰地记得最后一条土路被改造为公路的情景。现在，这里已经没有土路了——所有的路都成为了公路，而昔日的村庄已经变成了一个大都市。 Blue Mary想起了在改造期间她送信的经历。她从比特堡出发，需要去某个村庄，并且在两次送信经历的间隔期间,有某些土路被改造成了公路.现在Blue Mary需要你的帮助：计算出每次送信她需要走过的土路数目。（对于公路，她可以骑摩托车；而对于土路，她就只好推车了。）

---

【Input】

　　第一行是一个数n(1 < = n < = 2 50000).
以下n-1行，每行两个整数a，b（1 < = a以下一行包含一个整数m（1 < = m < = 2 50000），表示Blue Mary曾经在改造期间送过m次信。
以下n+m-1行，每行有两种格式的若干信息，表示按时间先后发生过的n+m-1次事件:
若这行为 A a b(a若这行为 W a, 则表示Blue Mary曾经从比特堡送信到村庄a。

---

【Output】

　　有m行，每行包含一个整数，表示对应的某次送信时经过的土路数目。

---

【Sample Input】

5
1 2
1 3
1 4
4 5
4
W 5
A 1 4
W 5
A 4 5
W 5
W 2
A 1 2
A 1 3

---

【Sample Output】

2
1
0
1

---

【Hint】

　　

---

【Solution】

　　求出DFS序，用树状数组维护。每个点(i)出现在序列的进入(l[i])和退出(r[i])的部分记上+1和-1，则数组中1~N的和即为1号点和序列中第N个所代表的点间土路的个数，删除时在l[i]记上-1，r[i]记上+1即可。
　　
　　代码如下：

/**************************************************************
    Problem: 1103
    User: llgyc
    Language: Pascal
    Result: Accepted
    Time:7176 ms
    Memory:10968 kb
****************************************************************/

const maxn = 250005;
type etype = record
               go,next:longint;
             end;
var n,cnt,top,tid:longint;
    e:array[0..maxn*2] of etype;
    tr:array[0..maxn*2] of longint;
    stack:array[0..maxn] of longint;
    l,r,fa,head:array[0..maxn] of longint;
procedure insert(u,v:longint);
  begin inc(cnt); e[cnt].go:=v; e[cnt].next:=head[u]; head[u]:=cnt; end;
procedure init();
  var i,a,b:longint;
  begin
    readln(n);
    for i:=1 to n-1 do begin
      readln(a,b); insert(a,b); insert(b,a);
    end;
  end;
procedure dfs();
  var i,now,f:longint;
  begin
    top:=1; stack[top]:=1; tid:=0;
    while (top>0) do begin
      now:=stack[top]; f:=fa[top]; dec(top);
      if l[now]=0 then begin
        inc(tid); l[now]:=tid;
        inc(top); stack[top]:=now;
        i:=head[now];
        while (i<>0) do begin
          if e[i].go<>f then begin
            inc(top); stack[top]:=e[i].go; fa[top]:=now;
          end;
          i:=e[i].next;
        end;
      end
      else begin inc(tid); r[now]:=tid; end;
    end;
  end;
function sum(x:longint):longint;
  begin
    sum:=0;
    while (x>0) do begin
      sum:=sum+tr[x];
      x:=x-x and (-x);
    end;
  end;
procedure add(x,val:longint);
  begin
    while (x<=n*2) do begin
      tr[x]:=tr[x]+val;
      x:=x+x and (-x);
    end;
  end;
procedure main();
  var m,x,y,p,i:longint;
      c:char;
  begin
    for i:=2 to n do begin
      add(l[i],1); add(r[i],-1);
    end;
    readln(m); m:=m+n-1;
    while (m>0) do begin
      dec(m); read(c);
      if c='W' then begin
        readln(x); writeln(sum(l[x]));
      end
      else begin
        readln(x,y); if l[x]>l[y] then p:=x else p:=y;
        add(l[p],-1); add(r[p],1);
      end;
    end;
  end;
begin
  init();
  dfs();
  main();
end.