读书笔记《30天自制操作系统》day03

最新推荐文章于 2023-08-31 10:43:46 发布
最新推荐文章于 2023-08-31 10:43:46 发布
阅读量4.5k 收藏 1
点赞数 2
分类专栏： 虚拟机-操作系统
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/ltbylc/article/details/8292922
版权

0. 自己试着在win7下用NASM和minGW改写汇编和C混合编程，结果受挫了。还是先使用作者提供的工具构建吧。

1. 通过前2天的工作已经能使用NASM制作一个映像了，并且编写的汇编代码可以成为引导扇区代码。

2. 引导扇区代码中可以调用BIOS中断，读取软盘上其它扇区到内存中，根据FAT12文件系统格式得知，保存到软盘内的第一个文件的文件名一定从19逻辑扇区开始，且该文件的内容从逻辑扇区33开始（见day01，图一）。

3. 引导扇区可以将第一个保存的文件（asmhead.nas，功能是跳入保护模式并调用C语言编写的函数代码）读入内存并使之执行，找这个文件用到了一个技巧（如2描述），不然通过文件系统结构分析出文件位置，并加载码就太复杂了。

4. 引导扇区代码如下ipl10.asm

CYLS	EQU		10				

		ORG		0x7c00			

		JMP		entry
		DB		0x90
		DB		"HARIBOTE"		
		DW		512				
		DB		1				
		DW		1				
		DB		2				
		DW		224				
		DW		2880			
		DB		0xf0			
		DW		9				
		DW		18				
		DW		2				
		DD		0				
		DD		2880			
		DB		0,0,0x29		
		DD		0xffffffff		
		DB		"HARIBOTEOS "	
		DB		"FAT12   "		
		RESB	18				



entry:
		MOV		AX,0			
		MOV		SS,AX
		MOV		SP,0x7c00
		MOV		DS,AX


		MOV		AX,0x0820  ;目的地址
		MOV		ES,AX
		MOV		CH,0	   ;柱面号		
		MOV		DH,0	   ;磁头号		
		MOV		CL,2	   ;扇区号		
readloop:
		MOV		SI,0			
retry:
		MOV		AH,0x02	   ;读磁盘	
		MOV		AL,1	   ;读1个扇区		
		MOV		BX,0       ;目的地址
		MOV		DL,0x00	   ;驱动器号		
		INT		0x13	   ;来BIOS中断		
		JNC		next			
		ADD		SI,1			
		CMP		SI,5			
		JAE		error	   ;读五次还失败就放弃		
		MOV		AH,0x00    ;重置驱动器功能号
		MOV		DL,0x00	   ;驱动器号	
		INT		0x13			
		JMP		retry
next:
		MOV		AX,ES			
		ADD		AX,0x0020   ;保存位置向后移动512字节，0x0020是段地址加偏移量后成为0x0200了
		MOV		ES,AX			
		ADD		CL,1			
		CMP		CL,18       ;读18个扇区	
		JBE		readloop		
		MOV		CL,1
		ADD		DH,1
		CMP		DH,2
		JB		readloop		
		MOV		DH,0
		ADD		CH,1
		CMP		CH,CYLS
		JB		readloop		


		MOV		[0x0ff0],CH		
		JMP		0xc200        ;跳到软盘kernel.sys(asmhead.nas+bootpack.c)文件内部执行
                                              ;该文件在加载软盘文件基址0x8000+Fat12文件系统中文件出现位置0x004200处=0xc200H
error:
                MOV             SI,msg
putloop:
                MOV		AL,[SI]
                ADD		SI,1
                CMP		AL,0
                JE		fin
                MOV		AH,0x0e
                MOV		BX,15
                INT		0x10
                JMP		putloop
fin:
                HLT
                JMP		fin
msg:
                DB		0x0a, 0x0a
                DB		"load error"
                DB		0x0a
                DB		0;
                RESB	        0x7dfe-$
                times           510-($-$$) db 0
                DB		0x55, 0xaa

BIOS 13中断说明（功能有磁盘的读、写、扇区校验、寻道）
AH=0x02 读盘/0x03写盘/0x04校验/0x0c寻道
AL=处理连续扇区数
CH=柱面号&0xff
CL=扇区号（0~5位）|（柱面号&0x300)>>2
DH=磁头号
DL=驱动器号
ES:BX=缓冲地址
返回值：FLAGS=0没有错误AH=0，FLAGS=1有错误AH保存错误码

 

5. 跳入保护模式代码如下asmhead.nas（1）准备GDT（2）用LGDT加载gdtr（3）打开A20（4）设置CR0的PE位（5）跳转进入保护模式

BOTPAK	EQU		0x00280000		
DSKCAC	EQU		0x00100000		
DSKCAC0	EQU		0x00008000		


CYLS	EQU		0x0ff0			
LEDS	EQU		0x0ff1
VMODE	EQU		0x0ff2			
SCRNX	EQU		0x0ff4			
SCRNY	EQU		0x0ff6			
VRAM	EQU		0x0ff8			

		ORG		0xc200	 ;让引导扇区加载后从这里开始运行，认为它们在一个段中所以能直接跳转过来		



		MOV		AL,0x13		;保存信息	
		MOV		AH,0x00
		INT		0x10
		MOV		BYTE [VMODE],8	
		MOV		WORD [SCRNX],320
		MOV		WORD [SCRNY],200
		MOV		DWORD [VRAM],0x000a0000


		MOV		AH,0x02
		INT		0x16 			; keyboard BIOS
		MOV		[LEDS],AL


		MOV		AL,0xff                 ;禁止PIC主从片的中断
      		OUT		0x21,AL
		NOP					;不能有两个连续的OUT指令
		OUT		0xa1,AL

		CLI		                        ;禁止PIC工作要在CLI之前				



		CALL	waitkbdout                      ;等待键盘电路准备好，要设置A20使1MB以上内存能被访问
		MOV		AL,0xd1
		OUT		0x64,AL
		CALL	waitkbdout
		MOV		AL,0xdf			; enable A20
		OUT		0x60,AL
		CALL	waitkbdout


[INSTRSET "i486p"]				

		LGDT	[GDTR0]			        ;加载临时的GDT表首地址到GDTR寄存器
		MOV		EAX,CR0
		AND		EAX,0x7fffffff	
		OR		EAX,0x00000001	
		MOV		CR0,EAX                 ;设置CR0寄存器PE标志位
		JMP		pipelineflush           ;设置标志位之后马上JMP
pipelineflush:                                          ;从此寻址方式变了
		MOV		AX,1*8                  ;段值的设置，用GDT中那个段（GDT+1段）			
		MOV		DS,AX
		MOV		ES,AX
		MOV		FS,AX
		MOV		GS,AX
		MOV		SS,AX



		MOV		ESI,bootpack	        ;将bootpack.c生成的目标代码移动到0x00280000，乾坤大挪移
		MOV		EDI,BOTPAK		
		MOV		ECX,512*1024/4
		CALL	memcpy



		MOV		ESI,0x7c00              ;将启动扇区复制到1MB以后的内存		
		MOV		EDI,DSKCAC		
		MOV		ECX,512/4
		CALL	memcpy


		MOV		ESI,DSKCAC0+512	        ;将0x00008200数据复制到0x00100200
		MOV		EDI,DSKCAC+512	
		MOV		ECX,0
		MOV		CL,BYTE [CYLS]
		IMUL	        ECX,512*18*2/4	
		SUB		ECX,512/4		
		CALL	memcpy
                ;至此内存中0x00100000部分与磁盘内容就一样了
   
                ;调用bootpack.c的初始化操作，解析bootpack.hrb的header并传入参数
		MOV		EBX,BOTPAK
		MOV		ECX,[EBX+16]
		ADD		ECX,3			
		SHR		ECX,2			
		JZ		skip			
		MOV		ESI,[EBX+20]	
		ADD		ESI,EBX
		MOV		EDI,[EBX+12]	
		CALL	memcpy
skip:
		MOV		ESP,[EBX+12]	
		JMP		DWORD 2*8:0x0000001b          ;跳到指定段中跳过可执行文件头p421

waitkbdout:
		IN		 AL,0x64
		AND		 AL,0x02
		JNZ		waitkbdout		
		RET

memcpy:
		MOV		EAX,[ESI]
		ADD		ESI,4
		MOV		[EDI],EAX
		ADD		EDI,4
		SUB		ECX,1
		JNZ		memcpy			
		RET


		ALIGNB	16
GDT0:                                                            ;临时设计的GDT表
		RESB	8				
		DW		0xffff,0x0000,0x9200,0x00cf	
		DW		0xffff,0x0000,0x9a28,0x0047	

		DW		0
GDTR0:                                                           ;临时设计的GDT选择子
		DW		8*3-1
		DD		GDT0

		ALIGNB	16
bootpack:

6. C语言代码如下bootpack.c

void io_hlt(void);
void write_mem8(int addr,int data);
void HariMain(void)
{
	int i;
	for(i=0xa0000;i<=0xaffff;i++)
	{
		write_mem8(i,15);        /*向内存的0xa0000~0xaffff位置写入信息，这块内存是显存空间，15是白色*/
 	}
	for(;;)
	{
		io_hlt();
	}

}


7. C语言中调用的io_hlt和write_mem8函数放到了如下代码中func.asm

[FORMAT "WCOFF"]				
[INSTRSET "i486p"]			
[BITS 32]						
[FILE "naskfunc.nas"]			
global _io_hlt,_write_mem8
[section .text]
;void io_hlt(void);
_io_hlt:
	HLT
	RET
	
;void write_mem8(int addr,int data);
_write_mem8:
	MOV ECX,[ESP+4]
	MOV AL,[ESP+8]
	MOV [ECX],AL
	RET

8. 在toolset文件夹内建立一个新文件夹，将上面所有的文件放在里边，编译链接接上面的文件，写个bat文件如下

nasm -o ipl10.bin ipl10.asm  ;生成引导扇区代码
nasm -o img.img img.asm      ;生成软盘镜像文件
..\z_tools\nask.exe asmhead.nas asmhead.bin
..\z_tools\cc1.exe -I..\z_tools\haribote\ -Os -Wall -quiet -o bootpack.gas bootpack.c
..\z_tools\gas2nask.exe -a bootpack.gas bootpack.nas
..\z_tools\nask.exe bootpack.nas bootpack.obj
..\z_tools\nask.exe func.asm func.obj
..\z_tools\obj2bim.exe @..\z_tools\haribote\haribote.rul out:bootpack.bim stack:3136k map:bootpack.map bootpack.obj func.obj
..\z_tools\bim2hrb.exe bootpack.bim bootpack.hrb 0
copy /B asmhead.bin+bootpack.hrb kernel.sys


9.这样除了中间文件外，生成img.img文件和kernel.sys文件。使用winImage打开img.img文件将kernel.sys文件加入到该img文件中。

10. 启动Bochs，呵呵看见屏幕白了，这可是从C代码里控制的啊！

11. asmhead中跳入保护模式的代码慢慢在深入掌握，不然会掉入细节里不能自拔了。

12. （这句很经典）asmhead和C代码是通过copy /B进行链接的其中asmhead代码最后留了个标号bootpack，在这个标号后面C的目标代码被砍去文件头直接将代码链接到了这里，所以能实现从汇编跳转到C语言的目的。

ltbylc
关注
  • 2
    点赞
  • 踩
  • 1
    收藏
    觉得还不错? 一键收藏
  • 0
    评论
专栏目录
《30天自制操作系统》 day3 小结
mintancy的博客
07-24 1561
《30天自制操作系统》 day3 小结
四、C语言与画面显示练习
Adolph_的专栏
10-07 1132
向显存里面写数据画白屏！。 汇编实现部分： ; naskfunc ; TAB=4 [FORMAT "WCOFF"]                    ;      [INSTRSET "i486p"]                    ;  [BITS 32]                              ;  [FILE "naskfunc.
《30天自制操作系统》从入门到放弃
wxkhturfun的博客
09-12 1万+
30天自制操作系统 01day 1.0写在前面的话 关于01day~03day，可以完全参考下述链接（下述内容部分也是来源此链接）： https://www.cnblogs.com/yucloud/category/1472969.html 1.1手打img 在下面这条链接中下载填制编辑软件 https://www.jb51.net/softs/601421.html#downintro2 （其实我不并推荐这种编辑器，使用vscode即可：https://www.cnblogs.com/baby123/p/
30天自制操作系统——第4天实验总结
核小体的博客
11-28 769
实验日期 实验项目 2020.10.22 第4天 C语言和画面显示的练习 文章目录一、实验主要内容1、 内容1 用C语言实现内存写入2、 内容2 条纹图案3、 内容3 挑战指针和指针的应用4、 内容4 色号设定5、 内容5 绘制矩形和系统界面二、遇到的问题及解决方法1、 描述问题1三、程序设计创新点1、 描述创新点1，关键代码及结果截图四、实验心得体会 一、实验主要内容 1、 内容1 用C语言实现内存写入 (1).内容概要 实验内容：用C语言实现内存写入，即向指定地址中写入指定的数...
《30天自制操作系统》入门方法总结
阿江的故事
08-31 375
《30天自制操作系统》是一位日本大佬“川合秀实”老师所写的一本书，逻辑清晰，语言朴实，我跟着中文版的电子书学习了两天，感觉很好。在这里我就实操环节简单做一下总结，以帮助初学者更好的入门
《30天自制操作系统》学习笔记_day03
zhangkai9895的博客
03-31 375
前言：第三天的难度还是蛮大的，看了一上午理解了大概，还是好好记录，捋顺一下。 1.实现Ipl的程序装载 首先实现用ipl指示将程序（软盘内容，操作系统）装载到内存特定位置 在03_day的harrib00a中的ipl.nas添加内容的部分 可以看到用到了 BIOS INT 0x13中断，0x13号中断主要用来磁盘的读写，AH=0x02说明用来读盘。 具体软盘的结构可以查询学习。 AH=处理对象的...
《30天自制操作系统》学习笔记_day01
zhangkai9895的博客
03-30 248
《30天自制操作系统》学习笔记_day01 1.二进制编辑器查看操作系统源代码并编写 博主未采用书中推荐二进制编辑器，而是使用Notepad++和HexEditor插件。 参考：新版Notepad++加十六进制查看的插件HexEditor 000000：HELLOIPL启动区的名称可以是任意的字符串（8字节） 启动区： 软盘的第一个扇区为启动区，计算机读取软盘512个字节为一个扇区单位。软盘大小...
《30 天自制操作系统》读书笔记.zip
10-16
《30天自制操作系统》是一本旨在引导读者亲手构建操作系统的学习指南。这本书通过实践的方式，帮助读者深入理解操作系统的原理和实现过程，从而提升对计算机系统本质的认知。 在阅读这本书的过程中，你可能会接触到...
操作系统读书笔记思维导图.xmind
10-24
操作系统读书笔记思维导图，一图胜千言，一图胜万字，结构清晰明了，内容丰富多彩，条理简明扼要，所见即所得，简约而不简单。
哈工大操作系统读书笔记1（第一周）
01-20
这篇读书笔记是根据第一周的学习内容编写的，涵盖了操作系统的基础概念和核心功能。 在第一周的学习中，我们首先会接触到操作系统的基本定义和角色。操作系统是系统软件的主体，它负责管理计算机的内存、处理器时间...
学生读书笔记共享系统代码 java学生读书笔记共享系统代码
最新发布
02-23
学生读书笔记共享系统代码 java学生读书笔记共享系统代码 基于springboot的学生读书笔记共享系统代码 1、学生读书笔记共享系统的技术栈、环境、工具、软件： 1、技术栈：java,springboot,vue，ajax，maven，mysql，...
进入32位模式并导入c语言教程,自制操作系统（十）| 进入32位模式并导入C语言...
weixin_36231529的博客
05-20 154
前期准备16位模式启动的话，用AX和CX等16位寄存器会非常方便，但反过来，像EAX和ECX等32位的寄存器，使用起来就很麻烦。另外，16位和32位模式中，机器语言中的命令代码不一样。同样的机器语言，解释的方法也不一样，所以16位模式的机器语言在32位模式下不能运行，反之亦然。在32位模式下，CPU的自我保护功能(识别出可疑的机器语言并进行屏蔽，以免破坏系统)在16位模式下不能使用，但32位能用。...
错误解决：process_begin: CreateProcess 系统找不到指定的文件
热门推荐
Langeldep的专栏
03-19 1万+
process_begin: CreateProcess(NULL, cc example.o -g -o example, ...) failed. make (e=2): 系统找不到指定的文件。 make: *** [Makefile:19: example] Error 2 解决方法： 在Makefile文件的开头增加CC=gcc
《操作系统30天》-合川秀实-学习日志day4
菜????一只
01-15 207
用C语言实现内存写入（harib01a） 在naskfunc.nas添加部分： _write_mem8: ; void write_mem8(int addr, int data); MOV ECX,[ESP+4] ; [ESP+4]中存放的是地址，将其读入ECX MOV AL,[ESP+8] ; [ESP+8]中存放的是数据，将其读入AL MOV [ECX],AL RET...
30天自制操作系统(day1)
m0_61722509的博客
11-08 1768
30天自制操作系统第一天内容
《30天自制操作系统》day1
lipengfei0427的博客
10-14 1770
今天开始正式学习操作系统啦!!!《30天自制操作系统》一本比较老旧的书，希望30天都能坚持看完。 内容1：利用二进制编辑器编写操作系统，输出“hello world”； 重点总结： 了解ASCII码相关知识，查询ASCII码对应表。 打开二进制编辑器，学会利用二进制表示法编写操作系统，输出hello world 根据课本提示要求，输入相关二进制，编写run.bat和install.bat...
30天自制操作系统——第1天 从计算机结构到汇编程序入门
weixin_59179454的博客
04-15 3570
落灰一学期的《30天自制操作系统》，希望能够利用大二最后这几个月完成操作系统的制作，以下是我阅读本书所记录的笔记以及学习过程，愿顺利完成。 1.先动手操作 安装“二进制编辑器”，网址：http://www.vcraft.jp/soft/bz.html 启动画面 ...
第4天 C语言与画面显示的练习
Histranger_的博客
03-28 499
第4天 C语言与画面显示的练习 2020.3.28 1. 用C语言实现内存写入 projects/04_day下的harib01a下的naskfunc.nas ; naskfunc ; TAB=4 [FORMAT "WCOFF"] ; 制作目标文件的模式 [INSTRSET "i486p"] ; 告诉nask，这个程序是给486用的 [BITS 32] ; 制作32...
Linux操作系统笔记：基础概念与实用命令详解
本资源是一份关于Linux操作系统的笔记，涵盖了操作系统的基础概念、常用命令以及特定环境下的应用。笔记由作者亲自动手记录，适合个人学习参考，其中包含了对不同发行版如RHEL、CentOS、Debian和Ubuntu的介绍，强调...

“相关推荐”对你有帮助么？

  • 非常没帮助
  • 没帮助
  • 一般
  • 有帮助
  • 非常有帮助
提交
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值