汇编语言-008（条件跳转应用 、loopnz 条件循环指令使用 、loopz 条件循环指令使用 、 if语句编写汇编时 、while语句编写汇编时 、循环内的if语句嵌套）

1： 条件跳转应用，三个数中最小数

.386
.model flat,stdcall

.stack 4096
ExitProcess PROTO,dwExitCode:DWORD

.data
V1 WORD 1
V2 WORD 2
V3 WORD 3

.code
main PROC
   mov ax,V1  ;假设V1是最小值
   cmp ax,V2  ;如果AX小于等于V2
   jbe L1
   mov ax,v2 
L1:
   cmp ax,V3
   jbe L2
   mov ax,V3
L2:
   INVOKE ExitProcess,0
main ENDP
END main

2： 条件跳转应用，循环直到按下按键

.386
.model flat,stdcall

include Irvine32.inc

.stack 4096
ExitProcess PROTO,dwExitCode:DWORD

.data
char BYTE ?

.code
main PROC
    L1:
	  mov eax,10
	  call Delay  ;10毫秒的延迟
	  call ReadKey ;检查按键
	  jz L1        ;如果没有按键就循环
	  mov char,AL  ;保存字符
   INVOKE ExitProcess,0
main ENDP
END main

3： 条件跳转应用，顺序搜索数组

.386
.model flat,stdcall

include Irvine32.inc

.stack 4096
ExitProcess PROTO,dwExitCode:DWORD

.data
intArray SWORD 0,0,0,0,1,20,35,-12,66,4,0
noneMsg BYTE "A non-zero value was not found",0

.code
main PROC
   mov ebx,OFFSET intArray
   mov ecx,LENGTHOF intArray
L1:
  cmp WORD PTR[ebx],0
  jnz found
  add ebx,2
  loop L1
  jmp notFound
found:
  movsx eax,WORD PTR[ebx]
  call WriteInt
  jmp quit
notFound:
   mov edx,OFFSET noneMsg
   call WriteString
quit:
   call Crlf
  INVOKE ExitProcess,0
main ENDP
END main

4： 条件跳转应用，简单字符串加密

.386
.model flat,stdcall

.stack 4096
ExitProcess PROTO,dwExitCode:DWORD

include Irvine32.inc

KEY = 239
BUFMAX = 128

.data
sPrompt BYTE "Enter the plain text:",0
sEncrypt BYTE "Cipher text: ",0
sDecrypt BYTE "Decrypted:  ",0
buffer BYTE BUFMAX+1 DUP(0)
bufSize DWORD ?

.code
main PROC
   call InputTheString
   call TranslateBuffer
   mov edx,OFFSET sEncrypt
   call DisplayMessage
   call TranslateBuffer
   mov edx,OFFSET sDecrypt
   call DisplayMessage
   INVOKE ExitProcess,0
main ENDP

;提示用户输入一个纯文本字符串
;保存字符串和它的长度
;接收：无
;返回：无
InputTheString PROC
   pushad
   mov edx,OFFSET sPrompt
   call WriteString
   mov ecx,BUFMAX
   mov edx,OFFSET buffer
   call ReadString
   mov bufSize,eax
   call Crlf
   popad
   ret
InputTheString ENDP


;显示加密或解密消息
;接收：EDX指向消息
;返回：无
DisplayMessage PROC
   pushad
   call WriteString
   mov edx,OFFSET buffer
   call WriteString
   call Crlf
   call Crlf
   popad
   ret
DisplayMessage ENDP

;字符串的每个字符与密钥字节进行异或实现转换
;接收：无
;返回：无
TranslateBuffer PROC
   pushad
   mov ecx,bufSize
   mov esi,0
L1:
   xor buffer[esi],KEY
   inc esi
   loop L1
   popad
   ret
TranslateBuffer ENDP
END main

5： loopnz 条件循环指令使用，查找数组第一个非负数

.386
.model flat,stdcall

.stack 4096
ExitProcess PROTO,dwExitCode:DWORD

.data
array SWORD -3,-6,-1,-10,10,30,40,4
sentinel SWORD 0

.code
main PROC
  mov esi,OFFSET array
  mov ecx,LENGTHOF array
L1:
  test WORD PTR[esi],8000h  ;测试符号位
  pushfd                    ;标志位入栈
  add esi,TYPE array        ;移动到下一个位置
  popfd
  loopnz L1                 ;当ZF=0时继续循环  
  jnz quit                  ;没有发现非负数
  sub esi,TYPE array        ;ESI指向数值
quit:
  INVOKE ExitProcess,0

main ENDP
END main

6： loopz 条件循环指令使用，查找数组第一个负数

.386
.model flat,stdcall

.stack 4096
ExitProcess PROTO,dwExitCode:DWORD

.data
array SWORD 3,6,1,10,-10,-30,-40,-4
sentinel SWORD 0

.code
main PROC
  mov esi,OFFSET array
  mov ecx,LENGTHOF array
L1:
  test WORD PTR[esi],8000h  ;测试符号位
  pushfd                    ;标志位入栈
  add esi,TYPE array        ;移动到下一个位置
  popfd
  loopz L1                  ;当ZF=1时继续循环  
  jz quit                  ;没有发现非负数
  sub esi,TYPE array        ;ESI指向数值
quit:
  INVOKE ExitProcess,0

main ENDP
END main

7： if语句编写汇编时的情况

.386
.model flat,stdcall

.stack 4096
ExitProcess PROTO,dwExitCode:DWORD

;if(al > bl) & (bl > cl)
;  X = 1


.data
X DWORD ?

.code
main PROC




  INVOKE ExitProcess,0
main ENDP

proc_1 PROC
	  cmp al,bl
	  ja L1
	  jmp next
	L1:
	   cmp bl,cl
	   ja L2
	   jmp next
	L2:
	   mov X,1
	next:
proc_1 ENDP


;如果将ja 换成 jbe,代码减少2条
proc_2 PROC
	
	  cmp al,bl
	  jbe next
	  cmp bl,cl
	  jbe next
	  mov X,1
	next:

proc_2 ENDP

END main

8： if语句编写汇编时的情况

.386
.model flat,stdcall

.stack 4096
ExitProcess PROTO,dwExitCode:DWORD

.data
X DWORD ?

;if(al > bl) || (bl > cl)
;X =1

.code
main PROC
  cmp al,bl
  ja L1
  cmp bl,cl
  jbe next
L1: 
  mov X,1
next:
  INVOKE ExitProcess,0
main ENDP
END main

9： while语句编写汇编时的情况

.386
.model flat,stdcall

.stack 4096
ExitProcess PROTO,dwExitCode:DWORD

.data
val1 DWORD 10
val2 DWORD 20

;while (val1 < val2)
;{
;   val1 ++;
;   val2 --;
;}

.code
main PROC
  mov eax,val1
beginwhile:
  cmp eax,val2
  jnl endwhile
  inc eax
  dec val2
  jmp beginwhile
endwhile:
  mov val1,eax
  INVOKE ExitProcess,0
main ENDP
END main

10： 循环内的if语句嵌套

.386
.model flat,stdcall

.stack 4096
ExitProcess PROTO,dwExitCode:DWORD

.data
sum DWORD 0
sample DWORD 50   ;计算数组所有大于sample的数之和
array DWORD 10,60,20,33,72,89,45,72,18
arraySize = ($ - array)/TYPE array

.code
main PROC
   mov eax,0
   mov edx,sample
   mov esi,0
   mov ecx,arraySize
L1:
   cmp esi,ecx
   jl L2
   jmp L5
L2:
   cmp array[esi*4],edx
   jg L3
   jmp L4
L3:
   add eax,array[esi*4]
L4:
   inc esi
   jmp L1
L5:
   mov sum,eax
  
  INVOKE ExitProcess,0
main ENDP
END main