循环登录模板

// 循环解锁屏幕
for I = 1 to 3
[
  // 先执行退出
  xx管理平台_退出()
  解锁结果 = 循环解锁(15)
  if (解锁结果 <> 'True')
  [
    返回 = 设置指标('严重', '解锁屏幕失败', '解锁屏幕失败')
    Trace(返回)
    Exit           
  ]
  
  退出谷歌浏览器()
  
  // 设置分辨率
  错误消息 = 设置屏幕分辨率(1920, 1080)
  if (错误消息 <> '')
  [
     Trace('设置分辨率错误：' + 错误消息)
  ]  
  
  
  // 新建浏览器会话
  信息 = se启动Chrome驱动()
  if (信息 <> '')
  [
    返回 = 设置指标('严重', '启动谷歌驱动失败', '')
    Trace(返回)
    continue
  ]
  信息 = seNewSession(sSessionID)
  if (sSessionID = '')
  [
    返回 = 设置指标('严重', '建立浏览器会话失败：' + 信息, '')
    Trace(返回)
    continue
  ]    
  
  Trace('会话ID：' + sSessionID)
  
  // 打开登录界面
  seGoToUrl(sSessionID, 网址)
  seWaitEelementImplicitly(sSessionID, 60)
  信息 = seFindElementByClassName(sSessionID, 'login-home-wrap', sElementID)
  if (sElementID = '')
  [
    返回 = 设置指标('严重', '打开登录界面失败', '')
    Trace(返回)
    continue
  ]  

  信息 =seFindElementById(sSessionID, 'tab-login', sElementID)
  if (sElementID = '')
  [
    返回 = 设置指标('严重', '获取账号登录元素失败', '')
    Trace(返回)
    continue
  ]
  信息 =  seClickElement(sSessionID, sElementID)
  
  
  UserSelector = '#pane-login > div > form > div:nth-child(1) > div > div > div.login-input.el-input > input'
  信息 = seFindElementByCssSelector(sSessionID, UserSelector, sUserElementID)
  if (sUserElementID = '')
  [
    返回 = 设置指标('严重', '获取用户名元素失败', '')
    Trace(返回)
    continue
  ]
  
  PwdSelector = '#pane-login > div > form > div:nth-child(2) > div > div > div.login-input.el-input > input'
  信息 = seFindElementByCssSelector(sSessionID, PwdSelector, sPwdElementID)
  if (sPwdElementID = '')
  [
    返回 = 设置指标('严重', '获取用户名元素失败', '')
    Trace(返回)
    continue
  ]
  

  输出信息(Format('第%d次登录', [I]))
  // 清空用户名密码
  信息 = seClearElement(sSessionID, sUserElementID)
  信息 = seClearElement(sSessionID, sPwdElementID)
  

  用户 = 获取全局参数('京东数科用户')
  密码 = 获取全局参数('京东数科密码')
  信息 = seSendKeysToElement(sSessionID, sUserElementID, 用户)
  if (信息 <> '')
  [
    返回 = 设置指标('严重',信息,'输入用户失败')
    trace(返回)
    continue
  ]
  信息 = seSendKeysToElement(sSessionID, sPwdElementID, 密码)
  if (信息 <> '')
  [
    返回 = 设置指标('严重',信息,'输入密码失败')
    trace(返回)
    continue
  ]
  sleep(1000)
  
  LoginSelector = '#pane-login > div > div.daas-confirm-button'
  信息 = seFindElementByCssSelector(sSessionID, LoginSelector, sBtnElementID)
  if (sBtnElementID = '')
  [
    返回 = 设置指标('严重', '获取登录按钮失败', '')
    Trace(返回)
    continue
  ]
  信息 =  seClickElement(sSessionID, sBtnElementID)
  
  sRstSelector = '#app > div > div.main-container > section > section > div.el-dialog__wrapper.daas-dialog.jd-login-dialog > div > div.el-dialog__body > div > div.custom-footer > button:nth-child(1) > span'
  信息 = seFindElementByCssSelector(sSessionID, sRstSelector, sRstElementID)
  if (sRstElementID <> '')
  [
    信息 = seGetElementAttribute(sSessionID, sRstElementID, 'innerHTML', sText) 
    if (sText = '暂 不 授 权')
    [
      信息 = seClickElement(sSessionID, sRstElementID)
    ]
  ]
  

  
  //关闭通知消息框  el-icon-close     
  信息 = seFindElementByClassName(sSessionID, 'el-icon-close', sElementID) 
  if (sElementID <> '')
  [
    信息 = seClickElement(sSessionID, sElementID)
  ]
  
  // 查找登录成功标志
  信息 = seFindElementByClassName(sSessionID, 'menu-container', sElementID)
  if (sElementID <> '')
  [
    返回 = 设置指标('正常', '登录成功', '')
    Trace(返回)
    sleep(3000)
    Break
  ] else
  [
    返回 = 设置指标('严重', format('第%d次登录失败', [I]), '')
    Trace(返回)
    continue
  ]
]