01. 汇编LED驱动实验

硬件原理分析

而LED0是接在GPIO1_IO03，下面一个LED灯是电源指示灯。输出低电平时，LED0会点亮

汇编原理分析

为什么要学习Cortex—A汇编

1. 需要用汇编初始化一些SOC外设
2. 使用汇编初始化DDR，I.MX6U不需要
3. 设置SP指针，一般指向DDR，设置好C语言运行环境

STM32IO初始化流程

1. 使能GPIO时钟
2. 设置IO复用，将其复用为GPIO
3. 配置GPIO电气属性
4. 使用GPIO输出高低电平

IMX6UL初始化流程

1. 使能时钟 CCM_CCGRx

CCM_CCGR0 ~ CCM_CCGR6这七个寄存器控制着6ULL所有外设时钟的使能。为了简单，将这七个寄存器全部设置为0xFFFFFFFF，相当于使能所有外设时钟

2. IO复用 IOMUXC_SW_MUX_CTL_PAD_GPIO1_IO03

此寄存器设置IO复用为什么。这个寄存器的0-3位是复用位，将这4位设置为0101，这样就是复用为GPIO。该寄存器一共可以复用9个功能

3. 配置电气属性 IOMUXC_SW_PAD_CTL_PAD_GPIO1_IO03

此寄存器是设置电气属性，包括压摆率、速度、驱动能力、开漏、上下拉等。

** bit16：** 使能迟滞比较器，当IO作为输入功能的时候有效，如果需要对输入波形进行整形就可以使能该位，0表示禁止，1表示使能
** bit15:14：** 设置上下拉电阻
** bit13：** 当IO作为输入的时候，这个位用来设置IO使用上下拉还是状态保持器。就是说外部电路断电后此IO口可以保持住以前的状态
** bit12：** 禁止或使能上下拉/状态保持器
** bit11：** IO作为输出的时候，用来禁止或使能开路输出
** bit7:6：** IO作为输出的时候，用来设置IO速度
** bit5:3：** 作为输出的时候用来设置IO的驱动能力
** bit0：** 设置压摆率，就是指IO电平跳变所需的时间。时间越小波形越陡，压摆率越大

4. 配置GPIO功能 DR、GDIR、PSR、ICR1、ICR2、EDGE_SEL、IMR 和 ISR

当IO用作GPIO的时候需要设置的寄存器有8个：DR、GDIR、PSR、ICR1、ICR2、EDGE_SEL、IMR 和 ISR

GPIOx_DR

此寄存器是32位的数据寄存器，一个GPIO组最大有32个IO，所以DR寄存器的每一个位都对应一个IO。如果要设置GPOP1_IO03 输出高电平，那么就是GPIO1_DR=1<<3。被设置为输入模式后，此寄存器就保存着对应的IO的电平值。

GPIOx_GDIR

此寄存器是方向寄存器，用来设置某个IO的输入输出

GPIOx_PSR

此寄存器是状态寄存器，读取相应的位就可以获取对应的GPIO的高低电平值，也就是和输入状态的DR寄存器一样

GPIOx_ICR1和GPIOx_ICR2

这两个寄存器都是中断控制寄存器，ICR1 配置低16位，ICR2 配置高16位
该寄存器中一个GPIO用两个位，用来配置中断的触发方式

GPIOx_IMR

此寄存器是中断屏蔽寄存器，用来控制GPIO的中断禁止和使能

GPIOx_ISR

此寄存器是中断状态寄存器，只要某个GPIO的中断发生，那么对应的位也就被设置为1。所以，当处理完中断后，应该清除中断标志位

GPIOx_EDGE_SEL

此寄存器是边沿选择寄存器，用来设置边沿中断，会覆盖ICR1和ICR2的设置，如果被设置为1，就是双边沿中断

汇编基础

处理器内部数据传输指令

1. mov指令
   用于将数据从一个寄存器拷贝到另一个寄存器，或者将一个立即数传递到寄存器里面

mov R0, R1 @将寄存器R1中的数据传递给R0
mov R0, #0x12 @将立即数0x12传递给R0寄存器

2. mrs指令
   用于将特殊寄存器（如CPSR和SPSR）中的数据传递给通用寄存器

mrs R0, CPSR

3. msr指令
   将普通寄存器的数据传递给特殊寄存器

msr CPSR, R0

存储器访问指令

ARM不能直接访问存储器，比如RAM中的数据。I.MX6UL中的寄存器就是RAM类型的，我们用汇编来配置时许哟啊借助寄存器访问指令，一般先要将要配置的值写入到Rx(x=0~12)寄存器中，然后借助存储器访问指令将Rx中的数据写入到I.MX6UL寄存器中，读取也是一样的。

1. LDR指令
   用于从存储器加载数据到寄存器Rx中，也可以将一个立即数加载到寄存器中，加载立即数时需要用=，而不是#。
   
   上述代码的offset是0
2. STR指令
   将数据写入到存储器中
   

编写驱动

.global _start #全局标号，_start是程序的入口

_start:
	# 使能所有外设时钟 
	ldr r0, =0x020c4068 	#CCGR0的地址
	ldr r1, =0xffffffff 	#要向CCGR0写入的数据
	str r1, [r0]			#将r1写入到r0中

	ldr r0, =0x020c406c
	str r1, [r0]
	
	ldr r0, =0x020c4070
	str r1, [r0]
	
	ldr r0, =0x020c4074
	str r1, [r0]

	ldr r0, =0x020c4078
	str r1, [r0]

	ldr r0, =0x020c407c
	str r1, [r0]

	ldr r0, =0x020c4080
	str r1, [r0]
    
    ldr r0, =0x020c4084
	str r1, [r0]

	# 配置GPIO1_IO03的复用为GPIO，也就是设置为5 
	ldr r0, =0x020e0068 
	ldr r1, =0x05
	str r1, [r0] 

   /* 配置GPIO1_IO03的电器属性，地址是0x020e02f4
	* bit0:    0低速率
	* bit5:3:  110 R0/6驱动能力
	* bit7:6:  10 100MHz速度
	* bit11:   0关闭开路输出
	* bit12:   1 使能pull/kepper
	* bit13:   0 kepper
	* bit15:14: 00 100k下拉
	* bit16:   0 关闭hys
	*/

	ldr r0, =0x020e02f4 
	ldr r1, =0x10b0 # 00 0 1 0000 10 110 00 0
	str r1, [r0] 
	
	# 设置GPIO1_GDIR寄存器，设置GPIO_GPIO03为输出 
	ldr r0, =0x0209c004
	ldr r1, =0x08
	str r1, [r0] 

	# 打开LED，也就是设置GPIO_IO03为低电平 GPIO_DR的地址为0x0209c000
	ldr r0, =0x0209c000
	ldr r1, =0x00
	str r1, [r0]
loop:
	b loop #死循环，防止程序结束

编译程序

1. 使用arm-linux-gnueabihf-gcc -g -c led.s led.o将.c 和.s 文件变为.o
2. 使用arm-linux-gnueabihf-ld -Ttext 0X87800000 led.o -o led.elf将.o文件链接为elf格式的可执行文件，链接时需要指定链接的起始地址。对于6ULL，链接其实地址应该指向RAM地址，而不是存在内部flash。RAM分为内部0x900000~0x91ffff，也可以是外部DDR，对于ALPHA，选择0x87800000。要使用DDR，必须要初始化DDR。对于IMX，bin文件不能直接烧写到SD卡、EMMC、NAND等外置存储中，然后从这些外置存储中启动运行，需要添加一个头部，这个头部包含了DDR的初始化参数
3. 使用arm-linux-gnueabihf-objcopy -O binary -S -g led.elf led.bin将elf文件转为bin文件
4. 使用arm-linux-gnueabihf-objdump -D led.elf > led.dis将elf文件转为汇编、反汇编文件

可以直接编写makefile文件，直接通过make指令编译，这里就不详细说明makefile文件的使用

led.bin:led.s
	arm-linux-gnueabihf-gcc -g -c led.s -o led.o
	arm-linux-gnueabihf-ld -Ttext 0X87800000 led.o -o led.elf
	arm-linux-gnueabihf-objcopy -O binary -S -g led.elf led.bin
	arm-linux-gnueabihf-objdump -D led.elf > led.dis

.PHONY:clean
clean:
	rm -rf *.o led.bin led.elf led.dis

烧写bin文件

烧写不是将bin文件拷贝到SD卡中，而是将bin文件烧写到SD卡的绝对路径下。而且对于IMX，不能直接烧写bin问价，需要使用imxdownload软件。使用方法：确定要烧写的SD卡文件，给予imxdownload可执行权限chmod 777 imxdownload。然后就./imxdownload led.bin /dev/sdf。会向led.bin添加一个头部，并且生成一个新的imx文件，将新的文件烧写到SD卡中