用IDEA根据sql生成Java POJO（Model）类

1、首先在idea右侧中连接数据库

  数据库第一次连接可能会提示没有连接驱动，点击确定就会自动下载，连接前先点击测试连接试试连接有没有问题。

2、生成POJO类

  连接上以后就可以选择表右键：工具——>脚本化扩展程序——>Generate POJOs.groovy然后选择生成目标目录就会生成到该目录下

3、脚本编写

  默认Generate POJOs.groovy脚本生成的POJO类是这样很简陋的，要想个性化自己的POJO类需要修改窗口左下角临时文件和控制台下的扩展下的com.intellij.database下的Generate POJOs.groovy文件。


我将脚本中的一些方法都加了注释，用户可以自行修改脚本

import com.intellij.database.model.DasTable
import com.intellij.database.model.ObjectKind
import com.intellij.database.util.Case
import com.intellij.database.util.DasUtil
import java.io.*
import java.text.SimpleDateFormat

/*
 * Available context bindings:
 *   SELECTION   Iterable<DasObject>
 *   PROJECT     project
 *   FILES       files helper
 */
//包路径，这里可以写死也可以置空由getPackageName动态生成
packageName = ""
//mysql类型对应java类型
typeMapping = [
        (~/(?i)tinyint|smallint|mediumint/)      : "Integer",
        (~/(?i)bigint/)                          : "Long",
        (~/(?i)int/)                             : "Integer",
        (~/(?i)bool|bit/)                        : "Boolean",
        (~/(?i)float|double|decimal|real/)       : "Double",
        (~/(?i)datetime|timestamp|date|time/)    : "String",
        (~/(?i)blob|binary|bfile|clob|raw|image/): "InputStream",
        (~/(?i)/)                                : "String"
]


FILES.chooseDirectoryAndSave("Choose directory", "Choose where to store generated files") { dir ->
    SELECTION.filter { it instanceof DasTable && it.getKind() == ObjectKind.TABLE }.each { generate(it, dir) }
}

def generate(table, dir) {
    def className = javaClassName(table.getName(), true)
    // def className = javaName(table.getName(), true)
    def fields = calcFields(table)
    packageName = getPackageName(dir)
    PrintWriter printWriter = new PrintWriter(new OutputStreamWriter(new FileOutputStream(new File(dir, className + ".java")), "UTF-8"))
    printWriter.withPrintWriter { out -> generate(out, className, fields, table) }

//    new File(dir, className + ".java").withPrintWriter { out -> generate(out, className, fields,table) }
}

// 获取包所在文件夹路径
def getPackageName(dir) {
    return dir.toString().replaceAll("\\\\", ".").replaceAll("/", ".").replaceAll("^.*src(\\.main\\.java\\.)?", "") + ";"
}
//生成实体类
def generate(out, className, fields, table) {
    def tableName = table.getName()
    out.println "package $packageName"
    out.println ""
    out.println "import java.io.Serializable;"
    out.println "import javax.persistence.Column;"
    out.println "import javax.persistence.Table;"
    out.println "import javax.persistence.Id;"
    out.println "import lombok.Getter;"
    out.println "import lombok.Setter;"
    out.println "import lombok.ToString;"

    Set types = new HashSet()

    fields.each() {
        types.add(it.type)
    }

    //如果有日期类型的文件则导入日期类
    if (types.contains("Date")) {
        out.println "import java.util.Date;"
    }
    //如果有io类导入InputStream类
    if (types.contains("InputStream")) {
        out.println "import java.io.InputStream;"
    }
    out.println ""
    out.println "/**\n" +
            " * @Description  \n" +
            " * @Author  \n" +
            " * @Date " + new SimpleDateFormat("yyyy-MM-dd").format(new Date()) + " \n" +
            " */"
    out.println "@Getter"
    out.println "@Setter"
    out.println "@ToString"
    out.println "@Table(\"" + table.getName() + "\")"
    out.println "public class $className implements Serializable {"
    out.println genSerialID()


    fields.each() {
        out.println ""
        // 输出注释
        if (isNotEmpty(it.commoent)) {
            out.println "\t/**"
            out.println "\t * ${it.commoent.toString()}"
            out.println "\t */"
        }

        if (it.annos != "") out.println "\t${it.annos}"

        if (("id").equalsIgnoreCase(it.name) || (it.name.contains("Id") && !it.type.equals("String"))) {
            // 输出成员变量
            // out.println "\tprivate Long ${it.name};"
            out.println "\tprivate ${it.type} ${it.name};"
        } else {
            out.println "\tprivate ${it.type} ${it.name};"
        }

    }

    // 输出get/set方法
//    fields.each() {
//        out.println ""
//        out.println "\tpublic ${it.type} get${it.name.capitalize()}() {"
//        out.println "\t\treturn this.${it.name};"
//        out.println "\t}"
//        out.println ""
//
//        out.println "\tpublic void set${it.name.capitalize()}(${it.type} ${it.name}) {"
//        out.println "\t\tthis.${it.name} = ${it.name};"
//        out.println "\t}"
//    }
    // toString方法
//    out.println "\t@Override"
//    out.println "\tpublic String toString() {"
//    out.print "\t\t return "
//    out.print "\"$className"
//    out.println "{\"+ "
//    fields.each() {
//        out.println "\t\t\t\", ${it.name}='\" + ${it.name} + '\\'' +"
//    }
//    out.println "\t\t'}\';"
//    out.println "\t}"

    out.println "}"
    out.println ""
}
//遍历表为字段类添加名称，类型，注释，以及自定义annos值
def calcFields(table) {
    DasUtil.getColumns(table).reduce([]) { fields, col ->
        def spec = Case.LOWER.apply(col.getDataType().getSpecification())

        def typeStr = typeMapping.find { p, t -> p.matcher(spec).find() }.value
        def comm = [
                colName : col.getName(),
                name    : javaName(col.getName(), false),
                type    : typeStr,
                commoent: col.getComment(),
                annos: "@Column(name = \"" + col.getName() + "\" )"
        ]
        //对于表中主键自定义注解
        if ("pk".equals(Case.LOWER.apply(col.getName()))){
            comm.annos = "\t@Id\n"
            //自增主键需要
            comm.annos += "@Column(name = \"" + col.getName() + "\")"
        }
        fields += [comm]
    }
}

// 处理类名（这里是因为我的表都是以detection_命名的，所以需要处理去掉生成类名时的开头的detection，
// 如果你不需要那么请查找用到了javaClassName这个方法的地方修改为 javaName 即可）
def javaClassName(str, capitalize) {
    def s = com.intellij.psi.codeStyle.NameUtil.splitNameIntoWords(str)
            .collect { Case.LOWER.apply(it).capitalize() }
            .join("")
            .replaceAll(/[^\p{javaJavaIdentifierPart}[_]]/, "_")
    // 此时s应该是Detectionxxx要去除开头的detection应该是截取从第9位到最后一位
    s = s[9..s.size() - 1]
    capitalize || s.length() == 1 ? s : Case.LOWER.apply(s[0]) + s[1..-1]
}

def javaName(str, capitalize) {
//    def s = str.split(/(?<=[^\p{IsLetter}])/).collect { Case.LOWER.apply(it).capitalize() }
//            .join("").replaceAll(/[^\p{javaJavaIdentifierPart}]/, "_")
//    capitalize || s.length() == 1? s : Case.LOWER.apply(s[0]) + s[1..-1]
    def s = com.intellij.psi.codeStyle.NameUtil.splitNameIntoWords(str)
            .collect { Case.LOWER.apply(it).capitalize() }
            .join("")
            .replaceAll(/[^\p{javaJavaIdentifierPart}[_]]/, "_")
    capitalize || s.length() == 1 ? s : Case.LOWER.apply(s[0]) + s[1..-1]
}

def isNotEmpty(content) {
    return content != null && content.toString().trim().length() > 0
}

static String changeStyle(String str, boolean toCamel) {
    if (!str || str.size() <= 1)
        return str

    if (toCamel) {
        String r = str.toLowerCase().split('_').collect { cc -> Case.LOWER.apply(cc).capitalize() }.join('')
        return r[0].toLowerCase() + r[1..-1]
    } else {
        str = str[0].toLowerCase() + str[1..-1]
        return str.collect { cc -> ((char) cc).isUpperCase() ? '_' + cc.toLowerCase() : cc }.join('')
    }
}

static String genSerialID() {
    return "\tprivate static final long serialVersionUID =  " + Math.abs(new Random().nextLong()) + "L;"
}

最后生成出来的文件就是长这个样子