解析简单的solidity安全数学计算库

pragma solidity ^0.4.13;

// 安全的数学计算库
library SafeMath {

  /**
  * @dev Multiplies two numbers, throws on overflow.
  */
  // 乘法计算
  function mul(uint256 a, uint256 b) internal pure returns (uint256 c) {
    // 判断 a 如果为0，则返回积为0。 这里为什么不把b一起判断了呢？
    if (a == 0) {
      return 0;
    }
    // 乘法计算公式
    c = a * b;
    // 返回之前，需要通过除法来验算一下结果没有溢出。因为溢出后，除法算式就不等了。
    // 这里也解答了上面为什么要单独判断 a==0，因为除法中，a 如果为0是不能作为除数的。
    // 上面不判断b，是多判断一个就会多一点计算量，为了简洁。
    assert(c / a == b);
    return c;
  }

  /**
  * @dev Integer division of two numbers, truncating the quotient.
  */
  // 除法计算
  function div(uint256 a, uint256 b) internal pure returns (uint256) {
    // assert(b > 0); // Solidity automatically throws when dividing by 0
    // uint256 c = a / b;
    // assert(a == b * c + a % b); // There is no case in which this doesn't hold
    // 现在当除数为0时，solidity 会自动抛出异常
    // 除法计算不会出现整数溢出异常情况
    return a / b;
  }

  /**
  * @dev Subtracts two numbers, throws on overflow (i.e. if subtrahend is greater than minuend).
  */
  // 减法计算
  function sub(uint256 a, uint256 b) internal pure returns (uint256) {
    // 因为是无符号整数的计算，所以要验证被减数比减少大，或者相等。
    assert(b <= a);
    return a - b;
  }

  /**
  * @dev Adds two numbers, throws on overflow.
  */
  // 加法计算
  function add(uint256 a, uint256 b) internal pure returns (uint256 c) {
    c = a + b;
    // c 为 a与b 的和，如果溢出，c将会变成一个很小的数，此时验证一下c 是否比a 大，或者相等（b为0时）。
    assert(c >= a);
    return c;
  }
}

上面SafeMath 定义了加减乘除四个计算方法，用于防止数学运算时整数溢出的问题。只有加、减、乘会有溢出情况，为了方便记忆和使用，把除法也一起定义了方法。

以uint8为例，八位无符号整数类型的最大值是 255，翻译到二进制是 1111 1111；当再加一时，当前所有的 1 都会变成 0，并向上进位。但由于该整数类型所能容纳的位置已经全部是 1 了，再向上进位，最高位会被丢弃，于是二进制就变成了 0000 0000

注：有符号的整数类型，其二进制最高位代表正负。所以该类型的正数溢出会变成负数，而不是零。

因为数据类型的限制，所以必须要在计算时充分考虑整数溢出的问题。不要觉得目前的数据不会出问题，就不考虑该问题。因为智能合约是可能会被外部调用，传入一些未知的参数，一旦发生整数溢出，将造成不可挽回的损失。

另外三个知识点：

1、方法中用到了internal，而不是private。internal 在子类可以继承且子类可以访问；private 表示子类不可以继承，子类不可以访问，只能在当前类访问。

2、pure，表示一个函数不读取状态，也不修改状态；相应的view，表示函数只读取状态，但是不修改状态。pure 和 view 在本地执行都不会消耗gas。

3、上面的方法，定义的是uint256 的安全计算方法。如果要计算uint32，就需要重新写一套类似的库函数，把函数的参数改成对应的uint32。