汇编原理知识点小结（一）

​

Loop指令

功能： 实现循环（计数型循环）
指令的格式： loop标号
CPU执行loop指令时要进行的操作：

1. (cx)=(cx)-1;
2. 判断cx中的值（不为零则转至标号处执行程序，如果为零则向下执行。）

要求：
cx中要提前存放循环次数，因为(cx)影响着loop指令的执行结果
要定义一个标号。
例：计算2的12次方

;loop指令示例程序
assume cs:code    ;伪指令
code segment
    mov ax, 2
    mov cx, 11    ;循环一次，cx-1
s.  add ax, ax    ;s.为循环标号
    loop s
    mov ax, 4c00h
    int 21h
code ends
end

三个要点：

• 在cx中存放循环次数；
• 用标号指定循环开始的位置；
• 在标号和loop指令的中间，写上要循环执行的程序段（循环体）。

例：用loop指令编程

assume cs:code
code segment
    mov ax, 0ffffh    ;在汇编源程序中，数据不能以字母开头，要在ffff面前加0
    mov ds, ax    ;规定数据段，不能直接赋值给ds

    mov bx, 6    ;把6赋值给bx
    mov al, [bx]    ;把ffff:0006赋值给al字节型单元寄存器
    mov ah, 0    ;把ah初始化成0

    mov dx, 0    ;初始化dx
    mov cx, 3    ;设置循环次数
s:  add dx, ax    ;循环体
    loop s    ;循环语句

    mov ax, 4c00h    ;结束语句
    int 21h
code ends    ;结束代码段
end    ;结束整个程序

引入段前缀

有如下代码：

assume cs:code
code segment
    mov ax, 2000h
    mov ds, ax
    mov al, [0]
    mov bl, [1]
    mov cl, [2]
    mov dl, [3]

    mov ax,4c00h
    int 21h
code ends
end

Debug中，mov al [0]的功能时将DS:0存储单元的值传给AL。
但编译(masm)并连接(link)后，编译好的程序中，mov al, [0]变成了将常量0传给AL。

小结

语句	内涵
mov al, [0]	(al)=0，同mov al,0
mov al,ds:[0]	(al)=((ds)*16+0)
mov al,[bx]	(al)=((ds)*16+(bx))
mov al,ds:[bx]	与mov al,[bx]相同

这些出现在访问内存单元的指令中，用于指明内存单元的段地址的ds:、cs:、ss:或者es:，在汇编语言中称为段前缀。

访问连续的内存单元——loop和[bx]联手

问题

计算ffff:0~ffff:b字节单元中数据的和，结果存储在dx中

分析

（1）运算后的结果是否会超出dx所能存储的范围？
ffff:0~ ffff:b内存单元中的数据是字节型数据，范围在ffff:0~ffff:b内存单元中的数据是字节型数据，范围在0 ~255之间，12个这样的数据相加，结果不会大于65535，可以在dx中存放下。
（2）是否可以将ffff:0 ~ ffff:b中的数据直接累加到dx中？
add dx, ds:[addr] ;(dx)=(dx)+?
期望：取出内存中的8位数据进行相加
实际：取出的是内存中的16位数据
（3）是否可以将ffff:0 ~ffff:b 中的数据直接累加到dl中？
期望：取出内存中的8位数据相加
实际：取出的是内存中的8位数据，但很有可能造成进位丢失

对策

assume cs: code
code segment
	; 指定段地址
	mov ax, 0ffffh
	mov ds, ax
	
	; bx存放地址偏移量，dx存放累加量，cx存放循环次数
	mov bx, 0	;初始化
	mov dx, 0
	mov cx, 12

	;循环语句
s: mov al, [bx]	;低位寄存器存放累加字节型变量
	mov ah, 0	;高位寄存器初始化
	add dx, ax	;将字节型数据存放在字型寄存器中
	inc bx	;地址偏移量加一
	loop s

	mov ax,4c00h
	int 21h
code ends
end

段前缀的使用

将内存ffff:0_{`ffff:b`中的数据拷贝到`0:200`}0:20b单元中。

; 初始方案
assume cs:code
code segment
	mov bx, 0	;初始化bx
	mov cx, 12	;设置循环次数

;复制ffff:0~ffff:b中的数据到dl
s: mov ax, 0ffffh	;设置代码段地址
	mov ds, ax
	mov dl, [bx]	;将ffff:bx内存单元中的值存放在dl中
	
;将dl的值转移到0020:0~0020:b
	mov ax, 0020h	
	mov ds, ax
	mov [bx], dl

;偏移地址加1
	inc bx
	loop s

	mov ax, 4c00h
	int 21h
code ends
end

引入一个新寄存器，存放段地址（0020h）

;使用附加段寄存器
assume cs:code
code segment
	mov ax, 0ffffh
	mov ds, ax
	mov ax 0020h
	mov es, ax

	mov bx, 0
	mov cx, 12

s: mov dl, [bx]
	mov es:[bx], dl
	inc bx
	loop s

	mov ax, 4c00h
	int 21h
code ends
end

在代码段中使用数据

在代码段中定义数据

dw 定义一个字
db 定义一个字节
dd 定义一个双字

定义一个标号，指示代码开始的位置

效果
程序加载后，CS:IP指向要执行的第一条指令在start处
程序的一般框架

assume cs:code
code segment
	:
	数据
	:
begin：
	:
	:
	代码
	:
	:
code ends
end begin

应用案例

问题
编程计算以下8个数据的和，结果存在ax寄存器中
0123H, 0456H, 0789H, 0abcH, 0defH, 0fedH, 0cbaH, 0987H
对策

assume cs:code
code segment
;在代码段中定义字型数据
		dw 0123H, 0456H, 0789H, 0abcH, 0defH, 0fedH, 0cbaH, 0987H
;定义一个标号，指示代码开始的位置。
start:mov bx, 0	;初始化bx
		mov ax, 0	;初始化ax
		mov cx, 8		;定义循环变量8

s: add ax, cs:[bx]		;将变量累加到ax中
	add bx, 2		;bx地址偏移量加2
	loop s

	mov ax, 4c00h
	int 21h
	code ends
	end start
;end的作用：除了通知编译器程序结束外，还可以通知编译器程序的入口在什么地方。

在代码段中使用栈：以数据逆序存放为例

问题

完成下列程序，利用栈，将程序中定义的数据逆序存放。

assume cs:codesg
codesg segment
	dw 0123h, 0456h, 0789h, 0abch, 0defh, 0fedh, 0cbah, 0987h
	?

code ends
end

思路

• 程序运行时，定义的数据放在cs:0~cs:F单元中，共8个字单元。
• 依次将这8个字单元中的数据入栈，然后再依次出栈到这8个字单元中，从而实现数据的逆序存放。
• 栈需要的内存空间，在程序中通过定义“空”数据来取得。

对策

assume cs:codesg
codesg segment
	dw 0123h, 0456h, 0789h, 0abch, 0defh, 0fedh, 0cbah, 0987h
	dw 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0
	; 定义16个空字型数据，用来作为存放空间
start: mov ax, cs
	mov ss, ax	;设置代码段起始就是栈段
	mov sp, 30h	;设置栈顶指针
	
	;入栈
	mov bx, 0
	mov cx, 8
s:push cs:[bx]
	add bx, 2
	loop s
	
	;出栈
	mov bx, 0
	mov cx, 8
s0: pop cs:[bx]
	add bx,2
	loop s0
	mov ax, 4c00h
	int 21h
codesg ends
end start