文章目录
1，逻辑指令
and r0,r1,#0xFF // r0 = r1&0xFF
orr r3,r0,#0x0F // r3 = r0|0x0F
bic r0,r0,#0x03 // 清除r0中的0号位和1号位
tst r0,#0x20 //测试第6位是否为0 ，为0则Z标志置1 （实际上是逻辑与操作）
cmp r1,r0 //将R1与R0相减做比较，并根据结果设置CPSR的标志位
1.1例
使能中断和快速中断？
mrs r0,cpsr
bic r0,r0,#0xc0
msr cpsr,r0
判断当前工作状态是否是ARM状态，是则切换到user 工作模式？
mrs r0,cpsr
tst r0,#0x20
andeq r0,r0,#0xFFFFFFE0 @将低五位模式位清零
orreq r0,r0,#0x10 @将低五位模式位设置成10000
msreq cpsr,r0
2，算数指令
add r0,r1,r2 //r0=r1+r2
sub r0,r1,#3 //r0= r1 - 3
sub r0,r1,r2,LSL#1 //先把r2左移一位
mul r1,r2,r3 //r1=r2*r3
3，跳转指令
b main //跳转到标号为main地代码处
bl func //保存下一条要执行的指令的位置到 LR寄存器,跳转函数func
//当跳转代码结束后,用MOV PC,LR指令跳回来
beq addr //当CPSR寄存器中的Z条件码置位时，跳转到该地址处
bne addr //当不等时，跳转到地址addr
3.1.1例
用汇编实现下面功能
void main(void)
{
int ret=0;
func1(2);
while(1) {};
}
func1(int a)
{
if(a==2)
return func2(a);
else
return func3(a);
}
func2(int a)
{
return a+3;
}
func3(int a)
{
return a-1;
}
.text
main:
mov r5,#0
mov r0,#3
bl func1
main_end:
b main_end
func1:
mov r8,lr @备份lr寄存器中的地址
cmp r0,#2
bleq func2
blne func3
mov pc,r8
func1_end:
func2:
add r0,r0,#3
mov pc,lr
func2_end:
func3:
sub r0,r0,#1
mov pc,lr
func3_end:
.end
3.1.2例
实现 延时1秒函数
@delay fos 1 second
delay1s:
ldr r4,=0x24f000
loop_delay1s:
sub r4,r4,#1
cmp r4,#0
bne loop_delay1s
delay1s_end:
mov pc,lr
3.1.3例
用汇编实现求最大公约数?(如9 15 值是3)
int GCD(int a,int b)
{
while(1)
{
if(a==b)
break;
if(a>b){
a=a-b;
}else{
b=b-a;
}
}
return a;
}
.text
main:
mov r0,#9
mov r1,#15
bl gcd
main_end:
b main_end
gcd:
loop_gcd:
cmp r0,r1
beq gcd_end
subgt r0,r0,r1
sublt r1,r1,r0
b loop_gcd
gcd_end:
mov pc,lr
4，Load/Store 指令
注：load/store架构规定，存储器之间不能直接拷贝，需通过寄存器做中转
ldr r0,[r1] (load) //r0=*r1 r1里存放的是地址，把该地址里存放的内容读入到r0中
//LDRB（byte） LDRH（half word）
ldr r0，[r1，#8] //r0=*（r1+8) 存储器地址为r1+8的字数据读入寄存器0。
ldr pc,_irq // pc = *(_irq) 将标号中的内容放入pc中
str r0,[r1] (store) // *r1 = r0 将寄存器r0中值写入到存储器地址为r1的空间中
str r0,[r1],#4 // r0=*r1, r1=r1+4 将r0 中的字数据写入以r1为地址的内存中,并将新地址r1+4 写入r1
str r0,[r1,#4] //*(r1+4)=r0 将r0 中的字数据写入以r1+4 为地址的内存中
4.1 前索引/后索引
4.2.1，例—代码
.text @代码段
main:
ldr r5,=buf @伪指令
ldr r0,[r5] @load指令，将r5中的地址所对应的内容（字），放入r0中
ldrb r1,[r5] @load指令，将r5中的地址所对应的内容（字节），放入r0中
ldrh r2,[r5],#4 @load指令，将r5中的地址所对应的内容（半字），放入r0中。之后将r5中的地址向后偏移4
ldr r3,[r5],#-4 @load指令，将r5中的地址所对应的内容（字），放入r0中。之后将r5中的地址向前偏移4
ldr r6,=dest_buf1
ldr r7,=dest_buf2
ldr r8,=dest_buf3
str r0,[r6]
str r1,[r7]
strb r2,[r8]
main_end:
b main_end
.data @数据段
buf: .byte 0x01,0x02,0x03,0x04 @相当于C语言中的数组，char buf[]={0x01,0x02,0x03,0x04}
dest_buf1: .space 4 @相当于C语言中的数组，char buf[4]
dest_buf2: .space 4 @相当于C语言中的数组，char buf[4]
dest_buf3: .space 8 @相当于C语言中的数组，char buf[8]
.end @程序结束
- 代码段只读，数据段可读可写
4.2.2，例—运行结果
4.3，例
用汇编实现下面功能
main()
{
int i=0;
const char buf[]={1,2,3};
char destBuf[8];
for(i=0,i<3,i++)
{
destBuf[i] = buf[i];
}
}
.text @代码段
main:
ldr r6,=buf
ldr r7,=dest_buf
mov r5,#0
loop:
cmp r5,#3
beq main_end
ldrb r0,[r6],#1
strb r0,[r7],#1
add r5,r5,#1
b loop
main_end:
b main_end
buf: .byte 1,2,3
.data @数据段
dest_buf: .space 3
.end @代码结束
5，GNU伪指令
.text 将定义符开始的代码编译到代码段
.data 将定义符开始的代码编译到数据段
.end 文件结束
.equ GPG3CON, 0XE03001C0 定义宏（即用GPG3CON代替 0XE03001C0）
.byte 定义变量 1字节
.byte 0x11,'a',0 定义字节数组
.word 定义word变量 (4字节 32位机)
.word 0x12344578,0x33445566
.string 定义字符串 .string "abcd\0"
ldr r0,=0xE0028008 载入大常数0xE0028008 到r0中
.global _start 声明_start 为全局符号
5.1，例
.text
main:
ldr r5,=srcBuf
ldr r6,=destBuf
loop:
ldrb r4,[r5]
cmp r4,#0
beq main_end
ldrb r0,[r5],#1
strb r0,[r6],#1
b loop
main_end:
b main_end
srcBuf:
.string "abcdefg\0"
.data
destBuf:
.space 8
.end
6，批量操作指令
批量操作指令 (ia-Increment After ib-Increment Before da-Dec After db-Dec Before)
ldmia r0!, {r3 - r10} //r0里地址指向的内容批量，load 到r3~r10寄存器中， r0里地址会自动加4
stmia r0!, {r3 - r10} //把r3~r10寄存器中内容，store 到r0里地址执行空间中，r0里地址会自动加4
6.1，例
实现块数据批量拷贝
r12指向源数据起始地址
r14指向源数据尾地址
r13指向目的数据起始地址
.text
ldr r12,=srcBuf
ldr r13,=dstBuf
ldmia r12!,{r0 - r11}
stmia r13!,{r0 - r11}
.data
srcBuf:
.string "abdfasdf13535dfksjdlfkjlksldkjflkl\0"
srcBuf_end:
dstBuf:
.space 12*4
.end
7，堆栈操作指令
stmfd sp!,{r0-r12,lr} 将寄存器r0~r12 lr中的值存入栈中
常用于中断保护现场,! 表示会自动偏移
ldmfd sp!,{r0-r12,pc}^ 将栈中值逐个弹出到寄存器r0~r12 pc中
常用于中恢复断现场，^表示会恢复spsr到cpsr
8，软中断指令
swi 0x02 产生软中断， 软中断号为2
9，C和汇编混合编程
9.1，参数传递
- 开始四个字大小的参数直接使用寄存器的R0-R3来传递(快速且高效的)
更多的信息可参看ATPCS - 如果需要更多的参数，将使用堆栈。(需要额外的指令和慢速的存储器操作)
- 所以通常限制参数的个数，使它为4或更少。
- 如果不可避免，把常用的参数放在前4个
9.2，汇编调用C
int v = 0;
int add(int a, int b, int c, int d, int e)
{
v = a + b + c + d + e;
return v;
}
@使用R0-R3传递参数
@使用BL Lable调用C函数
@ 汇编调用C语言的代码
_start:
ldr sp,=0x20008000
mov r0, #0x01
mov r1, #0x02
mov r2, #0x03
mov r3, #0x04
mov r4, #0x05
stmfd sp!, {r4}
bl add
stop:
b stop
9.3，C调用汇编
.global mystrcopy
.text
mystrcopy:
LDRB r2, [r1], #1
STRB r2, [r0], #1
CMP r2, #0
BNE mystrcopy
MOV pc, lr
.end
//在C程序中直接调用
extern void mystrcopy(char *d, const char *s);
int main(void)
{
const char *src = "abcdef";
char dest[10];
mystrcopy(dest, src);
return 0;
}
//这里所有的参数都是可以用寄存器来传递的，所以不需要在汇编程序中使用PUSH/POP来保护
9.3，GNU内联汇编(在c中嵌入汇编)
在C程序中直接调用
asm volatile
(
"mov r0, #2\n\t"
"mov r1, #3\n\t"
"add r2, r1, r0\n\t"
);
注：指令之间必须要换行，\t可以不加，只是在汇编文件中的指令格式对齐
内联汇编语言必须以 “;” 结束，不管有多长对C都只是一条语句
Asm后面可以加 volatile，告诉编译器不要优化内嵌汇编。
附加
1. 汇编过渡到C语言
设置栈
b main
2. C语言调用汇编函数
//----------start.s
.global delay1s
delay1s:
cmp r0,#1
beq delay1s_end
sub r0,r0,#1
ldr r4,=0x3ffffff
delay1s_loop:
sub r4,r4,#1
cmp r4,#0
bne delay1s_loop
b delay1s
delay1s_end:
mov pc,lr
//-----------main.c
int main()
{
delay1s(3); //R0 ~R3 对应4个输入参数
}
3. C语言中嵌入汇编
int add(unsigned int a, unsigned int b )
{
int sum;
asm volatile //asm 声明为内联汇编 ，加volatile避免被编译器优化
(
"add %0,%1,%2\n\t" //汇编指令
:"=r"(sum) //输出操作符列表
:"r"(a),"r"(b) //输入操作符列表
:"memory"
);
return sum;
}
4万+
被折叠的 条评论
为什么被折叠?
到【灌水乐园】发言
