CMake Test编写

已于 2023-05-19 23:03:49 修改
阅读量1.2k 收藏 1
点赞数
分类专栏： CMake笔记 文章标签： linux cmake
于 2023-03-27 14:31:35 首次发布
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/m0_46327721/article/details/129479928
版权

文章目录

CMake Test

cmake对任何编程语言进行测试

自定义CMake的Test

项目目录如下

.
├── CMakeLists.txt
├── main.cpp
├── sum_integers.cpp
├── sum_integers.hpp
├── test.cpp
├── test.py
└── test.sh
  • sum_integers为项目源文件。
  • main为从命令行获取测试数据并调用sum_integers的功能，并返回计算结果。
  • test为在test文件中设定测试数据，并调用相应的程序将测试数据传输给main的可执行文件。由main可执行程序计算，并返回计算结果。test获取计算结果，根据test文件中的设定，判断测试成功与否。

cmake中的test编写

  • enable_testing() 启用test功能，测试该CMakeList.txt所在目录及其所有子文件夹。
  • add_test() 定义一个新测试，并设置测试名称和运行命令

例如：

add_test(
    NAME cpp_test
    COMMAND $<TARGET_FILE:cpp_test>
)
  • 创建了一个名为cpp_test的测试项
  • COMMAN表示执行对应的命令
  • $<TARGET_FILE:cpp_test> 为生成器表达式。构建时，cmake会将名cpp_test这个可执行文件的完整路径，替换为该生成器表达式。并执行。以便可以不显示的指定可执行程序的位置和名称，而且不同系统的可执行文件名可能不同，不好移植

再例如：

add_test(
  NAME python_test_short
  COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/test.py --short --executable $<TARGET_FILE:sum_up>
  )

构建一个名为python_test_short的测试项。调用python解释器，指定test.py的选项参数为–short, --executable ， $<TARGET_FILE:sum_up>即为test文件所需要使用到的可执行程序（为main程序）。test.py产生调用main程序使用指定的测试数据进行测试，并获取测试结果，并返回测试成功与否。

编译完后，执行ctest命令即可进行测试。

  • 添加--return-failed执行之前失败的测试
  • –output-on-failure 将测试程序生成的内容打印到屏幕上
  • -v 将启用测试的详细输出
  • -vv 将启用更详细的输出

cmake还将为生成器创建目标。

  • Unix Makefile生成器，通过make test测试
  • Ninja生成器，通过ninja test测试
指定测试的工作目录

例如：

add_test(
  NAME python_test_long
  COMMAND ${PYTHON_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/test.py --executable $<TARGET_FILE:sum_up>
  )

可以改写为如下，指定工作目录。

add_test(
  NAME python_test_long
  COMMAND ${PYTHON_EXECUTABLE} test.py --executable $<TARGET_FILE:sum_up>
  WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  )
按名称组织相关测试

测试名称添加/即可

add_test(
  NAME python/long
  COMMAND ${PYTHON_EXECUTABLE} test.py --executable $<TARGET_FILE:sum_up>
  WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  )
为测试脚本设置环境变量
set_tests_properties(python_test
  PROPERTIES
    ENVIRONMENT
      ACCOUNT_MODULE_PATH=${CMAKE_CURRENT_SOURCE_DIR}
      ACCOUNT_HEADER_FILE=${CMAKE_CURRENT_SOURCE_DIR}/account/account.h
      ACCOUNT_LIBRARY_FILE=$<TARGET_FILE:account>
  )

也可以通过CMAKE_COMMAND调用CMake来预先设置环境变量。

add_test(
  NAME
      python_test
  COMMAND
    ${CMAKE_COMMAND} -E env
    ACCOUNT_MODULE_PATH=${CMAKE_CURRENT_SOURCE_DIR}
    ACCOUNT_HEADER_FILE=${CMAKE_CURRENT_SOURCE_DIR}/account/account.h
    ACCOUNT_LIBRARY_FILE=$<TARGET_FILE:account>
    ${PYTHON_EXECUTABLE}
    ${CMAKE_CURRENT_SOURCE_DIR}/account/test.py
  )

Catch2 Test

Catch2是一个C++的测试框架。

Catch2的安装

git clone -b v3.3.2 https://github.com/catchorg/Catch2.git

cd Catch2
mkdir -p build&&cd build
cmake ..
make && make install

Catch2在cmake中的使用

Catch2 CMake

  1. 找到Catch2库
find_package(Catch2 3 REQUIRED)
  1. 测试文件链接到Catch2
target_link_libraries(target_name 
            PRIVATE 
                Catch2::Catch2WithMain
)
  1. 开启测试
enable_testing()
  1. 添加测试项
add_test(
    NAME catch2_test
    COMMAND $<TARGET_FILE:target_name> --success
)

执行测试

ctest -v //测试时输出详细信息
或
make test //如果构建器是unix makefile

也可以测试二进制文件，--success是catch2的选项

./target_name --success

使用-h可以查看Catch2提供的选项

./target_name --help

googleTest

Google Test框架不仅仅是一个头文件，也是一个库，包含两个需要构建和链接的文件(gtest gtest_main gmock gmock_main)。

使用FetchContent来获取第三方库，并链接。（不用安装，更加轻量级）。

获取googletest

include(FetchContent)
FetchContent_Declare(
    googletest
    GIT_REPOSITORY https://github.com/google/googletest.git
    GIT_TAG v1.13.0
)
#使gtest可用
FetchContent_MakeAvailable(googletest)

googletest在cmake中的使用

测试项链接到googletest

target_link_libraries(test_target
  PRIVATE
    gtest_main
)

启动测试项

enable_testing()
add_test(
  NAME google_test
  COMMAND $<TARGET_FILE:test_target>
)

Boost Test

Boost是c++社区非常流行的测试框架。

安装Boost

apt-get  install libboost-all-dev

查找boost库并链接

find_package(Boost 1.74 REQUIRED COMPONENTS unit_test_framework)

target_link_libraries(
    test_target
    PRIVATE
        Boost::unit_test_framework
)

给测试文件添加main函数的定义

target_compile_definitions(
    test_target
    PRIVATE
        BOOST_TEST_DYN_LINK
)

启用测试项

enable_testing()
add_test(
  NAME boost_test
  COMMAND $<TARGET_FILE:test_target>
)

测试

make test //如果构建器为unix makefile
或
ctest -vv

使用动态分析检测内存缺陷

内存缺陷：写入或读取越界，或者内存泄漏(已分配但从未释放的内存)，会产生难以跟踪的bug

Valgrind 是一个通用的工具，用来检测内存缺陷和内存泄漏。

valgrind安装

apt-get install valgrind

定义测试目标和MEMORYCHECK_COMMAND

# 查找valgrind，并将MEMORYCHECK_COMMAND设置为其绝对路径
find_program(MEMORYCHECK_COMMAND NAMES valgrind)
# 将相关参数传递给valgrind
set(MEMORYCHECK_COMMAND_OPTIONS "--trace-children=yes --leak-check=full")

添加内存检测到ctest中

#显示添加CTest模块启用memcheck
include(CTest)

开启测试

enable_testing()
add_test(
  NAME test_target_name
  COMMAND $<TARGET_FILE:test_target>
  )

检查内存缺陷

ctest -T memcheck

预期测试失败的测试项

在某些情况，我们就是测试希望测试失败的测试项。即指定测试失败的项为成功。

  • 当使用测试框架(gtest boost catch2)时，可以通过测试框架进行设置。
  • 当不使用框架时，设定该测试项的选项即可。

设置测试项失败为成功

# 将属性WILL_FAIL设置为true,将转换成功与失败
set_tests_properties(test_target PROPERTIES WILL_FAIL true)

如果需要更大的灵活性，可以将测试属性PASS_REGULAR_EXPRESSION和FAIL_REGULAR_EXPRESSION与set_tests_properties组合使用。如果设置了这些参数，测试输出将根据参数给出的正则表达式列表进行检查，如果匹配了正则表达式，测试将通过或失败。

设置超时测试运行时间过长的测试

设置超时来终止耗时过长的测试。

# 超过10s即测试失败
set_tests_properties(test_target_name PROPERTIES TIMEOUT 10)

并行测试

使用多核来减少测试时间。
执行测试时，可以使用以下命令，利用多核进行测试。

ctest --parallel N

或者在CMakeLists.txt中将CTEST_PARALLEL_LEVEL设置为所需要的级别即可。
例如：

set(CTEST_PARALLEL_LEVEL 4)

并行测试须知

  • 不并行测试时，测试顺序执行
  • 当第一次并行测试时，测试顺序执行
  • 当非第一次并行测试时，测试从耗时最长的测试项开始进行
  • cmake会记录各个对应测试项的测试时间，在非第一次测试时，会从耗时最长的开始执行。
  • 可以通过set_tests_properties来预先评估测试时间，以便cmake自动从最长的测试项开始测试。（即使时首次测试）

例如：

set_tests_properties(
    test_target
    PROPERTIES COST 2.5
)

测试子集

有时不需要运行所有测试项，可以使用测试子集。

  • 通过添加测试项的标签，从而可以只测试部分项。
ctest --parallel 4 -L myLabel
  • 也可以通过名称只测试部分
ctest --parallel 4 -R testName
  • 当在CMakeLists.txt中添加测试项后，cmake会自动为每个测试项设置编号，从1开始。可以指定测试项编号进行测试
ctest --parallel 4 -I 3,5

为测试项添加测试标签

set_test_properties(
  test_target
  PROPERTIES
    LABELS "myLabel"
)

使用测试固件

有时在测试前需要进行某些操作，在测试完成后需要执行某些操作。这些都可以通过测试固件绑定测试项完成。
例如：

add_test(
  NAME setup
  COMMAND ${PYTHON_EXECUTABLE} setup.py
  WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/test/
  )
set_tests_properties(
  setup
  PROPERTIES
      FIXTURES_SETUP my-fixture
  )
add_test(
  NAME feature-a
  COMMAND ${PYTHON_EXECUTABLE} feature-a.py
  WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/test/

)
add_test(
  NAME feature-b
  COMMAND ${PYTHON_EXECUTABLE} feature-b.py
  WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/test/

)
set_tests_properties(
  feature-a
  feature-b
  PROPERTIES
      FIXTURES_REQUIRED my-fixture
  )
add_test(
  NAME cleanup
  COMMAND ${PYTHON_EXECUTABLE} cleanup.py
  WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/test/
)
set_tests_properties(
  cleanup
  PROPERTIES
      FIXTURES_CLEANUP my-fixture
  )
  • setup为测试时的前置操作，cleanup为测试后所需要进行的操作。
  • 定义了一个my-fixture的测试固件，该测试固件设定了 FIXTURES_SETUP和FIXTURES_CLEANUP属性。
  • 将测试固件绑定到feature-a和feature-b,并设定为必须(FIXTURES_REQUIRED)

上述例子，在测试执行前会执行setup操作，测试完成后会执行cleanup操作。

young_monkeysun
关注
  • 0
    点赞
  • 踩
  • 1
    收藏
    觉得还不错? 一键收藏
  • 1
    评论
专栏目录
CMake测试
dxa572862121的博客
05-19 1532
简单示例 如果想执行几个可执行的程序或是执行相同的可执行程序但添加不同的参数，可以使用CTest工具，CMake自带CTest和CPack。 cmake doc ctest. add_test. enable_testing. 添加两个可执行程序 目的：对两个不同的cpp文件生成不同的可执行文件。并同时执行ctest CMakeLists.txt #版本要求，如若没有此句代码，可能会发生错误 cmake_minimum_required(VERSION 3.4) project(te
CMake 编译
fignting_formyself的博客
05-03 2969
cmake编译的步骤：1.创建两个文件夹，都放在xxx源文件夹下 xxx_temp_file   用于存放cmake产生的ITK项目文件 xxx   用于保存编译成功后的bin, include, lib等文件2.CMake编译（1）where is the source code 选择  编译的源文件所在的文件夹位置        where to build the binaries 选择 x...
CMake I 创建一个简单的单元测试
该用户还没想到好的昵称的博客
01-25 6918
创建一个简单的单元测试。ctest命令、add_test()、enable_testing()。
CMake之创建和运行测试
u010378559的博客
03-30 1430
CMake中使用CTest，GoogleTest创建和运行测试
cmake命令之add_test和set_tests_properties使用案例
weixin_42108533的博客
07-29 4151
add_test的命令形式如下 add_test(NAME <name> COMMAND <command> [<arg>...] [CONFIGURATIONS <config>...] [WORKING_DIRECTORY <dir>] [COMMAND_EXPAND_LISTS]) 今天占个位，等有时间再更新说明和使用案例 ...
【Cmake】Ctest测试工具
bandaoyu的note
08-08 6134
CTest是CMake集成的一个测试工具，在使用CMakeLists.txt文件编译工程的时候，CTest会自动configure、build、test和展现测试结果。创建CTestConfig.cmake在上层目录中，在cmake文件中，我们可以声明项目的名字和上传到的地址。原文链接：https://blog.csdn.net/xu_yun_huan_yue/article/details/120155307。2. 在test/CMakeLists.txt中写你的测试需要的即可（可以如下面那样写）....
CMake项目使用ctest+gtest进行单元测试
witton的专栏
04-15 4191
使用CMake中的ctest进行单元测试
cmake_test cmake_test cmake_test
04-18
通过 `include(CTest)` 引入 CTest 功能，然后编写测试用例并用 `add_test()` 添加。例如，可以创建一个名为 `test_main.cpp` 的测试文件，其中包含 Google Test 或 Catch 等测试框架的测试用例。 构建流程通常包括...
Cmake test 练习案例
05-24
本练习案例主要关注CMake中的测试部分，这通常涉及到使用CTest模块来编写和运行单元测试。 CMake的基本使用流程包括创建`CMakeLists.txt`文件，这个文件是CMake项目的配置中心。在这个文件中，你可以指定项目的目标...
modern cmake
02-16
2. **编程 CMake**：除了简单的配置外，CMake 还支持编写脚本来处理更复杂的构建逻辑。 3. **项目结构**：合理地组织项目结构对于维护项目的长期可维护性非常重要。CMake 提供了灵活的方式来定义项目结构。 4. **...
CMake中文手册_cmake手册_cmake_
10-01
CMake是一种广泛使用的开源构建系统，它旨在简化跨平台软件构建和配置的...通过深入阅读这份手册，开发者不仅可以理解CMake的工作原理，还能学会如何编写有效的CMakeLists.txt文件，从而提升项目的开发效率和维护性。
如何使用CMake的CTest进行单元测试
目前在做 ROS相关的工作，主要是写ROS相关和C++的学习心得
04-21 4969
CMake是一个跨平台的构建工具，可以自动生成与平台相关的Makefile或Visual Studio项目文件，简化了C++程序的构建过程。而CTest是CMake的测试工具，它可以自动化运行单元测试，收集测试结果并生成报告。
CMake的CTest方法
热门推荐
huyanjie0327的专栏
06-26 1万+
参考：http://hahack.com/codes/cmake/ Demo目录结构如下： Test/ ├── add.cpp └── CMakeLists.txt add.cpp #include #include int main(int argc, char *argv[]) { if (argc != 3) { std::cout << "pa
CTest在CMake项目中的详细使用步骤（二）稍复杂版
m0_52536237的博客
02-23 1436
如果可能的话，尝试将。
cmake：add_dependencies、add_test、add_link_options
OceanStar的博客
07-01 2788
设置当前目录和子目录的属性。 set_directory_properties(PROPERTIES prop1 value1 [prop2 value2] ...) 在键值对中设置当前目录及其子目录的属性。 另请参见set_property(DIRECTORY) 命令。 有关每个属性的行为，请参见 Properties on Directorie，了解CMake已知的属性列表及其各自文档。 ...
CTest在CMake项目中的详细使用步骤（一）
m0_52536237的博客
02-22 1140
在QT Creator上编写的存在多个UI界面的cmake项目的测试。
CMake创建CTest工程
fduffyyg的博客
11-18 3271
CMake创建CTest工程
Windows 下的sqlserver数据拷贝到linux
最新发布
cyw8998的专栏
07-25 275
2.在 >1 提示符下，输入以下 RESTORE DATABASE 命令，并在每行后按 Enter（无法同时复制和粘贴整个多行命令）。将出现的所有 gpdb 替换为数据库的名称。1.启动 sqlcmd。下面的示例以 SA 用户身份连接到本地 SQL Server。出现提示时输入密码，或使用 -P 参数指定密码。SSH打开linux终端。
cmake test 使用
04-02
CMake Test 是一个命令行工具，可以用于自动化测试。它可以自动运行测试程序并收集测试结果，并且可以自动化地生成测试报告。CMake Test 可以用于 C++ 项目、Python 项目以及其他语言的项目。CMake Test 需要一个测试配置文件，这个配置文件包含了测试程序的路径、测试参数、测试工具等信息。测试配置文件可以使用 CMake 编写，也可以使用其他语言编写。使用 CMake Test 的基本步骤如下： 1. 在 CMakeLists.txt 文件中添加测试相关的代码。 2. 使用 CMake 生成 Makefile。 3. 在命令行中执行 make test 命令，运行测试程序。 4. 查看测试结果和测试报告。 下面是一个简单的示例： ``` # CMakeLists.txt # 添加测试 enable_testing() # 编译测试程序 add_executable(test_myapp test_myapp.cpp) # 添加测试 add_test(NAME myapp_test COMMAND test_myapp) ``` 在上面的示例中，我们首先使用 enable_testing() 命令开启测试功能，然后使用 add_executable() 命令编译测试程序。最后使用 add_test() 命令添加测试，指定测试程序的名称和命令。 执行 make test 命令后，CMake 会自动运行测试程序，并收集测试结果。测试结果会显示在命令行中，并且会生成测试报告。测试报告可以在 build/Testing/Temporary 目录下找到。
评论 1
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值