wikioi 3027 线段覆盖2

3027 线段覆盖 2
 时间限制: 1 s
 空间限制: 128000 KB
 题目等级 : 黄金 Gold
 题解
题目描述 Description
数轴上有n条线段，线段的两端都是整数坐标，坐标范围在0~1000000，每条线段有一个价值，请从n条线段中挑出若干条线段，使得这些线段两两不覆盖（端点可以重合）且线段价值之和最大。


n<=1000


输入描述 Input Description
第一行一个整数n，表示有多少条线段。


接下来n行每行三个整数, ai bi ci，分别代表第i条线段的左端点ai，右端点bi（保证左端点<右端点）和价值ci。


输出描述 Output Description
输出能够获得的最大价值
样例输入 Sample Input
3


1 2 1


2 3 2


1 3 4


样例输出 Sample Output
4


数据范围及提示 Data Size & Hint
数据范围


对于40%的数据，n≤10；


对于100%的数据，n≤1000；


0<=ai,bi<=1000000

0<=ci<=1000000

题解：将线段按右端点从小到大排序，f[i]表示以第i条线段结尾的最大价值，f[i]=max(f[j])+a[i,3] | j<i且a[j,2]<=a[i,1]，即前i条线段中能够合法接在第i条前的最大价值加上第i条的价值。在f中取最大值即为答案

const
  maxn=1000;
var
  a:array[0..maxn,1..3]of longint;
  f:array[1..maxn]of longint;
  n,ans,i,j:longint;

procedure init;
var
  i,t:longint;
begin
  readln(n);
  for i:=1 to n do
  begin
    readln(a[i,1],a[i,2],a[i,3]);
    if a[i,1]>a[i,2] then
    begin
      t:=a[i,1];a[i,1]:=a[i,2];a[i,2]:=t;
    end;
  end;
end;

procedure sort;
var
  i,j:longint;
begin
  for i:=1 to n-1 do
    for j:=i+1 to n do
      if (a[i,2]>a[j,2])or(a[i,2]=a[j,2])and(a[i,1]>a[j,1]) then
      begin
        a[0]:=a[i];a[i]:=a[j];a[j]:=a[0];
      end;
end;

function max(a,b:longint):longint;
begin
  if a>b then exit(a) else exit(b);
end;

begin
  init;
  sort;
  for i:=1 to n do
  begin
    for j:=1 to i-1 do
      if a[j,2]<=a[i,1] then
        f[i]:=max(f[i],f[j]);
      f[i]:=f[i]+a[i,3];
      if f[i]>ans then ans:=f[i];
  end;
  writeln(ans);
end.