IDEA自带的代码生成脚本 Generate POJOs.groovy

最新推荐文章于 2023-07-13 15:20:08 发布

theONLY24

最新推荐文章于 2023-07-13 15:20:08 发布

阅读量3.7k

点赞数 3

分类专栏： java mysql 文章标签：数据库 groovy java

本文链接：https://blog.csdn.net/m0_46157986/article/details/105913664

版权

java 同时被 2 个专栏收录

14 篇文章 1 订阅

订阅专栏

mysql

13 篇文章 0 订阅

订阅专栏

IDEA自带的代码生成脚本 `Generate POJOs.groovy`

1. 打开IDEA，连接到数据库

在这里插入图片描述
或

2. 脚本代码

成功连接数据库后，会出现下图所示的脚本文件（用来自动生成实体类）：
在这里插入图片描述

3. 生成实体类

在这里插入图片描述

注意：此时生成的实体类是没有 Jpa 注解的

4. 自定义（JPA）实体类生成脚本

修改Generate POJOs.groovy脚本文件

import com.intellij.database.model.DasTable
import com.intellij.database.model.ObjectKind
import com.intellij.database.util.Case
import com.intellij.database.util.DasUtil

import java.text.SimpleDateFormat

/*
 * Available context bindings:
 *   SELECTION   Iterable<DasObject>
 *   PROJECT     project
 *   FILES       files helper
 */
packageName = ""
typeMapping = [
        (~/(?i)tinyint|smallint|mediumint/)      : "Integer",
        (~/(?i)int/)                             : "Long",
        (~/(?i)bool|bit/)                        : "Boolean",
        (~/(?i)float|double|decimal|real/)       : "BigDecimal",
        (~/(?i)datetime|timestamp|date|time/)    : "Date",
        (~/(?i)blob|binary|bfile|clob|raw|image/): "InputStream",
        (~/(?i)/)                                : "String"
]


FILES.chooseDirectoryAndSave("Choose directory", "Choose where to store generated files") { dir ->
  SELECTION.filter { it instanceof DasTable && it.getKind() == ObjectKind.TABLE }.each { generate(it, dir) }
}

def generate(table, dir) {
  def className = javaName(table.getName(), true)
  def fields = calcFields(table)
  packageName = getPackageName(dir)
  PrintWriter printWriter = new PrintWriter(new OutputStreamWriter(new FileOutputStream(new File(dir, className + ".java")), "UTF-8"))
  printWriter.withPrintWriter { out -> generate(out, className, fields, table) }

//    new File(dir, className + ".java").withPrintWriter { out -> generate(out, className, fields,table) }
}

// 获取包所在文件夹路径
def getPackageName(dir) {
  return dir.toString().replaceAll("\\\\", ".").replaceAll("/", ".").replaceAll("^.*src(\\.main\\.java\\.)?", "") + ";"
}

def generate(out, className, fields, table) {
  out.println "package $packageName"
  out.println ""
  out.println "import javax.persistence.Column;"
  out.println "import javax.persistence.Entity;"
  out.println "import javax.persistence.Table;"
  out.println "import javax.persistence.Id;"
  out.println "import javax.persistence.GeneratedValue;"
  out.println "import java.io.Serializable;"
  Set types = new HashSet()

  fields.each() {
    types.add(it.type)
  }

  if (types.contains("Date")) {
    out.println "import java.util.Date;"
  }

  if (types.contains("BigDecimal")) {
    out.println "import java.math.BigDecimal;"
  }

  if (types.contains("InputStream")) {
    out.println "import java.io.InputStream;"
  }
  out.println ""
  out.println "/**\n" +
          " * @Description  \n" +
          " * @Author  linmengmeng\n" + //1. 修改idea为自己名字
          " * @Date " + new SimpleDateFormat("yyyy-MM-dd HH:mm:ss").format(new Date()) + " \n" +
          " */"
  out.println ""
  out.println "@Entity"
  out.println "@Table ( name =\"" + table.getName() + "\" , schema = \"\")" //2. schema = \"后面添加自己的表空间名称(mysql可以不添加, 不用这个schema属性也行)
  out.println "public class $className  implements Serializable {"
  out.println ""
  out.println genSerialID()
  fields.each() {
    out.println ""
    // 输出注释
    if (isNotEmpty(it.commoent)) {
      out.println "\t/**"
      out.println "\t * ${it.commoent.toString()}"
      out.println "\t */"
    }

    if ((it.annos+"").indexOf("[@Id]") >= 0) out.println "\t@Id"

    if (it.annos != "") out.println "   ${it.annos.replace("[@Id]", "")}"


    // 输出成员变量
    out.println "\tprivate ${it.type} ${it.name};"
  }

  // 输出get/set方法
  fields.each() {
    out.println ""
    out.println "\tpublic ${it.type} get${it.name.capitalize()}() {"
    out.println "\t\treturn this.${it.name};"
    out.println "\t}"
    out.println ""

    out.println "\tpublic void set${it.name.capitalize()}(${it.type} ${it.name}) {"
    out.println "\t\tthis.${it.name} = ${it.name};"
    out.println "\t}"
  }

  // 输出toString方法
  out.println ""
  out.println "\t@Override"
  out.println "\tpublic String toString() {"
  out.println "\t\treturn \"{\" +"
  fields.each() {
    out.println "\t\t\t\t\t\"${it.name}='\" + ${it.name} + '\\'' +"
  }
  out.println "\t\t\t\t'}';"
  out.println "\t}"

  out.println ""
  out.println "}"
}

def calcFields(table) {
  DasUtil.getColumns(table).reduce([]) { fields, col ->
    def spec = Case.LOWER.apply(col.getDataType().getSpecification())

    def typeStr = typeMapping.find { p, t -> p.matcher(spec).find() }.value
    def comm = [
            colName : col.getName(),
            name    : javaName(col.getName(), false),
            type    : typeStr,
            commoent: col.getComment(),
            annos   : "\t@Column(name = \"" + col.getName() + "\" )"]
    if ("id".equals(Case.LOWER.apply(col.getName())))
      comm.annos += ["@Id"]
    fields += [comm]
  }
}

// 这里是处理数据库表前缀的方法，这里处理的是tb_xxx命名的表
// 已经修改为使用javaName, 如果有需要可以在def className = javaName(table.getName(), true)中修改为javaClassName
// 处理类名（这里是因为我的表都是以tb_命名的，所以需要处理去掉生成类名时的开头的T，
// 如果你不需要去掉表的前缀，那么请查找用到了 javaClassName这个方法的地方修改为 javaName 即可）
def javaClassName(str, capitalize) {
  def s = com.intellij.psi.codeStyle.NameUtil.splitNameIntoWords(str)
          .collect { Case.LOWER.apply(it).capitalize() }
          .join("")
          .replaceAll(/[^\p{javaJavaIdentifierPart}[_]]/, "_")
  // 去除开头的T  http://developer.51cto.com/art/200906/129168.htm
  s = s[2..s.size() - 1]
  capitalize || s.length() == 1 ? s : Case.LOWER.apply(s[0]) + s[1..-1]
}

def javaName(str, capitalize) {
//    def s = str.split(/(?<=[^\p{IsLetter}])/).collect { Case.LOWER.apply(it).capitalize() }
//            .join("").replaceAll(/[^\p{javaJavaIdentifierPart}]/, "_")
//    capitalize || s.length() == 1? s : Case.LOWER.apply(s[0]) + s[1..-1]
  def s = com.intellij.psi.codeStyle.NameUtil.splitNameIntoWords(str)
          .collect { Case.LOWER.apply(it).capitalize() }
          .join("")
          .replaceAll(/[^\p{javaJavaIdentifierPart}[_]]/, "_")
  capitalize || s.length() == 1 ? s : Case.LOWER.apply(s[0]) + s[1..-1]
}

def isNotEmpty(content) {
  return content != null && content.toString().trim().length() > 0
}

static String changeStyle(String str, boolean toCamel) {
  if (!str || str.size() <= 1)
    return str

  if (toCamel) {
    String r = str.toLowerCase().split('_').collect { cc -> Case.LOWER.apply(cc).capitalize() }.join('')
    return r[0].toLowerCase() + r[1..-1]
  } else {
    str = str[0].toLowerCase() + str[1..-1]
    return str.collect { cc -> ((char) cc).isUpperCase() ? '_' + cc.toLowerCase() : cc }.join('')
  }
}

//生成序列化的serialVersionUID
static String genSerialID() {
  return "\tprivate static final long serialVersionUID =  " + Math.abs(new Random().nextLong()) + "L;"
}

生成的实体类：

copy到项目中，修改package

package E:.Linux;

import javax.persistence.Column;
import javax.persistence.Entity;
import javax.persistence.Table;
import javax.persistence.Id;
import javax.persistence.GeneratedValue;
import java.io.Serializable;

/**
 * @Description  
 * @Author  linmengmeng
 * @Date 2020-05-04 09:53:34 
 */

@Entity
@Table ( name ="tb_user" , schema = "")
public class TbUser  implements Serializable {

	private static final long serialVersionUID =  507302061348687792L;

	/**
	 * 用户名
	 */
   	@Column(name = "username" )
	private String username;

	/**
	 * 主键id
	 */
	@Id
   	@Column(name = "id" )
	private Long id;

   	@Column(name = "password" )
	private String password;

	public String getUsername() {
		return this.username;
	}

	public void setUsername(String username) {
		this.username = username;
	}

	public Long getId() {
		return this.id;
	}

	public void setId(Long id) {
		this.id = id;
	}

	public String getPassword() {
		return this.password;
	}

	public void setPassword(String password) {
		this.password = password;
	}

	@Override
	public String toString() {
		return "{" +
					"username='" + username + '\'' +
					"id='" + id + '\'' +
					"password='" + password + '\'' +
				'}';
	}

}

生成实体类+service+repository+controller

import com.intellij.database.model.DasTable
import com.intellij.database.model.ObjectKind
import com.intellij.database.util.Case
import com.intellij.database.util.DasUtil

config = [
        impSerializable  : true,
        extendBaseEntity : false,
        extendBaseService: true

]
baseEntityPackage = "com.hhsj.base.BaseEntity"
baseServicePackage = "com.hhsj.base.BaseService"
baseEntityProperties = ["id", "createDate", "lastModifiedDate", "version"]
typeMapping = [
        (~/(?i)bool|boolean|tinyint/)     : "Boolean",
        (~/(?i)bigint/)                   : "Long",
        (~/int/)                          : "Integer",
        (~/(?i)float|double|decimal|real/): "Double",
        (~/(?i)datetime|timestamp/)       : "java.util.Date",
        (~/(?i)date/)                     : "java.sql.Date",
        (~/(?i)time/)                     : "java.sql.Time",
        (~/(?i)/)                         : "String"
]

FILES.chooseDirectoryAndSave("Choose directory", "Choose where to store generated files") { dir ->
  SELECTION.filter {
    it instanceof DasTable && it.getKind() == ObjectKind.TABLE
  }.each {
    generate(it, dir)
  }
}
//dif -> E:\DEVELOPE\Code\jpademo\src\main\java\com\demo\jpa
def generate(table, dir) {

  def entityPath = "${dir.toString()}\\entity",
      servicePath = "${dir.toString()}\\service",
      repPath = "${dir.toString()}\\repository",
      serviceImpPath = "${dir.toString()}\\service\\impl",
      controllerPath = "${dir.toString()}\\controller"

  mkdirs([entityPath, servicePath, repPath, serviceImpPath, controllerPath])

  def entityName = javaClassName(table.getName(), true)
  def fields = calcFields(table)
  def basePackage = clacBasePackage(dir)

  new File("${entityPath}\\${entityName}.java").withPrintWriter("utf-8") { out -> genEntity(out, table, entityName, fields, basePackage) }
  new File("${servicePath}\\${entityName}Service.java").withPrintWriter("utf-8") { out -> genService(out, table, entityName, fields, basePackage) }
  new File("${repPath}\\${entityName}Repository.java").withPrintWriter("utf-8") { out -> genRepository(out, table, entityName, fields, basePackage) }
//  new File("${repPath}\\${entityName}RepositoryCustom.java").withPrintWriter("utf-8") { out -> genRepositoryCustom(out, entityName, basePackage) }
  new File("${serviceImpPath}\\${entityName}ServiceImpl.java").withPrintWriter("utf-8") { out -> getServiceImpl(out, table, entityName, fields, basePackage) }
  new File("${controllerPath}\\${entityName}Controller.java").withPrintWriter("utf-8") { out -> genController(out, table, entityName, fields, basePackage) }

}

def genProperty(out, field) {
  if (isNotEmpty(field.comment)) {
    // 没有效果
    out.println "\t/**${field.comment}*/"
  }
  if (field.annos != "") out.println "  ${field.annos}"
  if (field.colum != field.name) {
    out.println "\t@Column(name = \"${field.colum}\")"
  }
  out.println "\tprivate ${field.type} ${field.name};"
  out.println ""
}

def genEntity(out, table, entityName, fields, basePackage) {
  out.println "package ${basePackage}.entity;"
  out.println ""
  if (config.extendBaseEntity) {
    out.println "import $baseEntityPackage;"
  }
  out.println "import lombok.Data;"
  out.println ""
  if (config.impSerializable) {
    out.println "import java.io.Serializable;"
    out.println "import com.fasterxml.jackson.annotation.JsonIgnoreProperties;"
    out.println ""
  }
  out.println "import javax.persistence.*;"
  out.println ""
  out.println "@Data"
  out.println "@Entity"
  out.println "@Table(name = \"${table.getName()}\")"
  out.println "@JsonIgnoreProperties(value={\"hibernateLazyInitializer\",\"handler\",\"fieldHandler\"})"
  out.println "public class $entityName${config.extendBaseEntity ? " extends BaseEntity" : ""}${config.impSerializable ? " implements Serializable" : ""} {"
  out.println ""
  out.println genSerialID()
  if (config.extendBaseEntity) {
    // 继承父类
    fields.each() { if (!isBaseEntityProperty(it.name)) genProperty(out, it) }
  } else {
    // 不继承父类
    out.println "\t@Id"
    out.println "\t@GeneratedValue(strategy = GenerationType.IDENTITY)"
    fields.each() {
      genProperty(out, it)
    }
  }
  out.println "}"

}

def genController(out, table, entityName, fields, basePackage) {
//  def lowerEntityName = entityName.toLowerCase()
  def lowerEntityName = "";
  if (entityName.length() == 1) {
    lowerEntityName= entityName.toLowerCase()
  } else {

    lowerEntityName = entityName.substring(0,1).toLowerCase()+entityName.substring(1)
  }
  out.println "package ${basePackage}.controller;"
  out.println ""
  out.println "import org.springframework.web.bind.annotation.RequestMapping;"
  out.println "import org.springframework.web.bind.annotation.RestController;"
  out.println "import org.springframework.beans.factory.annotation.Autowired;"
  out.println "import ${basePackage}.service.${entityName}Service;"
  out.println ""
  out.println "@RestController"
  out.println "@RequestMapping(\"/${lowerEntityName}\")"

  out.println "public class ${entityName}Controller {"
  out.println ""
  out.println "\t@Autowired"
  out.println "\tprivate ${entityName}Service ${lowerEntityName}Service;"
  out.println ""
  out.println "}"
}

def genService(out, table, entityName, fields, basePackage) {
  out.println "package ${basePackage}.service;"
  out.println ""
  out.println "import ${basePackage}.repository.${entityName}Repository;"
  out.println "import ${basePackage}.base.Result;"
  if (config.extendBaseService) {
    out.println "import $baseServicePackage;"
    out.println "import ${basePackage}.entity.$entityName;"
  }
  out.println "import org.springframework.stereotype.Service;"
  out.println ""
  out.println "import javax.annotation.Resource;"
  out.println ""
  out.println "public interface ${entityName}Service${config.extendBaseService ? " extends BaseService<$entityName, ${fields[0].type}>" : ""}  {"
  out.println ""
  out.println "   //根据id查询"
  out.println "   public Result getOne(${fields[0].type} id);"
  out.println ""
  out.println "   //根据id删除"
  out.println "   public Result deleteOne(${fields[0].type} id);"
  out.println ""
  out.println "   //根据id保存"
  out.println "   public Result saveOne(${entityName} entity);"
  out.println "}"
}

def genRepository(out, table, entityName, fields, basePackage) {
  out.println "package ${basePackage}.repository;"
  out.println ""
  out.println "import ${basePackage}.entity.$entityName;"
  out.println "import org.springframework.data.jpa.repository.JpaRepository;"
  out.println ""
  out.println "public interface ${entityName}Repository extends JpaRepository<$entityName, ${fields[0].type}>{}"
}

/*def genRepositoryCustom(out, entityName, basePackage) {
  out.println "package ${basePackage}.repository;"
  out.println ""
  out.println "public interface ${entityName}RepositoryCustom { "
  out.println "}"
}*/

def getServiceImpl(out, table, entityName, fields, basePackage) {

  out.println "package ${basePackage}.service.impl;"
  out.println ""
  out.println "import ${basePackage}.service.${entityName}Service;"
  out.println "import org.springframework.stereotype.Service;"
  out.println "import ${basePackage}.base.Result;"
  out.println "import ${basePackage}.entity.${entityName};"
  out.println "import ${basePackage}.service.${entityName}Service;"
  out.println "import ${basePackage}.repository.${entityName}Repository;"
  out.println "import org.springframework.beans.factory.annotation.Autowired;"
  out.println ""
  out.println "@Service"
  out.println "public class ${entityName}ServiceImpl implements ${entityName}Service {"
  out.println ""
  out.println "\t@Autowired"
  out.println "\tprivate ${entityName}Repository rep;"
  out.println ""
  out.println "\t@Override"
  out.println "\tpublic Result getOne(${fields[0].type} id){"
  out.println " \t\t${entityName} one = rep.getOne(id);"
  out.println "\t\treturn Result.builder().success().data(one).build();"
  out.println "\t}"
  out.println ""
  out.println "\t@Override"
  out.println "\tpublic Result deleteOne(${fields[0].type} id){"
  out.println " \t\trep.deleteById(id);"
  out.println "\t\treturn Result.builder().success().build();"
  out.println "\t}"
  out.println ""
  out.println "\t@Override"
  out.println "\tpublic Result saveOne(${entityName} entity){"
  out.println " \t\t${entityName} one = rep.save(entity);"
  out.println "\t\treturn Result.builder().success().data(one).build();"
  out.println "\t}"
  out.println "}"
}

def mkdirs(dirs) {
  dirs.forEach {
    def f = new File(it)
    if (!f.exists()) {
      f.mkdirs();
    }
  }
}

def clacBasePackage(dir) {
  dir.toString()
          .replaceAll("^.+\\\\src\\\\main\\\\java\\\\", "")
          .replaceAll("\\\\", ".")
}

def isBaseEntityProperty(property) {
  baseEntityProperties.find { it == property } != null
}
// 转换类型
def calcFields(table) {
  DasUtil.getColumns(table).reduce([]) {
    fields, col ->
      def spec = Case.LOWER.apply(col.getDataType().getSpecification())
      def typeStr = typeMapping.find { p, t -> p.matcher(spec).find() }.value
      fields += [[
                         name : javaName(col.getName(), false),
                         colum: col.getName(),
                         type : typeStr,
                         comment : col.getComment(),
                         annos: ""]]
  }
}

// 处理类名（这里是因为我的表都是以tb_命名的，所以需要处理去掉生成类名时的开头的T，
// 如果你不需要那么请查找用到了 javaClassName这个方法的地方修改为 javaName 即可）
def javaClassName(str, capitalize) {
  def s = str.split(/[^\p{Alnum}]/).collect { def s = Case.LOWER.apply(it).capitalize() }.join("")
  // 去除开头的tb  http://developer.51cto.com/art/200906/129168.htm
  s = s[2..s.size() - 1]
  capitalize ? s : Case.LOWER.apply(s[0]) + s[1..-1]
}

def javaName(str, capitalize) {
  def s = str.split(/(?<=[^\p{IsLetter}])/).collect { Case.LOWER.apply(it).capitalize() }
          .join("").replaceAll(/[^\p{javaJavaIdentifierPart}]/, "_").replaceAll(/_/, "")
  capitalize || s.length() == 1 ? s : Case.LOWER.apply(s[0]) + s[1..-1]
}
def isNotEmpty(content) {
  return content != null && content.toString().trim().length() > 0
}
static String genSerialID() {
  return "\tprivate static final long serialVersionUID =  " + Math.abs(new Random().nextLong()) + "L;";
}

theONLY24

关注

3
点赞
踩
9

收藏

觉得还不错? 一键收藏
2
评论
IDEA自带的代码生成脚本 Generate POJOs.groovy

IDEA自带的生成实体类的脚本 Generate POJOs.groovy1. 打开IDEA，连接到数据库或2. 脚本代码成功连接数据库后，会出现下图所示的脚本文件（用来自动生成实体类）：3. 生成实体类注意：此时生成的实体类是没有 Jpa 注解的4. 自定义（JPA）实体类生成脚本修改Generate POJOs.groovy脚本文件import com.int...
复制链接

扫一扫